forked from gnuradio/gnuradio
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathCMakeLists.txt
147 lines (126 loc) · 5.71 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
# Copyright 2011,2013 Free Software Foundation, Inc.
#
# This file is part of GNU Radio
#
# SPDX-License-Identifier: GPL-3.0-or-later
#
include(GrComponent)
########################################################################
# Setup library
########################################################################
add_library(gnuradio-audio audio_registry.cc)
target_link_libraries(gnuradio-audio PUBLIC gnuradio-runtime)
target_include_directories(
gnuradio-audio PUBLIC $<INSTALL_INTERFACE:include>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/../include>)
list(APPEND gr_audio_confs ${CMAKE_CURRENT_SOURCE_DIR}/gr-audio.conf)
########################################################################
## ALSA Support
########################################################################
find_package(ALSA)
if((ALSA_FOUND)
AND NOT (CMAKE_SYSTEM_NAME STREQUAL "kFreeBSD")
AND NOT (CMAKE_SYSTEM_NAME STREQUAL GNU))
target_compile_definitions(gnuradio-audio PRIVATE -DALSA_FOUND)
target_link_libraries(gnuradio-audio PRIVATE ALSA::ALSA)
target_sources(
gnuradio-audio
PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/alsa/alsa_impl.cc
${CMAKE_CURRENT_SOURCE_DIR}/alsa/alsa_source.cc
${CMAKE_CURRENT_SOURCE_DIR}/alsa/alsa_sink.cc)
gr_append_subcomponent("alsa")
list(APPEND gr_audio_confs ${CMAKE_CURRENT_SOURCE_DIR}/alsa/gr-audio-alsa.conf)
endif()
########################################################################
## OSS Support
########################################################################
find_package(OSS)
if(OSS_FOUND)
target_compile_definitions(gnuradio-audio PRIVATE -DOSS_FOUND)
target_link_libraries(gnuradio-audio PRIVATE OSS::OSS)
target_sources(gnuradio-audio PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/oss/oss_source.cc
${CMAKE_CURRENT_SOURCE_DIR}/oss/oss_sink.cc)
gr_append_subcomponent("oss")
list(APPEND gr_audio_confs ${CMAKE_CURRENT_SOURCE_DIR}/oss/gr-audio-oss.conf)
endif(OSS_FOUND)
########################################################################
## Jack Support
########################################################################
find_package(JACK)
if(JACK_FOUND)
target_compile_definitions(gnuradio-audio PRIVATE -DJACK_FOUND)
target_link_libraries(gnuradio-audio PRIVATE JACK::JACK)
target_sources(
gnuradio-audio
PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/jack/jack_impl.cc
${CMAKE_CURRENT_SOURCE_DIR}/jack/jack_source.cc
${CMAKE_CURRENT_SOURCE_DIR}/jack/jack_sink.cc)
gr_append_subcomponent("jack")
list(APPEND gr_audio_confs ${CMAKE_CURRENT_SOURCE_DIR}/jack/gr-audio-jack.conf)
endif(JACK_FOUND)
########################################################################
## OSX Support
########################################################################
include(CheckIncludeFileCXX)
check_include_file_cxx(AudioUnit/AudioUnit.h AUDIO_UNIT_H)
check_include_file_cxx(AudioToolbox/AudioToolbox.h AUDIO_TOOLBOX_H)
if(AUDIO_UNIT_H AND AUDIO_TOOLBOX_H)
target_compile_definitions(gnuradio-audio PRIVATE -DOSX_FOUND)
target_link_libraries(
gnuradio-audio PUBLIC "-framework AudioUnit" "-framework CoreAudio"
"-framework AudioToolbox" "-framework Carbon")
target_sources(
gnuradio-audio
PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/osx/osx_impl.cc
${CMAKE_CURRENT_SOURCE_DIR}/osx/osx_source.cc
${CMAKE_CURRENT_SOURCE_DIR}/osx/osx_sink.cc)
gr_append_subcomponent("osx")
set(OSX_AUDIO_VALID
1
CACHE INTERNAL "OSX Audio is valid")
list(APPEND gr_audio_confs ${CMAKE_CURRENT_SOURCE_DIR}/osx/gr-audio-osx.conf)
else()
set(OSX_AUDIO_VALID
0
CACHE INTERNAL "OSX Audio is not valid")
endif()
########################################################################
## PortAudio Support
########################################################################
find_package(PORTAUDIO)
if(PORTAUDIO2_FOUND)
target_compile_definitions(gnuradio-audio PRIVATE -DPORTAUDIO_FOUND)
target_link_libraries(gnuradio-audio PRIVATE Portaudio::Portaudio)
target_sources(
gnuradio-audio
PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/portaudio/portaudio_impl.cc
${CMAKE_CURRENT_SOURCE_DIR}/portaudio/portaudio_source.cc
${CMAKE_CURRENT_SOURCE_DIR}/portaudio/portaudio_sink.cc)
gr_append_subcomponent("portaudio")
list(APPEND gr_audio_confs
${CMAKE_CURRENT_SOURCE_DIR}/portaudio/gr-audio-portaudio.conf)
endif(PORTAUDIO2_FOUND)
########################################################################
## Windows Support
########################################################################
if(WIN32)
target_compile_definitions(gnuradio-audio PRIVATE -DWIN32_FOUND)
target_link_libraries(gnuradio-audio PRIVATE winmm.lib)
target_sources(
gnuradio-audio PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/windows/windows_source.cc
${CMAKE_CURRENT_SOURCE_DIR}/windows/windows_sink.cc)
gr_append_subcomponent("windows")
#Add Windows DLL resource file if using MSVC
if(MSVC)
include(${PROJECT_SOURCE_DIR}/cmake/Modules/GrVersion.cmake)
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/gnuradio-audio.rc.in
${CMAKE_CURRENT_BINARY_DIR}/gnuradio-audio.rc @ONLY)
target_sources(gnuradio-audio
PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/gnuradio-audio.rc)
endif()
endif(WIN32)
if(ENABLE_COMMON_PCH)
target_link_libraries(gnuradio-audio PRIVATE common-precompiled-headers)
endif()
gr_library_foo(gnuradio-audio)
install(FILES ${gr_audio_confs} DESTINATION ${GR_PREFSDIR})