Add bolt example

Author: Martin Kraska

NonLinear/3PB/Refs/PEexpanded.png

@@ -0,0 +1,133 @@
+d = 10; // Nenndurchmesser
+s = 17; // Schluesselweite
+k = 7; // Kopfhoehe
+m = 0.8*d; // Mutternhoehe
+
+db = 11; //Bohrungsdurchmesser
+t1 = 10; //Plattendicke 1
+b1 = 40;
+l1 = 40;
+t2 = 15; //Plattendicke 2
+b2 = 50;
+l2 = 45;
+
+t3 = 10; //Stegdicke
+h3 = 30; //Steghoehe
+e = 20; //halber Schraubenabstand
+
+Point(1) = {e,0,-t2}; // Mittelpunkt der Schraube
+Point(2) = {e,0,t1+k};
+Point(3) = {e,s/2,t1+k};
+Point(4) = {e,s/2,t1};
+Point(5) = {e,d/2,t1};
+Point(6) = {e,d/2,-t2};
+Point(7) = {e,0,-t2-m};
+Point(8) = {e,s/2,-t2-m};
+Point(9) = {e,s/2,-t2};
+Line(1) = {1,2};
+Line(2) = {2,3};
+Line(3) = {3,4};
+Line(4) = {4,5};
+Line(5) = {5,6};
+Line(6) = {6,1};
+Line Loop(1) = {1,2,3,4,5,6};
+Plane Surface(1) ={1};
+Line(7) = {1,7};
+Line(8) = {7,8};
+Line(9) = {8,9};
+Line(10) = {9,6};
+Line Loop(2) = {7,8,9,10,6};
+Plane Surface(2) ={2};
+
+pc=newp;
+Point(pc) = {0,0,0};
+out[] = Extrude { {0,0,1}, {e,0,0}, Pi/2 } { Surface{1,2}; };
+out[] = Symmetry {0,1,0,0}  { Duplicata{ Volume{1,2}; } };
+out[] = Symmetry {-1,0,0,20}  { Duplicata{ Volume{1,2,98,60}; } };
+
+//Reverse Surface {84,145,181,120};
+
+Physical Surface("C_head") = {-84, 29, 245, -145};
+Physical Surface("C_nut") = {55, -120, -181, 212};
+
+// Platten
+// Platte 1
+// Aussenrand
+pp1 = newp;
+Point(pp1) = {0,b1/2,0};
+Point(pp1+1) = {l1,b1/2,0};
+Point(pp1+2) = {l1,-b1/2,0};
+Point(pp1+3) = {0,-b1/2,0};
+ll1 = newl;
+Line(ll1) = {pp1,pp1+1};
+Line(ll1+1) = {pp1+1,pp1+2};
+Line(ll1+2) = {pp1+2,pp1+3};
+Line(ll1+3) = {pp1+3,pp1};
+ll = newll;
+Line Loop(ll) = {ll1,ll1+1,ll1+2,ll1+3};
+// Bohrung
+pp1 = newp;
+Point(pp1) = {e,0,0};
+Point(pp1+1) = {e,db/2,0};
+Point(pp1+2) = {e+db/2,0,0};
+Point(pp1+3) = {e,-db/2,0};
+Point(pp1+4) = {e-db/2,0,0};
+ll1 = newl;
+Circle(ll1) = {pp1+1,pp1,pp1+2};
+Circle(ll1+1) = {pp1+2,pp1,pp1+3};
+Circle(ll1+2) = {pp1+3,pp1,pp1+4};
+Circle(ll1+3) = {pp1+4,pp1,pp1+1};
+Line Loop(ll+1) = {ll1,ll1+1,ll1+2,ll1+3};
+ns = news;
+Plane Surface(ns) ={ll,ll+1};
+Out[] = Extrude {0,0,t1} { Surface{ns}; };
+
+// Platte 2
+// Aussenrand
+eps = -0.001;
+pp1 = newp;
+Point(pp1) = {0,b2/2,eps};
+Point(pp1+1) = {l2,b2/2,eps};
+Point(pp1+2) = {l2,-b2/2,eps};
+Point(pp1+3) = {0,-b2/2,eps};
+ll1 = newl;
+Line(ll1) = {pp1,pp1+1};
+Line(ll1+1) = {pp1+1,pp1+2};
+Line(ll1+2) = {pp1+2,pp1+3};
+Line(ll1+3) = {pp1+3,pp1};
+ll = newll;
+Line Loop(ll) = {ll1,ll1+1,ll1+2,ll1+3};
+// Bohrung
+pp1 = newp;
+Point(pp1) = {e,0,eps};
+Point(pp1+1) = {e,db/2,eps};
+Point(pp1+2) = {e+db/2,0,eps};
+Point(pp1+3) = {e,-db/2,eps};
+Point(pp1+4) = {e-db/2,0,eps};
+ll1 = newl;
+Circle(ll1) = {pp1+1,pp1,pp1+2};
+Circle(ll1+1) = {pp1+2,pp1,pp1+3};
+Circle(ll1+2) = {pp1+3,pp1,pp1+4};
+Circle(ll1+3) = {pp1+4,pp1,pp1+1};
+Line Loop(ll+1) = {ll1,ll1+1,ll1+2,ll1+3};
+ns = news;
+Plane Surface(ns) = {ll,ll+1};
+Out[] = Extrude {0,0,-t2} { Surface{ns}; };
+
+Physical Surface("sym1") = {285};
+Physical Surface("sym2") = {337};
+Physical Surface("c1o") = {302};
+Physical Surface("c1u") = {260};
+Physical Surface("c2o") = {312};
+Physical Surface("c2u") = {354};
+Physical Surface("c2r") = {329};
+Physical Volume("bolt") = {1,2,60,121,221,98,159,190};
+Physical Volume("p1") = {222};
+Physical Volume("p2") = {223};
+
+Mesh.ElementOrder = 2;
+Mesh 3;
+	
+Mesh.SaveGroupsOfNodes = 1;
+
+Save "Bolt-gmsh.inp";

