flake.nix

{ inputs = {
    nixpkgs.url = github:NixOS/nixpkgs/release-22.05;

    utils.url = github:numtide/flake-utils;
  };

  outputs = { nixpkgs, utils, ... }:
    utils.lib.eachDefaultSystem (system:
      let
        config = { };

        overlay = pkgsNew: pkgsOld: {
          haskellPackages = pkgsOld.haskellPackages.override (old: {
            overrides =
            pkgsNew.lib.fold
              pkgsNew.lib.composeExtensions
              (_: _: { })
              [ (pkgsNew.haskell.lib.packageSourceOverrides {
                  foldl = ./.;
                })
                (pkgsNew.haskell.lib.packagesFromDirectory {
                  directory = ./nix;
                })
                (haskellPackagesNew: haskellPackagesOld: {
                })
              ];
          });
        };

        pkgs =
          import nixpkgs { inherit config system; overlays = [ overlay ]; };

      in
        rec {
          packages.default = pkgs.haskellPackages.foldl;

          devShells.default = pkgs.haskellPackages.foldl.env;
        }
    );
}