forked from QEF/q-e
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathexx_band.f90
1490 lines (1466 loc) · 47.7 KB
/
exx_band.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
! Copyright (C) 2005-2018 Quantum ESPRESSO group
! This file is distributed under the terms of the
! GNU General Public License. See the file `License'
! in the root directory of the present distribution,
! or http://www.gnu.org/copyleft/gpl.txt .
!
!----------------------------------------------------------------------------
MODULE exx_band
!---------------------------------------------------------------------------
!! Variables and subroutines for band parallelization over pairs of bands.
!
!! See:
!! T. Barnes, T. Kurth, P. Carrier, N. Wichmann, D. Prendergast,
!! P.R.C. Kent, J. Deslippe, Comp. Phys. Comm. (2017),
!! doi.org/10.1016/j.cpc.2017.01.008
!
USE kinds, ONLY : DP
USE noncollin_module, ONLY : npol
USE io_global, ONLY : ionode, stdout
!
USE control_flags, ONLY : gamma_only, use_gpu
USE fft_types, ONLY : fft_type_descriptor
USE stick_base, ONLY : sticks_map
!
IMPLICIT NONE
!
SAVE
!
COMPLEX(DP), ALLOCATABLE :: evc_exx(:,:)
COMPLEX(DP), ALLOCATABLE :: psi_exx(:,:), hpsi_exx(:,:)
INTEGER :: lda_original
INTEGER :: nwordwfc_exx
INTEGER, ALLOCATABLE :: igk_exx(:,:)
INTEGER, ALLOCATABLE :: igk_exx_d(:,:)
#if defined(__CUDA)
attributes(DEVICE) :: igk_exx_d
#endif
!
! mapping for the data structure conversion
!
TYPE comm_packet
INTEGER :: size
INTEGER, ALLOCATABLE :: indices(:)
COMPLEX(DP), ALLOCATABLE :: msg(:,:,:)
END TYPE comm_packet
TYPE(comm_packet), ALLOCATABLE :: comm_recv(:,:), comm_send(:,:)
TYPE(comm_packet), ALLOCATABLE :: comm_recv_reverse(:,:)
TYPE(comm_packet), ALLOCATABLE :: comm_send_reverse(:,:,:)
INTEGER, ALLOCATABLE :: lda_local(:,:)
INTEGER, ALLOCATABLE :: lda_exx(:,:)
INTEGER, ALLOCATABLE :: ngk_local(:), ngk_exx(:)
INTEGER :: npwx_local = 0
INTEGER :: npwx_exx = 0
INTEGER :: n_local = 0
LOGICAL :: first_data_structure_change = .TRUE.
INTEGER :: ngm_loc, ngm_g_loc, gstart_loc
INTEGER, ALLOCATABLE :: ig_l2g_loc(:)
REAL(DP), ALLOCATABLE :: g_loc(:,:), gg_loc(:)
INTEGER, ALLOCATABLE :: mill_loc(:,:), nl_loc(:)
INTEGER :: ngms_loc, ngms_g_loc
INTEGER, ALLOCATABLE :: nls_loc(:)
INTEGER, ALLOCATABLE :: nlm_loc(:)
INTEGER, ALLOCATABLE :: nlsm_loc(:)
INTEGER :: ngm_exx, ngm_g_exx, gstart_exx
INTEGER, ALLOCATABLE :: ig_l2g_exx(:)
REAL(DP), ALLOCATABLE :: g_exx(:,:), gg_exx(:)
INTEGER, ALLOCATABLE :: mill_exx(:,:), nl_exx(:)
INTEGER :: ngms_exx, ngms_g_exx
INTEGER, ALLOCATABLE :: nls_exx(:)
INTEGER, ALLOCATABLE :: nlm_exx(:)
INTEGER, ALLOCATABLE :: nlsm_exx(:)
TYPE(fft_type_descriptor) :: dfftp_loc, dffts_loc
TYPE(fft_type_descriptor) :: dfftp_exx, dffts_exx
TYPE (sticks_map) :: smap_exx ! Stick map descriptor
CONTAINS
!
!-----------------------------------------------------------------------
SUBROUTINE transform_evc_to_exx( type )
!-----------------------------------------------------------------------
!! Transform evc to the EXX data structure.
!
USE wvfct, ONLY : npwx, nbnd
USE io_files, ONLY : nwordwfc, iunwfc, iunwfc_exx
USE klist, ONLY : nks, ngk, igk_k
USE uspp, ONLY : nkb, vkb
USE wavefunctions, ONLY : evc
USE control_flags, ONLY : io_level
USE buffers, ONLY : open_buffer, get_buffer, save_buffer
USE mp_exx, ONLY : max_ibands, negrp
!
IMPLICIT NONE
!
INTEGER, INTENT(IN) :: type
INTEGER :: lda, n, ik
LOGICAL :: exst_mem, exst_file
!
IF (negrp == 1) THEN
!
! no change in data structure is necessary
! just copy all of the required data
!
! get evc_exx
!
IF(.not.allocated(evc_exx))THEN
ALLOCATE(evc_exx(npwx*npol,nbnd))
END IF
evc_exx = evc
!
! get igk_exx
!
IF(.not.allocated(igk_exx)) THEN
ALLOCATE( igk_exx( npwx, nks ) )
igk_exx = igk_k
END IF
IF(use_gpu .and. ( .not. allocated(igk_exx_d) ) ) THEN
ALLOCATE( igk_exx_d, source=igk_exx )
END IF
!
! get the wfc buffer is used
!
iunwfc_exx = iunwfc
nwordwfc_exx = nwordwfc
!
RETURN
!
END IF
!
! change the data structure of evc and igk
!
lda = npwx
n = npwx
npwx_local = npwx
IF( .not.allocated(ngk_local) ) allocate(ngk_local(nks))
ngk_local = ngk
!
IF ( .not.allocated(comm_recv) ) THEN
!
! initialize all of the conversion maps and change the data structure
!
CALL initialize_local_to_exact_map(lda, nbnd)
ELSE
!
! change the data structure
!
CALL change_data_structure(.TRUE.)
END IF
!
lda = npwx
n = npwx
npwx_exx = npwx
IF( .not.allocated(ngk_exx) ) allocate(ngk_exx(nks))
ngk_exx = ngk
!
! get evc_exx
!
IF(.not.allocated(evc_exx))THEN
ALLOCATE(evc_exx(lda*npol,max_ibands+2))
!
! ... open files/buffer for wavefunctions (nwordwfc set in openfil)
! ... io_level > 1 : open file, otherwise: open buffer
!
nwordwfc_exx = size(evc_exx)
CALL open_buffer( iunwfc_exx, 'wfc_exx', nwordwfc_exx, io_level, &
exst_mem, exst_file )
END IF
!
DO ik=1, nks
!
! read evc for the local data structure
!
IF ( nks > 1 ) CALL get_buffer(evc, nwordwfc, iunwfc, ik)
!
! transform evc to the EXX data structure
!
CALL transform_to_exx(lda, n, nbnd, nbnd, ik, evc, evc_exx, type)
!
! save evc to a buffer
!
IF ( nks > 1 ) CALL save_buffer ( evc_exx, nwordwfc_exx, iunwfc_exx, ik )
END DO
!
END SUBROUTINE transform_evc_to_exx
!
!
!-----------------------------------------------------------------------
SUBROUTINE transform_psi_to_exx( lda, n, m, psi )
!-----------------------------------------------------------------------
!! Transform psi to EXX data structure.
!
USE wvfct, ONLY : current_k, npwx, nbnd
USE mp_exx, ONLY : negrp, nibands, my_egrp_id, max_ibands
!
IMPLICIT NONE
!
INTEGER, INTENT(IN) :: lda
INTEGER, INTENT(IN) :: m
INTEGER, INTENT(INOUT) :: n
COMPLEX(DP), INTENT(IN) :: psi(lda*npol,m)
!
! change to the EXX data strucutre
!
npwx_local = npwx
n_local = n
IF ( .not.allocated(comm_recv) ) THEN
!
! initialize all of the conversion maps and change the data structure
!
CALL initialize_local_to_exact_map(lda, m)
ELSE
!
! change the data structure
!
CALL change_data_structure(.TRUE.)
END IF
npwx_exx = npwx
n = ngk_exx(current_k)
!
! get igk
!
CALL update_igk(.TRUE.)
!
! get psi_exx
!
CALL transform_to_exx(lda, n, m, max_ibands, &
current_k, psi, psi_exx, 0)
!
! zero hpsi_exx
!
hpsi_exx = 0.d0
!
!
END SUBROUTINE transform_psi_to_exx
!
!
!-----------------------------------------------------------------------
SUBROUTINE transform_hpsi_to_local( lda, n, m, hpsi )
!-----------------------------------------------------------------------
!! Transform hpsi_exx to the local data structure.
!
USE mp_exx, ONLY : iexx_istart, iexx_iend, my_egrp_id
!
IMPLICIT NONE
!
INTEGER, INTENT(IN) :: lda
INTEGER, INTENT(IN) :: m
INTEGER, INTENT(INOUT) :: n
COMPLEX(DP), INTENT(OUT) :: hpsi(lda_original*npol,m)
INTEGER :: m_exx
!
! change to the local data structure
!
CALL change_data_structure(.FALSE.)
!
! get igk
!
CALL update_igk(.FALSE.)
n = n_local
!
! transform hpsi_exx to the local data structure
!
m_exx = iexx_iend(my_egrp_id+1) - iexx_istart(my_egrp_id+1) + 1
CALL transform_to_local(m,m_exx,hpsi_exx,hpsi)
!
END SUBROUTINE transform_hpsi_to_local
!
!
!-----------------------------------------------------------------------
SUBROUTINE initialize_local_to_exact_map( lda, m )
!-----------------------------------------------------------------------
!! Determine the mapping between the local and EXX data structures.
!
USE wvfct, ONLY : npwx, nbnd
USE klist, ONLY : nks, igk_k
USE mp_exx, ONLY : nproc_egrp, negrp, my_egrp_id, me_egrp, &
intra_egrp_comm, inter_egrp_comm, &
ibands, nibands, init_index_over_band, &
iexx_istart, iexx_iend, max_ibands
USE mp_pools, ONLY : nproc_pool, me_pool, intra_pool_comm
USE mp, ONLY : mp_sum
USE gvect, ONLY : ig_l2g
USE uspp, ONLY : nkb
!
IMPLICIT NONE
!
Integer :: lda
INTEGER :: n, m
INTEGER, ALLOCATABLE :: local_map(:,:), exx_map(:,:)
INTEGER, ALLOCATABLE :: l2e_map(:,:), e2l_map(:,:,:)
INTEGER, ALLOCATABLE :: psi_source(:), psi_source_exx(:,:)
INTEGER :: current_index
INTEGER :: i, j, k, ik, im, ig, count, iproc, prev, iegrp
INTEGER :: total_lda(nks), prev_lda(nks)
INTEGER :: total_lda_exx(nks), prev_lda_exx(nks)
INTEGER :: n_local
INTEGER :: lda_max_local, lda_max_exx
INTEGER :: max_lda_egrp
INTEGER :: request_send(nproc_egrp), request_recv(nproc_egrp)
INTEGER :: ierr
INTEGER :: egrp_base, total_lda_egrp(nks), prev_lda_egrp(nks)
INTEGER :: igk_loc(npwx)
!
! initialize the pair assignments
!
CALL init_index_over_band(inter_egrp_comm,nbnd,m)
!
! allocate bookeeping arrays
!
IF ( .not.allocated(comm_recv) ) THEN
ALLOCATE(comm_recv(nproc_egrp,nks),comm_send(nproc_egrp,nks))
END IF
IF ( .not.allocated(lda_local) ) THEN
ALLOCATE(lda_local(nproc_pool,nks))
ALLOCATE(lda_exx(nproc_egrp,nks))
END IF
!
! store the original values of lda FIXME: why?
!
lda_original = lda
!
! construct the local map
!
lda_local = 0
DO ik = 1, nks
igk_loc = igk_k(:,ik)
n = 0
DO i = 1, size(igk_loc)
IF(igk_loc(i).gt.0)n = n + 1
END DO
lda_local(me_pool+1,ik) = n
CALL mp_sum(lda_local(:,ik),intra_pool_comm)
total_lda(ik) = sum(lda_local(:,ik))
prev_lda(ik) = sum(lda_local(1:me_pool,ik))
END DO
ALLOCATE(local_map(maxval(total_lda),nks))
local_map = 0
DO ik = 1, nks
local_map(prev_lda(ik)+1:prev_lda(ik)+lda_local(me_pool+1,ik),ik) = &
ig_l2g(igk_k(1:lda_local(me_pool+1,ik),ik))
END DO
CALL mp_sum(local_map,intra_pool_comm)
!
!-----------------------------------------!
! Switch to the exx data structure !
!-----------------------------------------!
!
CALL change_data_structure(.TRUE.)
!
! construct the exx map
!
lda_exx = 0
DO ik = 1, nks
n = 0
DO i = 1, size(igk_exx(:,ik))
IF(igk_exx(i,ik).gt.0)n = n + 1
END DO
lda_exx(me_egrp+1,ik) = n
CALL mp_sum(lda_exx(:,ik),intra_egrp_comm)
total_lda_exx(ik) = sum(lda_exx(:,ik))
prev_lda_exx(ik) = sum(lda_exx(1:me_egrp,ik))
END DO
ALLOCATE(exx_map(maxval(total_lda_exx),nks))
exx_map = 0
DO ik = 1, nks
exx_map(prev_lda_exx(ik)+1:prev_lda_exx(ik)+lda_exx(me_egrp+1,ik),ik) = &
ig_l2g(igk_exx(1:lda_exx(me_egrp+1,ik),ik))
END DO
CALL mp_sum(exx_map,intra_egrp_comm)
!
! construct the l2e_map
!
allocate( l2e_map(maxval(total_lda_exx),nks) )
l2e_map = 0
DO ik = 1, nks
DO ig = 1, lda_exx(me_egrp+1,ik)
DO j=1, total_lda(ik)
IF( local_map(j,ik).EQ.exx_map(ig+prev_lda_exx(ik),ik) ) exit
END DO
l2e_map(ig+prev_lda_exx(ik),ik) = j
END DO
END DO
CALL mp_sum(l2e_map,intra_egrp_comm)
!
! plan communication for the data structure change
!
lda_max_local = maxval(lda_local)
lda_max_exx = maxval(lda_exx)
allocate(psi_source(maxval(total_lda_exx)))
!
DO ik = 1, nks
!
! determine which task each value will come from
!
psi_source = 0
DO ig = 1, lda_exx(me_egrp+1,ik)
j = 1
DO i = 1, nproc_pool
j = j + lda_local(i,ik)
IF( j.gt.l2e_map(ig+prev_lda_exx(ik),ik) ) exit
END DO
psi_source(ig+prev_lda_exx(ik)) = i-1
END DO
CALL mp_sum(psi_source,intra_egrp_comm)
!
! allocate communication packets to receive psi and hpsi
!
DO iproc=0, nproc_egrp-1
!
! determine how many values need to come from iproc
!
count = 0
DO ig=1, lda_exx(me_egrp+1,ik)
IF ( MODULO(psi_source(ig+prev_lda_exx(ik)),nproc_egrp)&
.eq.iproc ) THEN
count = count + 1
END IF
END DO
!
! allocate the communication packet
!
comm_recv(iproc+1,ik)%size = count
IF (count.gt.0) THEN
IF (.not.ALLOCATED(comm_recv(iproc+1,ik)%msg)) THEN
ALLOCATE(comm_recv(iproc+1,ik)%indices(count))
ALLOCATE(comm_recv(iproc+1,ik)%msg(count,npol,max_ibands+2))
END IF
END IF
!
! determine which values need to come from iproc
!
count = 0
DO ig=1, lda_exx(me_egrp+1,ik)
IF ( MODULO(psi_source(ig+prev_lda_exx(ik)),nproc_egrp)&
.eq.iproc ) THEN
count = count + 1
comm_recv(iproc+1,ik)%indices(count) = ig
END IF
END DO
!
END DO
!
! allocate communication packets to send psi and hpsi
!
prev = 0
DO iproc=0, nproc_egrp-1
!
! determine how many values need to be sent to iproc
!
count = 0
DO ig=1, lda_exx(iproc+1,ik)
IF ( MODULO(psi_source(ig+prev),nproc_egrp).eq.me_egrp ) THEN
count = count + 1
END IF
END DO
!
! allocate the communication packet
!
comm_send(iproc+1,ik)%size = count
IF (count.gt.0) THEN
IF (.not.ALLOCATED(comm_send(iproc+1,ik)%msg)) THEN
ALLOCATE(comm_send(iproc+1,ik)%indices(count))
ALLOCATE(comm_send(iproc+1,ik)%msg(count,npol,max_ibands+2))
END IF
END IF
!
! determine which values need to be sent to iproc
!
count = 0
DO ig=1, lda_exx(iproc+1,ik)
IF ( MODULO(psi_source(ig+prev),nproc_egrp).eq.me_egrp ) THEN
count = count + 1
comm_send(iproc+1,ik)%indices(count) = l2e_map(ig+prev,ik)
END IF
END DO
!
prev = prev + lda_exx(iproc+1,ik)
!
END DO
!
END DO
!
! allocate psi_exx and hpsi_exx
!
IF(allocated(psi_exx))DEALLOCATE(psi_exx)
ALLOCATE(psi_exx(npwx*npol, max_ibands ))
IF(allocated(hpsi_exx))DEALLOCATE(hpsi_exx)
ALLOCATE(hpsi_exx(npwx*npol, max_ibands ))
!
! allocate communication arrays for the exx to local transformation
!
IF ( .not.allocated(comm_recv_reverse) ) THEN
ALLOCATE(comm_recv_reverse(nproc_egrp,nks))
ALLOCATE(comm_send_reverse(nproc_egrp,negrp,nks))
END IF
!
egrp_base = my_egrp_id*nproc_egrp
DO ik = 1, nks
total_lda_egrp(ik) = &
sum( lda_local(egrp_base+1:(egrp_base+nproc_egrp),ik) )
prev_lda_egrp(ik) = &
sum( lda_local(egrp_base+1:(egrp_base+me_egrp),ik) )
END DO
!
max_lda_egrp = 0
DO j = 1, negrp
DO ik = 1, nks
max_lda_egrp = max(max_lda_egrp, &
sum( lda_local((j-1)*nproc_egrp+1:j*nproc_egrp,ik) ) )
END DO
END DO
!
! determine the e2l_map
!
allocate( e2l_map(max_lda_egrp,nks,negrp) )
e2l_map = 0
DO ik = 1, nks
DO ig = 1, lda_local(me_pool+1,ik)
DO j=1, total_lda_exx(ik)
IF( local_map(ig+prev_lda(ik),ik).EQ.exx_map(j,ik) ) exit
END DO
e2l_map(ig+prev_lda_egrp(ik),ik,my_egrp_id+1) = j
END DO
END DO
CALL mp_sum(e2l_map(:,:,my_egrp_id+1),intra_egrp_comm)
CALL mp_sum(e2l_map,inter_egrp_comm)
!
! plan communication for the local to EXX data structure transformation
!
allocate(psi_source_exx( max_lda_egrp, negrp ))
DO ik = 1, nks
!
! determine where each value is coming from
!
psi_source_exx = 0
DO ig = 1, lda_local(me_pool+1,ik)
j = 1
DO i = 1, nproc_egrp
j = j + lda_exx(i,ik)
IF( j.gt.e2l_map(ig+prev_lda_egrp(ik),ik,my_egrp_id+1) ) exit
END DO
psi_source_exx(ig+prev_lda_egrp(ik),my_egrp_id+1) = i-1
END DO
CALL mp_sum(psi_source_exx(:,my_egrp_id+1),intra_egrp_comm)
CALL mp_sum(psi_source_exx,inter_egrp_comm)
!
! allocate communication packets to receive psi and hpsi (reverse)
!
DO iegrp=my_egrp_id+1, my_egrp_id+1
DO iproc=0, nproc_egrp-1
!
! determine how many values need to come from iproc
!
count = 0
DO ig=1, lda_local(me_pool+1,ik)
IF ( psi_source_exx(ig+prev_lda_egrp(ik),iegrp).eq.iproc ) THEN
count = count + 1
END IF
END DO
!
! allocate the communication packet
!
comm_recv_reverse(iproc+1,ik)%size = count
IF (count.gt.0) THEN
IF (.not.ALLOCATED(comm_recv_reverse(iproc+1,ik)%msg)) THEN
ALLOCATE(comm_recv_reverse(iproc+1,ik)%indices(count))
ALLOCATE(comm_recv_reverse(iproc+1,ik)%msg(count,npol,m+2))
END IF
END IF
!
! determine which values need to come from iproc
!
count = 0
DO ig=1, lda_local(me_pool+1,ik)
IF ( psi_source_exx(ig+prev_lda_egrp(ik),iegrp).eq.iproc ) THEN
count = count + 1
comm_recv_reverse(iproc+1,ik)%indices(count) = ig
END IF
END DO
END DO
END DO
!
! allocate communication packets to send psi and hpsi
!
DO iegrp=1, negrp
prev = 0
DO iproc=0, nproc_egrp-1
!
! determine how many values need to be sent to iproc
!
count = 0
DO ig=1, lda_local(iproc+(iegrp-1)*nproc_egrp+1,ik)
IF ( psi_source_exx(ig+prev,iegrp).eq.me_egrp ) THEN
count = count + 1
END IF
END DO
!
! allocate the communication packet
!
comm_send_reverse(iproc+1,iegrp,ik)%size = count
IF (count.gt.0) THEN
IF (.not.ALLOCATED(comm_send_reverse(iproc+1,iegrp,ik)%msg))THEN
ALLOCATE(comm_send_reverse(iproc+1,iegrp,ik)%indices(count))
ALLOCATE(comm_send_reverse(iproc+1,iegrp,ik)%msg(count,npol,&
iexx_iend(my_egrp_id+1)-iexx_istart(my_egrp_id+1)+3))
END IF
END IF
!
! determine which values need to be sent to iproc
!
count = 0
DO ig=1, lda_local(iproc+(iegrp-1)*nproc_egrp+1,ik)
IF ( psi_source_exx(ig+prev,iegrp).eq.me_egrp ) THEN
count = count + 1
comm_send_reverse(iproc+1,iegrp,ik)%indices(count) = &
e2l_map(ig+prev,ik,iegrp)
END IF
END DO
!
prev = prev + lda_local( (iegrp-1)*nproc_egrp+iproc+1, ik )
!
END DO
END DO
!
END DO
!
! deallocate arrays
!
DEALLOCATE( local_map, exx_map )
DEALLOCATE( l2e_map, e2l_map )
DEALLOCATE( psi_source, psi_source_exx )
!
END SUBROUTINE initialize_local_to_exact_map
!
!
!-----------------------------------------------------------------------
SUBROUTINE transform_to_exx( lda, n, m, m_out, ik, psi, psi_out, type )
!-----------------------------------------------------------------------
!! Transform psi into the EXX data structure, and place the result
!! in psi_out.
!
USE wvfct, ONLY : nbnd
USE mp, ONLY : mp_sum
USE mp_pools, ONLY : nproc_pool, me_pool
USE mp_exx, ONLY : intra_egrp_comm, inter_egrp_comm, &
nproc_egrp, me_egrp, negrp, my_egrp_id, &
nibands, ibands, max_ibands, all_start, &
all_end
USE parallel_include
!
IMPLICIT NONE
!
Integer :: lda
INTEGER :: n, m, m_out
COMPLEX(DP) :: psi(npwx_local*npol,m)
COMPLEX(DP) :: psi_out(npwx_exx*npol,m_out)
INTEGER, INTENT(in) :: type
COMPLEX(DP), ALLOCATABLE :: psi_work(:,:,:,:), psi_gather(:,:)
INTEGER :: i, j, im, iproc, ig, ik, iegrp
INTEGER :: prev, lda_max_local
INTEGER :: request_send(nproc_egrp), request_recv(nproc_egrp)
INTEGER :: ierr
INTEGER :: current_ik
!INTEGER, EXTERNAL :: find_current_k
INTEGER :: recvcount(negrp)
INTEGER :: displs(negrp)
#if defined(__MPI)
INTEGER :: istatus(MPI_STATUS_SIZE)
#endif
INTEGER :: requests(max_ibands+2,negrp)
!
INTEGER :: ipol, my_lda, lda_offset, count
lda_max_local = maxval(lda_local)
current_ik = ik
!
!-------------------------------------------------------!
!Communication Part 1
!-------------------------------------------------------!
!
allocate(psi_work(lda_max_local,npol,m,negrp))
allocate(psi_gather(lda_max_local*npol,m))
DO im=1, m
my_lda = lda_local(me_pool+1,current_ik)
DO ipol=1, npol
lda_offset = lda_max_local*(ipol-1)
DO ig=1, my_lda
psi_gather(lda_offset+ig,im) = psi(npwx_local*(ipol-1)+ig,im)
END DO
END DO
END DO
recvcount = lda_max_local*npol
count = lda_max_local*npol
#if defined (__MPI_NONBLOCKING)
IF ( type.eq.0 ) THEN
DO iegrp=1, negrp
displs(iegrp) = (iegrp-1)*(count*m)
END DO
DO iegrp=1, negrp
DO im=1, nibands(iegrp)
IF ( my_egrp_id.eq.(iegrp-1) ) THEN
DO j=1, negrp
displs(j) = (j-1)*(count*m) + count*(ibands(im,iegrp)-1)
END DO
END IF
#if defined(__MPI)
CALL MPI_IGATHERV( psi_gather(:, ibands(im,iegrp) ), &
count, MPI_DOUBLE_COMPLEX, &
psi_work, &
recvcount, displs, MPI_DOUBLE_COMPLEX, &
iegrp-1, &
inter_egrp_comm, requests(im,iegrp), ierr )
#endif
END DO
END DO
ELSE IF(type.eq.1) THEN
#elif defined(__MPI)
CALL MPI_ALLGATHER( psi_gather, &
count*m, MPI_DOUBLE_COMPLEX, &
psi_work, &
count*m, MPI_DOUBLE_COMPLEX, &
inter_egrp_comm, ierr )
#endif
#if defined (__MPI_NONBLOCKING)
ELSE IF(type.eq.2) THEN !evc2
DO iegrp=1, negrp
displs(iegrp) = (iegrp-1)*(count*m)
END DO
DO iegrp=1, negrp
DO im=1, all_end(iegrp) - all_start(iegrp) + 1
!
IF(all_start(iegrp).eq.0) CYCLE
!
IF ( my_egrp_id.eq.(iegrp-1) ) THEN
DO j=1, negrp
displs(j) = (j-1)*(count*m) + count*(im+all_start(iegrp)-2)
END DO
END IF
#if defined(__MPI)
CALL MPI_IGATHERV( psi_gather(:, im+all_start(iegrp)-1 ), &
count, MPI_DOUBLE_COMPLEX, &
psi_work, &
recvcount, displs, MPI_DOUBLE_COMPLEX, &
iegrp-1, &
inter_egrp_comm, requests(im,iegrp), ierr )
#endif
END DO
END DO
END IF
!
IF(type.eq.0)THEN
DO iegrp=1, negrp
DO im=1, nibands(iegrp)
CALL MPI_WAIT(requests(im,iegrp), istatus, ierr)
END DO
END DO
ELSEIF(type.eq.2)THEN
DO iegrp=1, negrp
DO im=1, all_end(iegrp) - all_start(iegrp) + 1
IF(all_start(iegrp).eq.0) CYCLE
CALL MPI_WAIT(requests(im,iegrp), istatus, ierr)
END DO
END DO
END IF
#endif
!
!-------------------------------------------------------!
!Communication Part 2
!-------------------------------------------------------!
!
!send communication packets
!
DO iproc=0, nproc_egrp-1
!
!prepare receive buffers
!
IF ( comm_recv(iproc+1,current_ik)%size.gt.0) THEN
#if defined(__MPI)
IF (type.eq.0) THEN !psi or hpsi
CALL MPI_IRECV( comm_recv(iproc+1,current_ik)%msg, &
comm_recv(iproc+1,current_ik)%size*npol*nibands(my_egrp_id+1), &
MPI_DOUBLE_COMPLEX, &
iproc, 100+me_egrp*nproc_egrp+iproc, &
intra_egrp_comm, request_recv(iproc+1), ierr )
ELSE IF (type.eq.1) THEN !evc
CALL MPI_IRECV( comm_recv(iproc+1,current_ik)%msg, &
comm_recv(iproc+1,current_ik)%size*npol*m, MPI_DOUBLE_COMPLEX, &
iproc, 100+me_egrp*nproc_egrp+iproc, &
intra_egrp_comm, request_recv(iproc+1), ierr )
ELSE IF (type.eq.2) THEN !evc2
CALL MPI_IRECV( comm_recv(iproc+1,current_ik)%msg, &
comm_recv(iproc+1,current_ik)%size*npol*(all_end(my_egrp_id+1)-all_start(my_egrp_id+1)+1), &
MPI_DOUBLE_COMPLEX, &
iproc, 100+me_egrp*nproc_egrp+iproc, &
intra_egrp_comm, request_recv(iproc+1), ierr )
END IF
#endif
!
END IF
!
!now do the actual sends
!
IF ( comm_send(iproc+1,current_ik)%size.gt.0) THEN
DO i=1, comm_send(iproc+1,current_ik)%size
ig = comm_send(iproc+1,current_ik)%indices(i)
!
!determine which egrp this corresponds to
!
prev = 0
DO j=1, nproc_pool
IF ((prev+lda_local(j,current_ik)).ge.ig) THEN
ig = ig - prev
exit
END IF
prev = prev + lda_local(j,current_ik)
END DO
!
! prepare the message
!
DO ipol=1, npol
IF ( type.eq.0 ) THEN !psi or hpsi
DO im=1, nibands(my_egrp_id+1)
comm_send(iproc+1,current_ik)%msg(i,ipol,im) = &
psi_work(ig,ipol,ibands(im,my_egrp_id+1),1+(j-1)/nproc_egrp)
END DO
ELSE IF (type.eq.1) THEN !evc
DO im=1, m
comm_send(iproc+1,current_ik)%msg(i,ipol,im) = &
psi_work(ig,ipol,im,1+(j-1)/nproc_egrp)
END DO
ELSE IF ( type.eq.2 ) THEN !evc2
IF(all_start(my_egrp_id+1).gt.0) THEN
DO im=1, all_end(my_egrp_id+1) - all_start(my_egrp_id+1) + 1
comm_send(iproc+1,current_ik)%msg(i,ipol,im) = &
psi_work(ig,ipol,im+all_start(my_egrp_id+1)-1,1+(j-1)/nproc_egrp)
END DO
END IF
END IF
END DO
!
END DO
!
! send the message
!
#if defined(__MPI)
IF ( type.eq.0 ) THEN !psi or hpsi
CALL MPI_ISEND( comm_send(iproc+1,current_ik)%msg, &
comm_send(iproc+1,current_ik)%size*npol*nibands(my_egrp_id+1), &
MPI_DOUBLE_COMPLEX, &
iproc, 100+iproc*nproc_egrp+me_egrp, &
intra_egrp_comm, request_send(iproc+1), ierr )
ELSE IF (type.eq.1) THEN !evc
CALL MPI_ISEND( comm_send(iproc+1,current_ik)%msg, &
comm_send(iproc+1,current_ik)%size*npol*m, MPI_DOUBLE_COMPLEX, &
iproc, 100+iproc*nproc_egrp+me_egrp, &
intra_egrp_comm, request_send(iproc+1), ierr )
ELSE IF (type.eq.2) THEN !evc2
CALL MPI_ISEND( comm_send(iproc+1,current_ik)%msg, &
comm_send(iproc+1,current_ik)%size*npol*(all_end(my_egrp_id+1)-all_start(my_egrp_id+1)+1), &
MPI_DOUBLE_COMPLEX, &
iproc, 100+iproc*nproc_egrp+me_egrp, &
intra_egrp_comm, request_send(iproc+1), ierr )
END IF
#endif
!
END IF
END DO
!
! begin receiving the messages
!
!
! assign psi_out
!
DO iproc=0, nproc_egrp-1
IF ( comm_recv(iproc+1,current_ik)%size.gt.0 ) THEN
!
! wait for the message to be received
!
#if defined(__MPI)
CALL MPI_WAIT(request_recv(iproc+1), istatus, ierr)
#endif
!
DO i=1, comm_recv(iproc+1,current_ik)%size
ig = comm_recv(iproc+1,current_ik)%indices(i)
!
! place the message into the correct elements of psi_out
!
IF (type.eq.0) THEN !psi or hpsi
DO im=1, nibands(my_egrp_id+1)
DO ipol=1, npol
psi_out(ig+npwx_exx*(ipol-1),im) = &
comm_recv(iproc+1,current_ik)%msg(i,ipol,im)
END DO
END DO
ELSE IF (type.eq.1) THEN !evc
DO im=1, m
DO ipol=1, npol
psi_out(ig+npwx_exx*(ipol-1),im) = &
comm_recv(iproc+1,current_ik)%msg(i,ipol,im)
END DO
END DO
ELSE IF (type.eq.2) THEN !evc2
DO im=1, all_end(my_egrp_id+1) - all_start(my_egrp_id+1) + 1
DO ipol=1, npol
psi_out(ig+npwx_exx*(ipol-1),im) = comm_recv(iproc+1,current_ik)%msg(i,ipol,im)
END DO
END DO
END IF
!
END DO
!
END IF
END DO
!
! wait for everything to finish sending
!
#if defined(__MPI)
DO iproc=0, nproc_egrp-1
IF ( comm_send(iproc+1,current_ik)%size.gt.0 ) THEN
CALL MPI_WAIT(request_send(iproc+1), istatus, ierr)
END IF
END DO
#endif
!
! deallocate arrays
!
DEALLOCATE( psi_work, psi_gather )
!
END SUBROUTINE transform_to_exx
!
!
!-----------------------------------------------------------------------
SUBROUTINE change_data_structure( is_exx )
!-----------------------------------------------------------------------
!! Change between the local and EXX data structures:
!
!! * is_exx = .TRUE. - change to the EXX data structure;
!! * is_exx = .FALSE. - change to the local data strucutre.
!
USE cell_base, ONLY : at, bg, tpiba2
USE cellmd, ONLY : lmovecell
USE wvfct, ONLY : npwx
USE gvect, ONLY : gcutm, ig_l2g, g, gg, ngm, ngm_g, mill, &
gstart, gvect_init, deallocate_gvect_exx, gshells
USE gvecs, ONLY : gcutms, ngms, ngms_g, gvecs_init
USE gvecw, ONLY : gkcut, ecutwfc, gcutw
USE klist, ONLY : xk, nks, ngk
USE mp_bands, ONLY : intra_bgrp_comm, ntask_groups, nyfft
USE mp_exx, ONLY : intra_egrp_comm, me_egrp, exx_mode, nproc_egrp, &
negrp, root_egrp
USE io_global, ONLY : stdout
USE fft_base, ONLY : dfftp, dffts, smap, fft_base_info
USE fft_types, ONLY : fft_type_init
USE recvec_subs, ONLY : ggen, ggens
USE command_line_options, ONLY : nmany_, pencil_decomposition_
!
!
IMPLICIT NONE
!
LOGICAL, intent(in) :: is_exx
INTEGER, EXTERNAL :: n_plane_waves
COMPLEX(DP), ALLOCATABLE :: work_space(:)
INTEGER :: ik, i
INTEGER :: ngm_, ngs_, ngw_
LOGICAL exst
#if defined (__MPI)
LOGICAL :: lpara = .true.
#else
LOGICAL :: lpara = .false.
#endif
!
IF (negrp.eq.1) RETURN
!
IF (first_data_structure_change) THEN
allocate( ig_l2g_loc(ngm), g_loc(3,ngm), gg_loc(ngm) )
allocate( mill_loc(3,ngm), nl_loc(ngm) )
allocate( nls_loc(size(dffts%nl)) )
IF ( gamma_only) THEN
allocate( nlm_loc(size(dfftp%nlm)) )
allocate( nlsm_loc(size(dffts%nlm)) )
END IF
ig_l2g_loc = ig_l2g
g_loc = g
gg_loc = gg
mill_loc = mill
nl_loc = dfftp%nl
nls_loc = dffts%nl
IF ( gamma_only) THEN