NonLinear/Bolt/Bolt.geo

@@ -0,0 +1,74 @@
+# Bolted Plates
+Tested with CGX 2.19 / CCX 2.19
+
++ Non-linear static analysis
++ Surface-to-surface penalty contact 
++ Thermal shrinkage for bolt pre-tension.
+
+
+File                         | Contents    
+ :-------------              | :-------------
+ [Bolt.geo](Bolt.geo)        | Gmsh script for geomentry and meshing
+ [pre.fbd](pre.fbd)          | CGX script, pre-processing
+ [post.fbd](post.fbd)        | CGX script, post-processing, movie
+ [thermal.inp](thermal.inp)  | CCX input
+ [test.py](test.py)          | python script to run the simulation  
+
+
+The model represents one half of two plates and two bolts. The lower plate is fixed at the outer sides, the upper plate is pulled up vertically in the center. The bolt is pre-stressed by thermal shrinkage. 
+
+<img src="expansion.png" width="500" title="expanded model">
+
+## Pre-Processing
+
+Contact surfaces and node sets for constraints:
+
+<img src="contact.png" width="400" title="Contact surfaces"> <img src="boundary.png" width="400" title="node sets">
+
+- `nsym1` and `nsym2` are set to UX=0 (symmetry)
+- `nc2r` is constrained to UY=UZ=0 (support)
+- In step 1, the bolt is cooled down to pre-tighten it.
+- In step 2, `nsym1` is displaced to UZ=0.001 (displacement-controlled loading)
+
+
+| Parameter | Value   | Meaning |
+| :-------- |  :----- | :------------- |
+| `d`       | 10      | nominal bolt diameter in mm |
+| `s`       | 17      | key-width of head and nut in mm|
+| `k`       | 7       | height of bolt head in mm |
+| `db`      | 11      | diameter of holes in mm |
+| `t1`      | 10      | thickness of upper plate in mm |
+| `b1`      | 40      | width of upper plate in mm |
+| `l1`      | 40      | length of upper plate in mm |
+| `t2`      | 15      | thickness of lower plate in mm |
+| `b2`      | 50      | width of lower plate in mm |
+| `l2`      | 45      | length of lower plate in mm |
+| `e`       | 20      | distance of bolt axis from plane of symmetry in mm |
+
+You may adjust the parameter values in the file [Bolt.geo](Bolt.geo) and then run
+```
+> gmsh Bolt.geo
+> cgx -b pre.fbd
+```
+
+## Solving
+
+```
+> ccx thermal
+> monitor.py thermal
+```
+<img src="thermal.png" title="Convergence plot">
+
+## Post-Processing
+
+```
+> cgx -b post.fbl
+```
+Stress and contact pressure after pre-tensioning
+
+<img width="400" src="se-bolt-pretension.png"  title="Equivalent stress"><img width="400" src="cpress-pretension.png"  title="contact pressure">
+
+Stress and contact pressure under external load
+
+<img width="400" src="se-bolt.png"  title="Equivalent stress"><img width="400" src="cpress.png"  title="contact pressure">
+

