ExternalProject for secp256k1

Author: chfast

CMakeLists.txt

@@ -52,6 +52,7 @@ include(ProjectBoost)
 include(ProjectCryptopp)
 include(ProjectJsonCpp)
 include(ProjectJsonRpcCpp)
+include(ProjectSecp256k1)
 
 
 

cmake/ProjectSecp256k1.cmake

@@ -0,0 +1,32 @@
+include(ExternalProject)
+
+if (MSVC)
+    set(_only_release_configuration -DCMAKE_CONFIGURATION_TYPES=Release)
+endif()
+
+ExternalProject_Add(ep-secp256k1
+    PREFIX ${CMAKE_SOURCE_DIR}/deps
+    DOWNLOAD_NAME secp256k1-9d560f99.tar.gz
+    DOWNLOAD_NO_PROGRESS 1
+    URL https://github.com/bitcoin-core/secp256k1/archive/9d560f992db26612ce2630b194aef5f44d63a530.tar.gz
+    URL_HASH SHA256=910b2535bdbb5d235e9212c92050e0f9b327e05129b449f8f3d3c6d558121284
+    PATCH_COMMAND ${CMAKE_COMMAND} -E copy_directory
+        ${CMAKE_CURRENT_LIST_DIR}/secp256k1
+        <SOURCE_DIR>
+    CMAKE_ARGS -DCMAKE_INSTALL_PREFIX=<INSTALL_DIR>
+               -DCMAKE_POSITION_INDEPENDENT_CODE=${BUILD_SHARED_LIBS}
+               ${_only_release_configuration}
+    LOG_CONFIGURE 1
+    LOG_INSTALL 1
+)
+
+# Create imported library
+ExternalProject_Get_Property(ep-secp256k1 INSTALL_DIR)
+add_library(Secp256k1 STATIC IMPORTED)
+set(SECP256K1_LIBRARY ${INSTALL_DIR}/lib/${CMAKE_STATIC_LIBRARY_PREFIX}secp256k1${CMAKE_STATIC_LIBRARY_SUFFIX})
+set(SECP256K1_INCLUDE_DIR ${INSTALL_DIR}/include)
+file(MAKE_DIRECTORY ${SECP256K1_INCLUDE_DIR})  # Must exist.
+set_property(TARGET Secp256k1 PROPERTY IMPORTED_LOCATION ${SECP256K1_LIBRARY})
+set_property(TARGET Secp256k1 PROPERTY INTERFACE_INCLUDE_DIRECTORIES ${SECP256K1_INCLUDE_DIR})
+add_dependencies(Secp256k1 ep-secp256k1)
+unset(INSTALL_DIR)

cmake/secp256k1/CMakeLists.txt

@@ -0,0 +1,28 @@
+# This is copy of secp256k1 project from https://github.com/bitcoin-core/secp256k1
+# Commit: https://github.com/bitcoin-core/secp256k1/commit/9d560f992db26612ce2630b194aef5f44d63a530
+#
+# It has been configured following official docs with following options:
+#
+# ./configure --disable-shared --disable-tests --disable-coverage --disable-openssl-tests --disable-exhaustive-tests --disable-jni --with-bignum=no --with-field=64bit --with-scalar=64bit --with-asm=no
+#
+# Build static context:
+# make src/ecmult_static_context.h
+#
+# Copy src and include dirs.
+#
+# Copy CFLAGS from Makefile to COMPILE_OPTIONS.
+
+cmake_minimum_required(VERSION 3.4)
+project(secp256k1 LANGUAGES C)
+
+if (NOT MSVC)
+	# Use default Release flags on MSVC.
+	set(COMPILE_OPTIONS -O3 -W -std=c89 -pedantic -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes -Wno-unused-function -Wno-long-long -Wno-overlength-strings -fvisibility=hidden)
+endif()
+
+add_library(secp256k1 STATIC src/secp256k1.c)
+target_compile_definitions(secp256k1 PRIVATE HAVE_CONFIG_H)
+target_include_directories(secp256k1 PRIVATE . src)
+target_compile_options(secp256k1 PRIVATE ${COMPILE_OPTIONS})
+install(TARGETS secp256k1 ARCHIVE DESTINATION lib)
+install(DIRECTORY include/ DESTINATION include)