build.gradle

/*
 * Licensed to Elasticsearch under one or more contributor
 * license agreements. See the NOTICE file distributed with
 * this work for additional information regarding copyright
 * ownership. Elasticsearch licenses this file to you under
 * the Apache License, Version 2.0 (the "License"); you may
 * not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing,
 * software distributed under the License is distributed on an
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 * KIND, either express or implied.  See the License for the
 * specific language governing permissions and limitations
 * under the License.
 */

subprojects {
    // Apply root build plugin to grab ES versions at the very least
    apply plugin: 'es.hadoop.build'

    // QA projects will not have distributions to speak of.
    Task distributionTasks = getTasks().findByName('distribution')
    if (distributionTasks) {
        distributionTasks.setEnabled(false)
    }

    // We're gonna need the es build tools as part of the build scripts here to take advantage of
    // all the fixture tasks. Add a build script dependency for it. Be sensitive of pulling it from
    // a local repo if we're currently in the release manager (unlikely, but be future proof).
    buildscript {
        boolean localRepo = project.getProperties().containsKey("localRepo")
        repositories {
            gradlePluginPortal()
            mavenCentral()
            if (localRepo) {
                // For some reason the root dirs all point to the buildSrc folder. The local Repo will be one above that.
                flatDir { dirs new File(project.rootProject.rootDir, "localRepo") }
            } else {
                maven { url = "https://oss.sonatype.org/content/repositories/snapshots" }
                maven { url = "https://artifacts-snapshot.elastic.co/elasticsearch/${version}/maven" }
            }
        }
        dependencies {
            if (localRepo) {
                classpath name: "build-tools-${version}"
            } else {
                classpath group: 'org.elasticsearch.gradle', name: 'build-tools', version: project.ext.buildToolsVersion
            }
        }
    }
}