NonLinear/Bolt/README.md

@@ -0,0 +1,43 @@
+read thermal.frd
+read thermal.inp nom
+# document pre-tension
+comp Nbolt do
+
+view ill
+
+rot y
+rot u 20
+rot l 20
+view disp 
+scal d 100
+
+ds 6 e 7
+plot fv Nbolt
+min 0
+max 200
+hcpy png se-bolt-pretension
+
+ds -3 e 7
+plot fv Nbolt
+min 0
+max 200
+hcpy png se-bolt
+
+
+plot fv all
+min 0
+max 200
+hcpy png se-all
+
+ds 7 e 4
+plot fv +cont1
+min 0
+max 200
+hcpy png cpress-pretension
+
+
+ds -2 e 4
+plot fv +cont1
+min 0
+max 200
+hcpy png cpress

NonLinear/Bolt/boundary.png

@@ -0,0 +1,71 @@
+read Bolt-gmsh.inp
+zap +CPS6
+# contact surfaces
+comp C_head do
+send C_head abq surf
+comp C_nut do
+send C_nut abq surf
+comp c1o do
+send c1o abq surf
+comp c1u do
+send c1u abq surf
+comp c2o do
+send c2o abq surf
+comp c2u do
+send c2u abq surf
+
+# node sets for boundary conditions
+seta nc2r n c2r
+send nc2r abq nam
+seta nsym1 n sym1
+send nsym1 abq nam
+seta nsym2 n sym2
+send nsym2 abq nam
+
+# correct position of p2
+move p2 tra 0 0 0.001
+
+# constraint node for the bolt
+seta nbolt n bolt
+enq nbolt nfix rec 20 0 17 1
+send nfix abq nam
+enq nbolt nfix1 rec 28.5 0 17 1
+send nfix1 abq nam
+
+#constraint node for p1
+seta np1 n p1
+enq np1 nfixp1 rec 0 20 0 1
+send nfixp1 abq nam
+
+# elements
+send p1 abq
+send p2 abq
+send bolt abq
+
+# parts plot
+seta ! all
+rot y
+rot l 15
+rot u 15
+hcpy png parts
+
+# plot contact
+ulin slave (red), master (blue)
+view ill on
+plot fb C_head r 50
+plus fb c1o b 50
+plus fb c1u r 50
+plus fb c2o b 50
+plus fb c2u b 50
+plus fb C_nut r 50
+hcpy png contact
+
+# plot boundary
+ulin nsym1 (red), nsym2 (green), nc2r (blue)
+plot n nsym1 r 
+plus n nsym2 g
+plus n nc2r b
+plus fb all n 20
+hcpy png boundary
+
+

NonLinear/Bolt/contact.png

@@ -0,0 +1,50 @@
+#!/usr/bin/env python
+import os
+import multiprocessing
+import shutil
+
+
+# Provide access to the helper scripts
+def modify_path():
+    scripts_dir = os.path.dirname(__file__)
+    while not 'Scripts' in os.listdir(scripts_dir):
+        scripts_dir = os.path.abspath(os.path.join(scripts_dir, '..'))
+    scripts_dir = os.path.join(scripts_dir, 'Scripts')
+    if not scripts_dir in os.environ['PATH']:
+        os.environ['PATH'] += os.pathsep + scripts_dir
+    print('\nPATH = {}\n'.format(os.environ['PATH']))
+
+
+# Move new files and folders to 'Refs'
+def move(old_snap):
+    new_snap = os.listdir(os.curdir)
+    if not os.path.exists('Refs'):
+        os.mkdir('Refs')
+    for f in new_snap:
+        if not f in old_snap:
+            fname = os.path.basename(f)
+            new_name = os.path.join(os.curdir, 'Refs', fname)
+            if os.path.isfile(new_name):
+                os.remove(new_name)
+            if os.path.isdir(new_name):
+                shutil.rmtree(new_name)
+            os.rename(f, new_name)
+
+
+if __name__ == '__main__':
+
+    # Enable multithreading for ccx
+    os.environ['OMP_NUM_THREADS'] = str(multiprocessing.cpu_count())
+
+    # Explicitly move to example's directory
+    os.chdir(os.path.dirname(__file__))
+
+    # Run the example
+    modify_path()
+    snap = os.listdir(os.curdir)
+    os.system("gmsh Bolt.geo")
+    os.system("cgx -b pre.fbd")
+    os.system("ccx thermal")
+    os.system("monitor.py thermal")
+    os.system("cgx -b post.py")
+    #move(snap)