firebase-storage.gradle

// Copyright 2018 Google LLC
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//      http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

plugins {
    id 'firebase-library'
    id("kotlin-android")
    id 'com.google.protobuf'
    id("copy-google-services")
}

firebaseLibrary {
    libraryGroup = "storage"
    testLab.enabled = true
    publishJavadoc = true
    releaseNotes {
        name.set("{{firebase_storage_full}}")
        versionName.set("storage")
    }
}

android {
    adbOptions {
        timeOutInMs 60 * 1000
    }

    namespace "com.google.firebase.storage"
    compileSdkVersion project.compileSdkVersion
    defaultConfig {
        targetSdkVersion project.targetSdkVersion
        minSdkVersion project.minSdkVersion
        multiDexEnabled true
        versionName version
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }

    buildTypes {
        release {
        }
        debug {
        }
    }
    sourceSets {
        androidTest {
            java {
                srcDir 'src/androidTest/java'
                srcDir 'src/testUtil/java'
                //We need this since FirebaseApp rule is externalized
                //TODO(ashwinraghav) b/113079738
                srcDir '../firebase-common/src/testUtil'
            }
        }

        test {
            java {
                srcDir 'src/testUtil/java'
                //We need this since FirebaseApp rule is externalized
                //TODO(ashwinraghav) b/113079738
                srcDir '../firebase-common/src/testUtil'
            }
            resources {
                srcDirs "src/test/resources"
            }
        }

        testOptions.unitTests.includeAndroidResources = true
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    kotlinOptions { jvmTarget = "1.8" }
}

dependencies {
    javadocClasspath libs.autovalue.annotations
    javadocClasspath libs.findbugs.jsr305

    api("com.google.firebase:firebase-annotations:16.2.0")
    api("com.google.firebase:firebase-appcheck:17.1.0") {
        exclude group: "com.google.firebase", module: "firebase-common"
        exclude group: "com.google.firebase", module: "firebase-components"
        exclude group: "com.google.firebase", module: "firebase-annotations"
    }
    api("com.google.firebase:firebase-appcheck-interop:17.1.0")
    api('com.google.firebase:firebase-auth-interop:18.0.0') {
         exclude group: "com.google.firebase", module: "firebase-common"
         exclude group: "com.google.firebase", module: "firebase-components"
         exclude group: "com.google.firebase", module: "firebase-annotations"
     }
    api("com.google.firebase:firebase-common:21.0.0")
    api("com.google.firebase:firebase-common-ktx:21.0.0")
    api("com.google.firebase:firebase-components:18.0.0")

    implementation libs.androidx.annotation
    implementation libs.playservices.base
    implementation libs.playservices.tasks
    implementation libs.kotlin.stdlib
    implementation libs.kotlinx.coroutines.core

    testImplementation libs.androidx.test.core
    testImplementation libs.androidx.test.rules
    testImplementation libs.truth
    testImplementation libs.junit
    testImplementation libs.mockito.core
    testImplementation libs.robolectric

    androidTestImplementation libs.androidx.annotation
    androidTestImplementation libs.androidx.test.rules
    androidTestImplementation libs.androidx.test.runner
    androidTestImplementation libs.truth
    androidTestImplementation libs.junit
}