forked from kshedstrom/roms
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathad_prsgrd31.h
805 lines (791 loc) · 37.1 KB
/
ad_prsgrd31.h
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
SUBROUTINE ad_prsgrd (ng, tile)
!
!svn $Id$
!************************************************** Hernan G. Arango ***
! Copyright (c) 2002-2020 The ROMS/TOMS Group Andrew M. Moore !
! Licensed under a MIT/X style license !
! See License_ROMS.txt !
!***********************************************************************
! !
! This routine evalutes the adjoint baroclinic hydrostatic pressure !
! gradient term using the standard and weighted Jacobians scheme of !
! Song and Wright (1997). Notice that horizontal gradients are !
! computed before of the vertical integration. !
! !
! The pressure gradient terms (m4/s2) are loaded into right-hand- !
! side arrays "ad_ru" and "ad_rv". !
! !
! Reference: !
! !
! Song, Y.T. and D.G. Wright, 1997: A general pressure gradient !
! formutlation for numerical ocean models. Part I: Scheme !
! design and diagnostic analysis. DRAFT. !
! !
! BASIC STATE variables needed: Hz, rho, z_r, z_w !
! !
!***********************************************************************
!
USE mod_param
#ifdef DIAGNOSTICS
!! USE mod_diags
#endif
#ifdef ATM_PRESS
USE mod_forces
#endif
USE mod_grid
USE mod_ocean
USE mod_stepping
!
! Imported variable declarations.
!
integer, intent(in) :: ng, tile
!
! Local variable declarations.
!
#include "tile.h"
!
#ifdef PROFILE
CALL wclock_on (ng, iADM, 23, __LINE__, __FILE__)
#endif
CALL ad_prsgrd_tile (ng, tile, &
& LBi, UBi, LBj, UBj, &
& IminS, ImaxS, JminS, JmaxS, &
& nrhs(ng), &
& GRID(ng) % om_v, &
& GRID(ng) % on_u, &
& GRID(ng) % Hz, &
& GRID(ng) % ad_Hz, &
& GRID(ng) % z_r, &
& GRID(ng) % ad_z_r, &
& GRID(ng) % z_w, &
& GRID(ng) % ad_z_w, &
& OCEAN(ng) % rho, &
& OCEAN(ng) % ad_rho, &
#ifdef ATM_PRESS
& FORCES(ng) % Pair, &
#endif
#ifdef DIAGNOSTICS_UV
!! & DIAGS(ng) % DiaRU, &
!! & DIAGS(ng) % DiaRV, &
#endif
& OCEAN(ng) % ad_ru, &
& OCEAN(ng) % ad_rv)
#ifdef PROFILE
CALL wclock_off (ng, iADM, 23, __LINE__, __FILE__)
#endif
RETURN
END SUBROUTINE ad_prsgrd
!
!***********************************************************************
SUBROUTINE ad_prsgrd_tile (ng, tile, &
& LBi, UBi, LBj, UBj, &
& IminS, ImaxS, JminS, JmaxS, &
& nrhs, &
& om_v, on_u, &
& Hz, ad_Hz, &
& z_r, ad_z_r, &
& z_w, ad_z_w, &
& rho, ad_rho, &
#ifdef ATM_PRESS
& Pair, &
#endif
#ifdef DIAGNOSTICS_UV
!! & DiaRU, DiaRV, &
#endif
& ad_ru, ad_rv)
!***********************************************************************
!
USE mod_param
USE mod_scalars
!
! Imported variable declarations.
!
integer, intent(in) :: ng, tile
integer, intent(in) :: LBi, UBi, LBj, UBj
integer, intent(in) :: IminS, ImaxS, JminS, JmaxS
integer, intent(in) :: nrhs
#ifdef ASSUMED_SHAPE
real(r8), intent(in) :: om_v(LBi:,LBj:)
real(r8), intent(in) :: on_u(LBi:,LBj:)
real(r8), intent(in) :: Hz(LBi:,LBj:,:)
real(r8), intent(in) :: z_r(LBi:,LBj:,:)
real(r8), intent(in) :: z_w(LBi:,LBj:,0:)
real(r8), intent(in) :: rho(LBi:,LBj:,:)
# ifdef ATM_PRESS
real(r8), intent(in) :: Pair(LBi:,LBj:)
# endif
# ifdef DIAGNOSTICS_UV
!! real(r8), intent(inout) :: DiaRU(LBi:,LBj:,:,:,:)
!! real(r8), intent(inout) :: DiaRV(LBi:,LBj:,:,:,:)
# endif
real(r8), intent(inout) :: ad_Hz(LBi:,LBj:,:)
real(r8), intent(inout) :: ad_z_r(LBi:,LBj:,:)
real(r8), intent(inout) :: ad_z_w(LBi:,LBj:,0:)
real(r8), intent(inout) :: ad_rho(LBi:,LBj:,:)
real(r8), intent(inout) :: ad_ru(LBi:,LBj:,0:,:)
real(r8), intent(inout) :: ad_rv(LBi:,LBj:,0:,:)
#else
real(r8), intent(in) :: om_v(LBi:UBi,LBj:UBj)
real(r8), intent(in) :: on_u(LBi:UBi,LBj:UBj)
real(r8), intent(in) :: Hz(LBi:UBi,LBj:UBj,N(ng))
real(r8), intent(in) :: z_r(LBi:UBi,LBj:UBj,N(ng))
real(r8), intent(in) :: z_w(LBi:UBi,LBj:UBj,0:N(ng))
real(r8), intent(in) :: rho(LBi:UBi,LBj:UBj,N(ng))
# ifdef ATM_PRESS
real(r8), intent(in) :: Pair(LBi:UBi,LBj:UBj)
# endif
# ifdef DIAGNOSTICS_UV
!! real(r8), intent(inout) :: DiaRU(LBi:UBi,LBj:UBj,N(ng),2,NDrhs)
!! real(r8), intent(inout) :: DiaRV(LBi:UBi,LBj:UBj,N(ng),2,NDrhs)
# endif
real(r8), intent(inout) :: ad_Hz(LBi:UBi,LBj:UBj,N(ng))
real(r8), intent(inout) :: ad_z_r(LBi:UBi,LBj:UBj,N(ng))
real(r8), intent(inout) :: ad_z_w(LBi:UBi,LBj:UBj,0:N(ng))
real(r8), intent(inout) :: ad_rho(LBi:UBi,LBj:UBj,N(ng))
real(r8), intent(inout) :: ad_ru(LBi:UBi,LBj:UBj,0:N(ng),2)
real(r8), intent(inout) :: ad_rv(LBi:UBi,LBj:UBj,0:N(ng),2)
#endif
!
! Local variable declarations.
!
integer :: i, j, k, kk
real(r8) :: fac, fac1, fac2, fac3
real(r8) :: cff1, cff2, cff3, cff4
real(r8) :: adfac, adfac1, adfac2
real(r8) :: ad_cff1, ad_cff2, ad_cff3, ad_cff4
#ifdef WJ_GRADP
real(r8) :: gamma, ad_gamma
#endif
real(r8), dimension(IminS:ImaxS) :: phie
real(r8), dimension(IminS:ImaxS) :: phix
real(r8), dimension(IminS:ImaxS) :: ad_phie
real(r8), dimension(IminS:ImaxS) :: ad_phix
#include "set_bounds.h"
!
!-----------------------------------------------------------------------
! Initialize adjoint private variables.
!-----------------------------------------------------------------------
!
ad_cff1=0.0_r8
ad_cff2=0.0_r8
ad_cff3=0.0_r8
ad_cff4=0.0_r8
#ifdef WJ_GRADP
ad_gamma=0.0_r8
#endif
DO i=IminS,ImaxS
ad_phie(i)=0.0_r8
ad_phix(i)=0.0_r8
END DO
!
!-----------------------------------------------------------------------
! Calculate adjoint pressure gradient in the ETA-direction (m4/s2).
!-----------------------------------------------------------------------
!
#ifdef ATM_PRESS
fac=100.0_r8/rho0
#endif
fac1=0.5_r8*g/rho0
fac2=1000.0_r8*g/rho0
fac3=0.25_r8*g/rho0
J_LOOP : DO j=Jstr,Jend
IF (j.ge.JstrV) THEN
!
! Compute appropriate BASIC STATE "phie". Notice that a reverse
! vertical integration of "phie" is carried out over kk-index.
!
!> DO k=N(ng)-1,1,-1
!>
DO k=1,N(ng)-1
DO i=Istr,Iend
cff1=z_w(i,j ,N(ng))-z_r(i,j ,N(ng))+ &
& z_w(i,j-1,N(ng))-z_r(i,j-1,N(ng))
phie(i)=fac1*(rho(i,j,N(ng))-rho(i,j-1,N(ng)))*cff1
#ifdef ATM_PRESS
phie(i)=phie(i)+fac*(Pair(i,j)-Pair(i,j-1))
#endif
#ifdef RHO_SURF
phie(i)=phie(i)+ &
& (fac2+fac1*(rho(i,j,N(ng))+rho(i,j-1,N(ng))))* &
& (z_w(i,j,N(ng))-z_w(i,j-1,N(ng)))
#endif
END DO
DO kk=N(ng)-1,k,-1
DO i=Istr,Iend
#ifdef WJ_GRADP
cff1=1.0_r8/((z_r(i,j ,kk+1)-z_r(i,j ,kk))* &
& (z_r(i,j-1,kk+1)-z_r(i,j-1,kk)))
cff2=z_r(i,j ,kk )-z_r(i,j-1,kk )+ &
& z_r(i,j ,kk+1)-z_r(i,j-1,kk+1)
cff3=z_r(i,j ,kk+1)-z_r(i,j ,kk )- &
& z_r(i,j-1,kk+1)+z_r(i,j-1,kk )
gamma=0.125_r8*cff1*cff2*cff3
cff1=(1.0_r8+gamma)*(rho(i,j,kk+1)-rho(i,j-1,kk+1))+ &
& (1.0_r8-gamma)*(rho(i,j,kk )-rho(i,j-1,kk ))
cff2=rho(i,j,kk+1)+rho(i,j-1,kk+1)- &
& rho(i,j,kk )-rho(i,j-1,kk )
cff3=z_r(i,j,kk+1)+z_r(i,j-1,kk+1)- &
& z_r(i,j,kk )-z_r(i,j-1,kk )
cff4=(1.0_r8+gamma)*(z_r(i,j,kk+1)-z_r(i,j-1,kk+1))+ &
& (1.0_r8-gamma)*(z_r(i,j,kk )-z_r(i,j-1,kk ))
phie(i)=phie(i)+ &
& fac3*(cff1*cff3-cff2*cff4)
#else
cff1=rho(i,j,kk+1)-rho(i,j-1,kk+1)+ &
& rho(i,j,kk )-rho(i,j-1,kk )
cff2=rho(i,j,kk+1)+rho(i,j-1,kk+1)- &
& rho(i,j,kk )-rho(i,j-1,kk )
cff3=z_r(i,j,kk+1)+z_r(i,j-1,kk+1)- &
& z_r(i,j,kk )-z_r(i,j-1,kk )
cff4=z_r(i,j,kk+1)-z_r(i,j-1,kk+1)+ &
& z_r(i,j,kk )-z_r(i,j-1,kk )
phie(i)=phie(i)+ &
& fac3*(cff1*cff3-cff2*cff4)
#endif
END DO
END DO
!
! Compute interior adjoint baroclinic pressure gradient. Differentiate
! and then vertically integrate.
!
DO i=Istr,Iend
#ifdef DIAGNOSTICS_UV
!! DiaRV(i,j,k,nrhs,M3pgrd)=rv(i,j,k,nrhs)
#endif
!> tl_rv(i,j,k,nrhs)=-0.5_r8*om_v(i,j)* &
!> & ((tl_Hz(i,j,k)+tl_Hz(i,j-1,k))* &
!> & phie(i)+ &
!> & (Hz(i,j,k)+Hz(i,j-1,k))* &
!> & tl_phie(i))
!>
adfac=-0.5_r8*om_v(i,j)*ad_rv(i,j,k,nrhs)
adfac1=adfac*phie(i)
ad_phie(i)=ad_phie(i)+ &
& (Hz(i,j,k)+Hz(i,j-1,k))*adfac
ad_Hz(i,j-1,k)=ad_Hz(i,j-1,k)+adfac1
ad_Hz(i,j ,k)=ad_Hz(i,j ,k)+adfac1
ad_rv(i,j,k,nrhs)=0.0_r8
#ifdef WJ_GRADP
cff1=1.0_r8/((z_r(i,j ,k+1)-z_r(i,j ,k))* &
& (z_r(i,j-1,k+1)-z_r(i,j-1,k)))
cff2=z_r(i,j ,k )-z_r(i,j-1,k )+ &
& z_r(i,j ,k+1)-z_r(i,j-1,k+1)
cff3=z_r(i,j ,k+1)-z_r(i,j ,k )- &
& z_r(i,j-1,k+1)+z_r(i,j-1,k )
gamma=0.125_r8*cff1*cff2*cff3
cff1=(1.0_r8+gamma)*(rho(i,j,k+1)-rho(i,j-1,k+1))+ &
& (1.0_r8-gamma)*(rho(i,j,k )-rho(i,j-1,k ))
cff2=rho(i,j,k+1)+rho(i,j-1,k+1)- &
& rho(i,j,k )-rho(i,j-1,k )
cff3=z_r(i,j,k+1)+z_r(i,j-1,k+1)- &
& z_r(i,j,k )-z_r(i,j-1,k )
cff4=(1.0_r8+gamma)*(z_r(i,j,k+1)-z_r(i,j-1,k+1))+ &
& (1.0_r8-gamma)*(z_r(i,j,k )-z_r(i,j-1,k ))
!> tl_phie(i)=tl_phie(i)+ &
!> & fac3*(tl_cff1*cff3+ &
!> & cff1*tl_cff3- &
!> & tl_cff2*cff4- &
!> & cff2*tl_cff4)
!>
adfac=fac3*ad_phie(i)
ad_cff1=ad_cff1+cff3*adfac
ad_cff2=ad_cff2-cff4*adfac
ad_cff3=ad_cff3+cff1*adfac
ad_cff4=ad_cff4-cff2*adfac
!> tl_cff4=tl_gamma*(z_r(i,j,k+1)-z_r(i,j-1,k+1)- &
!> & z_r(i,j,k )+z_r(i,j-1,k ))+ &
!> & (1.0_r8+gamma)*(tl_z_r(i,j ,k+1)- &
!> & tl_z_r(i,j-1,k+1))+ &
!> & (1.0_r8-gamma)*(tl_z_r(i,j ,k )- &
!> & tl_z_r(i,j-1,k ))
!> tl_cff3=tl_z_r(i,j,k+1)+tl_z_r(i,j-1,k+1)- &
!> & tl_z_r(i,j,k )-tl_z_r(i,j-1,k )
!>
adfac1=(1.0_r8+gamma)*ad_cff4
adfac2=(1.0_r8-gamma)*ad_cff4
ad_z_r(i,j-1,k )=ad_z_r(i,j-1,k )-adfac2-ad_cff3
ad_z_r(i,j ,k )=ad_z_r(i,j ,k )+adfac2-ad_cff3
ad_z_r(i,j-1,k+1)=ad_z_r(i,j-1,k+1)-adfac1+ad_cff3
ad_z_r(i,j ,k+1)=ad_z_r(i,j ,k+1)+adfac1+ad_cff3
ad_gamma=ad_gamma+ &
& (z_r(i,j,k+1)-z_r(i,j-1,k+1)- &
& z_r(i,j,k )+z_r(i,j-1,k ))*ad_cff4
ad_cff4=0.0_r8
ad_cff3=0.0_r8
!> tl_cff2=tl_rho(i,j,k+1)+tl_rho(i,j-1,k+1)- &
!> & tl_rho(i,j,k )-tl_rho(i,j-1,k )
!> tl_cff1=tl_gamma*(rho(i,j,k+1)-rho(i,j-1,k+1)- &
!> & rho(i,j,k )+rho(i,j-1,k ))+ &
!> & (1.0_r8+gamma)*(tl_rho(i,j ,k+1)- &
!> & tl_rho(i,j-1,k+1))+ &
!> & (1.0_r8-gamma)*(tl_rho(i,j ,k )- &
!> & tl_rho(i,j-1,k ))
!>
adfac1=(1.0_r8+gamma)*ad_cff1
adfac2=(1.0_r8-gamma)*ad_cff1
ad_rho(i,j-1,k )=ad_rho(i,j-1,k )-adfac2-ad_cff2
ad_rho(i,j ,k )=ad_rho(i,j ,k )+adfac2-ad_cff2
ad_rho(i,j-1,k+1)=ad_rho(i,j-1,k+1)-adfac1+ad_cff2
ad_rho(i,j ,k+1)=ad_rho(i,j ,k+1)+adfac1+ad_cff2
ad_gamma=ad_gamma+ &
& (rho(i,j,k+1)-rho(i,j-1,k+1)- &
& rho(i,j,k )+rho(i,j-1,k ))*ad_cff1
ad_cff2=0.0_r8
ad_cff1=0.0_r8
!
cff1=1.0_r8/((z_r(i,j ,k+1)-z_r(i,j ,k))* &
& (z_r(i,j-1,k+1)-z_r(i,j-1,k)))
cff2=z_r(i,j ,k )-z_r(i,j-1,k )+ &
& z_r(i,j ,k+1)-z_r(i,j-1,k+1)
cff3=z_r(i,j ,k+1)-z_r(i,j ,k )- &
& z_r(i,j-1,k+1)+z_r(i,j-1,k )
!> tl_gamma=0.125_r8*(tl_cff1*cff2*cff3+ &
!> & cff1*(tl_cff2*cff3+ &
!> & cff2*tl_cff3))
!>
adfac=0.125_r8*ad_gamma
adfac1=adfac*cff1
ad_cff3=ad_cff3+cff2*adfac1
ad_cff2=ad_cff2+cff3*adfac1
ad_cff1=ad_cff1+cff2*cff3*adfac
ad_gamma=0.0_r8
!> tl_cff3=tl_z_r(i,j ,k+1)-tl_z_r(i,j ,k )- &
!> & tl_z_r(i,j-1,k+1)+tl_z_r(i,j-1,k )
!> tl_cff2=tl_z_r(i,j ,k )-tl_z_r(i,j-1,k )+ &
!> & tl_z_r(i,j ,k+1)-tl_z_r(i,j-1,k+1)
!>
ad_z_r(i,j-1,k )=ad_z_r(i,j-1,k )-ad_cff2+ad_cff3
ad_z_r(i,j ,k )=ad_z_r(i,j ,k )+ad_cff2-ad_cff3
ad_z_r(i,j-1,k+1)=ad_z_r(i,j-1,k+1)-ad_cff2-ad_cff3
ad_z_r(i,j ,k+1)=ad_z_r(i,j ,k+1)+ad_cff2+ad_cff3
ad_cff3=0.0_r8
ad_cff2=0.0_r8
!> tl_cff1=-cff1*cff1*((tl_z_r(i,j ,k+1)-tl_z_r(i,j ,k))* &
!> & (z_r(i,j-1,k+1)-z_r(i,j-1,k))+ &
!> & (z_r(i,j ,k+1)-z_r(i,j ,k))* &
!> & (tl_z_r(i,j-1,k+1)-tl_z_r(i,j-1,k)))
!>
adfac=-cff1*cff1*ad_cff1
adfac1=adfac*(z_r(i,j-1,k+1)-z_r(i,j-1,k))
adfac2=adfac*(z_r(i,j ,k+1)-z_r(i,j ,k))
ad_z_r(i,j-1,k )=ad_z_r(i,j-1,k )-adfac2
ad_z_r(i,j ,k )=ad_z_r(i,j ,k )-adfac1
ad_z_r(i,j-1,k+1)=ad_z_r(i,j-1,k+1)+adfac2
ad_z_r(i,j ,k+1)=ad_z_r(i,j ,k+1)+adfac1
ad_cff1=0.0_r8
#else
!
cff1=rho(i,j,k+1)-rho(i,j-1,k+1)+ &
& rho(i,j,k )-rho(i,j-1,k )
cff2=rho(i,j,k+1)+rho(i,j-1,k+1)- &
& rho(i,j,k )-rho(i,j-1,k )
cff3=z_r(i,j,k+1)+z_r(i,j-1,k+1)- &
& z_r(i,j,k )-z_r(i,j-1,k )
cff4=z_r(i,j,k+1)-z_r(i,j-1,k+1)+ &
& z_r(i,j,k )-z_r(i,j-1,k )
!> tl_phie(i)=tl_phie(i)+ &
!> & fac3*(tl_cff1*cff3+ &
!> & cff1*tl_cff3- &
!> & tl_cff2*cff4- &
!> & cff2*tl_cff4)
!>
adfac=fac3*ad_phie(i)
ad_cff1=ad_cff1+cff3*adfac
ad_cff2=ad_cff2-cff4*adfac
ad_cff3=ad_cff3+cff1*adfac
ad_cff4=ad_cff4-cff2*adfac
!> tl_cff4=tl_z_r(i,j,k+1)-tl_z_r(i,j-1,k+1)+ &
!> & tl_z_r(i,j,k )-tl_z_r(i,j-1,k )
!> tl_cff3=tl_z_r(i,j,k+1)+tl_z_r(i,j-1,k+1)- &
!> & tl_z_r(i,j,k )-tl_z_r(i,j-1,k )
!>
ad_z_r(i,j-1,k )=ad_z_r(i,j-1,k )-ad_cff3-ad_cff4
ad_z_r(i,j ,k )=ad_z_r(i,j ,k )-ad_cff3+ad_cff4
ad_z_r(i,j-1,k+1)=ad_z_r(i,j-1,k+1)+ad_cff3-ad_cff4
ad_z_r(i,j ,k+1)=ad_z_r(i,j ,k+1)+ad_cff3+ad_cff4
ad_cff4=0.0_r8
ad_cff3=0.0_r8
!> tl_cff2=tl_rho(i,j,k+1)+tl_rho(i,j-1,k+1)- &
!> & tl_rho(i,j,k )-tl_rho(i,j-1,k )
!> tl_cff1=tl_rho(i,j,k+1)-tl_rho(i,j-1,k+1)+ &
!> & tl_rho(i,j,k )-tl_rho(i,j-1,k )
!>
ad_rho(i,j-1,k )=ad_rho(i,j-1,k )-ad_cff1-ad_cff2
ad_rho(i,j ,k )=ad_rho(i,j ,k )+ad_cff1-ad_cff2
ad_rho(i,j-1,k+1)=ad_rho(i,j-1,k+1)-ad_cff1+ad_cff2
ad_rho(i,j ,k+1)=ad_rho(i,j ,k+1)+ad_cff1+ad_cff2
ad_cff2=0.0_r8
ad_cff1=0.0_r8
#endif
END DO
END DO
!
! Compute surface adjoint baroclinic pressure gradient.
!
DO i=Istr,Iend
cff1=z_w(i,j ,N(ng))-z_r(i,j ,N(ng))+ &
& z_w(i,j-1,N(ng))-z_r(i,j-1,N(ng))
phie(i)=fac1*(rho(i,j,N(ng))-rho(i,j-1,N(ng)))*cff1
#ifdef ATM_PRESS
phie(i)=phie(i)+fac*(Pair(i,j)-Pair(i,j-1))
#endif
#ifdef RHO_SURF
phie(i)=phie(i)+ &
& (fac2+fac1*(rho(i,j,N(ng))+rho(i,j-1,N(ng))))* &
& (z_w(i,j,N(ng))-z_w(i,j-1,N(ng)))
#endif
# ifdef DIAGNOSTICS_UV
!! DiaRV(i,j,N(ng),nrhs,M3pgrd)=rv(i,j,N(ng),nrhs)
# endif
!> tl_rv(i,j,N(ng),nrhs)=-0.5_r8*om_v(i,j)* &
!> & ((tl_Hz(i,j ,N(ng))+ &
!> & tl_Hz(i,j-1,N(ng)))*phie(i)+ &
!> & (Hz(i,j ,N(ng))+ &
!> & Hz(i,j-1,N(ng)))*tl_phie(i))
!>
adfac=-0.5_r8*om_v(i,j)*ad_rv(i,j,N(ng),nrhs)
adfac1=adfac*phie(i)
ad_phie(i)=ad_phie(i)+(Hz(i,j ,N(ng))+ &
& Hz(i,j-1,N(ng)))*adfac
ad_Hz(i,j-1,N(ng))=ad_Hz(i,j-1,N(ng))+adfac1
ad_Hz(i,j ,N(ng))=ad_Hz(i,j ,N(ng))+adfac1
ad_rv(i,j,N(ng),nrhs)=0.0
#ifdef RHO_SURF
!> tl_phie(i)=tl_phie(i)+ &
!> & (fac1*(tl_rho(i,j,N(ng))+tl_rho(i,j-1,N(ng))))* &
!> & (z_w(i,j,N(ng))-z_w(i,j-1,N(ng)))+ &
!> & (fac2+fac1*(rho(i,j,N(ng))+rho(i,j-1,N(ng))))* &
!> & (tl_z_w(i,j,N(ng))-tl_z_w(i,j-1,N(ng)))
!>
adfac1=fac1*(z_w(i,j,N(ng))-z_w(i,j-1,N(ng)))* &
& ad_phie(i)
adfac2=(fac2+fac1*(rho(i,j,N(ng))+rho(i,j-1,N(ng))))* &
& ad_phie(i)
ad_rho(i,j-1,N(ng))=ad_rho(i,j-1,N(ng))+adfac1
ad_rho(i,j ,N(ng))=ad_rho(i,j ,N(ng))+adfac1
ad_z_w(i,j-1,N(ng))=ad_z_w(i,j-1,N(ng))-adfac2
ad_z_w(i,j ,N(ng))=ad_z_w(i,j ,N(ng))+adfac2
#endif
!> tl_phie(i)=fac1* &
!> & ((tl_rho(i,j,N(ng))-tl_rho(i,j-1,N(ng)))*cff1+ &
!> & (rho(i,j,N(ng))-rho(i,j-1,N(ng)))*tl_cff1)
!>
adfac=fac1*ad_phie(i)
adfac1=adfac*cff1
ad_rho(i,j-1,N(ng))=ad_rho(i,j-1,N(ng))-adfac1
ad_rho(i,j ,N(ng))=ad_rho(i,j ,N(ng))+adfac1
ad_cff1=ad_cff1+ &
& (rho(i,j,N(ng))-rho(i,j-1,N(ng)))*adfac
ad_phie(i)=0.0_r8
!> tl_cff1=tl_z_w(i,j ,N(ng))-tl_z_r(i,j ,N(ng))+ &
!> & tl_z_w(i,j-1,N(ng))-tl_z_r(i,j-1,N(ng))
!>
ad_z_r(i,j-1,N(ng))=ad_z_r(i,j-1,N(ng))-ad_cff1
ad_z_r(i,j ,N(ng))=ad_z_r(i,j ,N(ng))-ad_cff1
ad_z_w(i,j-1,N(ng))=ad_z_w(i,j-1,N(ng))+ad_cff1
ad_z_w(i,j ,N(ng))=ad_z_w(i,j ,N(ng))+ad_cff1
ad_cff1=0.0_r8
END DO
END IF
!
!-----------------------------------------------------------------------
! Calculate adjoint pressure gradient in the XI-direction (m4/s2).
!-----------------------------------------------------------------------
!
! Compute appropriate BASIC STATE "phix". Notice that a reverse
! vertical integration of "phix" is carried out over kk-index.
!
!> DO k=N(ng)-1,1,-1
!>
DO k=1,N(ng)-1
DO i=IstrU,Iend
cff1=z_w(i ,j,N(ng))-z_r(i ,j,N(ng))+ &
& z_w(i-1,j,N(ng))-z_r(i-1,j,N(ng))
phix(i)=fac1*(rho(i,j,N(ng))-rho(i-1,j,N(ng)))*cff1
#ifdef ATM_PRESS
phix(i)=phix(i)+fac*(Pair(i,j)-Pair(i-1,j))
#endif
#ifdef RHO_SURF
phix(i)=phix(i)+ &
& (fac2+fac1*(rho(i,j,N(ng))+rho(i-1,j,N(ng))))* &
& (z_w(i,j,N(ng))-z_w(i-1,j,N(ng)))
#endif
END DO
DO kk=N(ng)-1,k,-1
DO i=IstrU,Iend
#ifdef WJ_GRADP
cff1=1.0_r8/((z_r(i ,j,kk+1)-z_r(i ,j,kk))* &
& (z_r(i-1,j,kk+1)-z_r(i-1,j,kk)))
cff2=z_r(i ,j,kk )-z_r(i-1,j,kk )+ &
& z_r(i ,j,kk+1)-z_r(i-1,j,k+1)
cff3=z_r(i ,j,kk+1)-z_r(i ,j,kk )- &
& z_r(i-1,j,kk+1)+z_r(i-1,j,kk )
gamma=0.125_r8*cff1*cff2*cff3
cff1=(1.0_r8+gamma)*(rho(i,j,kk+1)-rho(i-1,j,kk+1))+ &
& (1.0_r8-gamma)*(rho(i,j,kk )-rho(i-1,j,kk ))
cff2=rho(i,j,kk+1)+rho(i-1,j,kk+1)- &
& rho(i,j,kk )-rho(i-1,j,kk )
cff3=z_r(i,j,kk+1)+z_r(i-1,j,kk+1)- &
& z_r(i,j,kk )-z_r(i-1,j,kk )
cff4=(1.0_r8+gamma)*(z_r(i,j,kk+1)-z_r(i-1,j,kk+1))+ &
& (1.0_r8-gamma)*(z_r(i,j,kk )-z_r(i-1,j,kk ))
phix(i)=phix(i)+ &
& fac3*(cff1*cff3-cff2*cff4)
#else
cff1=rho(i,j,kk+1)-rho(i-1,j,kk+1)+ &
& rho(i,j,kk )-rho(i-1,j,kk )
cff2=rho(i,j,kk+1)+rho(i-1,j,kk+1)- &
& rho(i,j,kk )-rho(i-1,j,kk )
cff3=z_r(i,j,kk+1)+z_r(i-1,j,kk+1)- &
& z_r(i,j,kk )-z_r(i-1,j,kk )
cff4=z_r(i,j,kk+1)-z_r(i-1,j,kk+1)+ &
& z_r(i,j,kk )-z_r(i-1,j,kk )
phix(i)=phix(i)+ &
& fac3*(cff1*cff3-cff2*cff4)
#endif
END DO
END DO
!
! Compute interior adjoint baroclinic pressure gradient. Differentiate
! and then vertically integrate.
!
DO i=IstrU,Iend
# ifdef DIAGNOSTICS_UV
!! DiaRU(i,j,k,nrhs,M3pgrd)=ru(i,j,k,nrhs)
# endif
!> tl_ru(i,j,k,nrhs)=-0.5_r8*on_u(i,j)* &
!> & ((tl_Hz(i,j,k)+tl_Hz(i-1,j,k))* &
!> & phix(i)+ &
!> & (Hz(i,j,k)+Hz(i-1,j,k))* &
!> & tl_phix(i))
!>
adfac=-0.5_r8*on_u(i,j)*ad_ru(i,j,k,nrhs)
adfac1=adfac*phix(i)
ad_phix(i)=ad_phix(i)+ &
& (Hz(i,j,k)+Hz(i-1,j,k))*adfac
ad_Hz(i-1,j,k)=ad_Hz(i-1,j,k)+adfac1
ad_Hz(i ,j,k)=ad_Hz(i ,j,k)+adfac1
ad_ru(i,j,k,nrhs)=0.0
#ifdef WJ_GRADP
cff1=1.0_r8/((z_r(i ,j,k+1)-z_r(i ,j,k))* &
& (z_r(i-1,j,k+1)-z_r(i-1,j,k)))
cff2=z_r(i ,j,k )-z_r(i-1,j,k )+ &
& z_r(i ,j,k+1)-z_r(i-1,j,k+1)
cff3=z_r(i ,j,k+1)-z_r(i ,j,k )- &
& z_r(i-1,j,k+1)+z_r(i-1,j,k )
gamma=0.125_r8*cff1*cff2*cff3
cff1=(1.0_r8+gamma)*(rho(i,j,k+1)-rho(i-1,j,k+1))+ &
& (1.0_r8-gamma)*(rho(i,j,k )-rho(i-1,j,k ))
cff2=rho(i,j,k+1)+rho(i-1,j,k+1)- &
& rho(i,j,k )-rho(i-1,j,k )
cff3=z_r(i,j,k+1)+z_r(i-1,j,k+1)- &
& z_r(i,j,k )-z_r(i-1,j,k )
cff4=(1.0_r8+gamma)*(z_r(i,j,k+1)-z_r(i-1,j,k+1))+ &
& (1.0_r8-gamma)*(z_r(i,j,k )-z_r(i-1,j,k ))
!> tl_phix(i)=tl_phix(i)+ &
!> & fac3*(tl_cff1*cff3+ &
!> & cff1*tl_cff3- &
!> & tl_cff2*cff4- &
!> & cff2*tl_cff4)
!>
adfac=fac3*ad_phix(i)
ad_cff1=ad_cff1+cff3*adfac
ad_cff2=ad_cff2-cff4*adfac
ad_cff3=ad_cff3+cff1*adfac
ad_cff4=ad_cff4-cff2*adfac
!> tl_cff4=tl_gamma*(z_r(i,j,k+1)-z_r(i-1,j,k+1)- &
!> & z_r(i,j,k )+z_r(i-1,j,k ))+ &
!> & (1.0_r8+gamma)*(tl_z_r(i ,j,k+1)- &
!> & tl_z_r(i-1,j,k+1))+ &
!> & (1.0_r8-gamma)*(tl_z_r(i ,j,k )- &
!> & tl_z_r(i-1,j,k ))
!> tl_cff3=tl_z_r(i,j,k+1)+tl_z_r(i-1,j,k+1)- &
!> & tl_z_r(i,j,k )-tl_z_r(i-1,j,k )
!>
adfac1=(1.0_r8+gamma)*ad_cff4
adfac2=(1.0_r8-gamma)*ad_cff4
ad_z_r(i-1,j,k )=ad_z_r(i-1,j,k )-adfac2-ad_cff3
ad_z_r(i ,j,k )=ad_z_r(i ,j,k )+adfac2-ad_cff3
ad_z_r(i-1,j,k+1)=ad_z_r(i-1,j,k+1)-adfac1+ad_cff3
ad_z_r(i ,j,k+1)=ad_z_r(i ,j,k+1)+adfac1+ad_cff3
ad_gamma=ad_gamma+ &
& (z_r(i,j,k+1)-z_r(i-1,j,k+1)- &
& z_r(i,j,k )+z_r(i-1,j,k ))*ad_cff4
ad_cff4=0.0_r8
ad_cff3=0.0_r8
!> & tl_cff2=tl_rho(i,j,k+1)+tl_rho(i-1,j,k+1)- &
!> & tl_rho(i,j,k )-tl_rho(i-1,j,k )
!> tl_cff1=tl_gamma*(rho(i,j,k+1)-rho(i-1,j,k+1)- &
!> & rho(i,j,k )+rho(i-1,j,k ))+ &
!> & (1.0_r8+gamma)*(tl_rho(i ,j,k+1)- &
!> & tl_rho(i-1,j,k+1))+ &
!> & (1.0_r8-gamma)*(tl_rho(i ,j,k )- &
!> & tl_rho(i-1,j,k ))
!>
adfac1=(1.0_r8+gamma)*ad_cff1
adfac2=(1.0_r8-gamma)*ad_cff1
ad_rho(i-1,j,k )=ad_rho(i-1,j,k )-adfac2-ad_cff2
ad_rho(i ,j,k )=ad_rho(i ,j,k )+adfac2-ad_cff2
ad_rho(i-1,j,k+1)=ad_rho(i-1,j,k+1)-adfac1+ad_cff2
ad_rho(i ,j,k+1)=ad_rho(i ,j,k+1)+adfac1+ad_cff2
ad_gamma=ad_gamma+ &
& (rho(i,j,k+1)-rho(i-1,j,k+1)- &
& rho(i,j,k )+rho(i-1,j,k ))*ad_cff1
ad_cff2=0.0_r8
ad_cff1=0.0_r8
!
cff1=1.0_r8/((z_r(i ,j,k+1)-z_r(i ,j,k))* &
& (z_r(i-1,j,k+1)-z_r(i-1,j,k)))
cff2=z_r(i ,j,k )-z_r(i-1,j,k )+ &
& z_r(i ,j,k+1)-z_r(i-1,j,k+1)
cff3=z_r(i ,j,k+1)-z_r(i ,j,k )- &
& z_r(i-1,j,k+1)+z_r(i-1,j,k )
!> tl_gamma=0.125_r8*(tl_cff1*cff2*cff3+ &
!> & cff1*(tl_cff2*cff3+ &
!> & cff2*tl_cff3))
!>
adfac=0.125_r8*ad_gamma
adfac1=adfac*cff1
ad_cff3=ad_cff3+cff2*adfac1
ad_cff2=ad_cff2+cff3*adfac1
ad_cff1=ad_cff1+cff2*cff3*adfac
ad_gamma=0.0_r8
!> & tl_cff3=tl_z_r(i ,j,k+1)-tl_z_r(i ,j,k )- &
!> & tl_z_r(i-1,j,k+1)+tl_z_r(i-1,j,k )
!> tl_cff2=tl_z_r(i ,j,k )-tl_z_r(i-1,j,k )+ &
!> & tl_z_r(i ,j,k+1)-tl_z_r(i-1,j,k+1)
!>
ad_z_r(i-1,j,k )=ad_z_r(i-1,j,k )-ad_cff2+ad_cff3
ad_z_r(i ,j,k )=ad_z_r(i ,j,k )+ad_cff2-ad_cff3
ad_z_r(i-1,j,k+1)=ad_z_r(i-1,j,k+1)-ad_cff2-ad_cff3
ad_z_r(i ,j,k+1)=ad_z_r(i ,j,k+1)+ad_cff2+ad_cff3
ad_cff3=0.0
ad_cff2=0.0
!> tl_cff1=-cff1*cff1*((tl_z_r(i ,j,k+1)-tl_z_r(i ,j,k))* &
!> & (z_r(i-1,j,k+1)-z_r(i-1,j,k))+ &
!> & (z_r(i ,j,k+1)-z_r(i ,j,k))* &
!> & (tl_z_r(i-1,j,k+1)-tl_z_r(i-1,j,k)))
!>
adfac=-cff1*cff1*ad_cff1
adfac1=adfac*(z_r(i-1,j,k+1)-z_r(i-1,j,k))
adfac2=adfac*(z_r(i ,j,k+1)-z_r(i ,j,k))
ad_z_r(i-1,j,k )=ad_z_r(i-1,j,k )-adfac2
ad_z_r(i ,j,k )=ad_z_r(i ,j,k )-adfac1
ad_z_r(i-1,j,k+1)=ad_z_r(i-1,j,k+1)+adfac2
ad_z_r(i ,j,k+1)=ad_z_r(i ,j,k+1)+adfac1
ad_cff1=0.0_r8
#else
cff1=rho(i,j,k+1)-rho(i-1,j,k+1)+ &
& rho(i,j,k )-rho(i-1,j,k )
cff2=rho(i,j,k+1)+rho(i-1,j,k+1)- &
& rho(i,j,k )-rho(i-1,j,k )
cff3=z_r(i,j,k+1)+z_r(i-1,j,k+1)- &
& z_r(i,j,k )-z_r(i-1,j,k )
cff4=z_r(i,j,k+1)-z_r(i-1,j,k+1)+ &
& z_r(i,j,k )-z_r(i-1,j,k )
!> tl_phix(i)=tl_phix(i)+ &
!> & fac3*(tl_cff1*cff3+ &
!> & cff1*tl_cff3- &
!> & tl_cff2*cff4- &
!> & cff2*tl_cff4)
!>
adfac=fac3*ad_phix(i)
ad_cff1=ad_cff1+cff3*adfac
ad_cff2=ad_cff2-cff4*adfac
ad_cff3=ad_cff3+cff1*adfac
ad_cff4=ad_cff4-cff2*adfac
!> tl_cff4=tl_z_r(i,j,k+1)-tl_z_r(i-1,j,k+1)+ &
!> & tl_z_r(i,j,k )-tl_z_r(i-1,j,k )
!> tl_cff3=tl_z_r(i,j,k+1)+tl_z_r(i-1,j,k+1)- &
!> & tl_z_r(i,j,k )-tl_z_r(i-1,j,k )
!>
ad_z_r(i-1,j,k )=ad_z_r(i-1,j,k )-ad_cff3-ad_cff4
ad_z_r(i ,j,k )=ad_z_r(i ,j,k )-ad_cff3+ad_cff4
ad_z_r(i-1,j,k+1)=ad_z_r(i-1,j,k+1)+ad_cff3-ad_cff4
ad_z_r(i ,j,k+1)=ad_z_r(i ,j,k+1)+ad_cff3+ad_cff4
ad_cff4=0.0_r8
ad_cff3=0.0_r8
!> tl_cff1=tl_rho(i,j,k+1)-tl_rho(i-1,j,k+1)+ &
!> & tl_rho(i,j,k )-tl_rho(i-1,j,k )
!> tl_cff2=tl_rho(i,j,k+1)+tl_rho(i-1,j,k+1)- &
!> & tl_rho(i,j,k )-tl_rho(i-1,j,k )
!>
ad_rho(i-1,j,k )=ad_rho(i-1,j,k )-ad_cff2-ad_cff1
ad_rho(i ,j,k )=ad_rho(i ,j,k )-ad_cff2+ad_cff1
ad_rho(i-1,j,k+1)=ad_rho(i-1,j,k+1)+ad_cff2-ad_cff1
ad_rho(i ,j,k+1)=ad_rho(i ,j,k+1)+ad_cff2+ad_cff1
ad_cff2=0.0_r8
ad_cff1=0.0_r8
#endif
END DO
END DO
!
! Compute surface adjoint baroclinic pressure gradient.
!
DO i=IstrU,Iend
cff1=z_w(i ,j,N(ng))-z_r(i ,j,N(ng))+ &
& z_w(i-1,j,N(ng))-z_r(i-1,j,N(ng))
phix(i)=fac1*(rho(i,j,N(ng))-rho(i-1,j,N(ng)))*cff1
#ifdef ATM_PRESS
phix(i)=phix(i)+fac*(Pair(i,j)-Pair(i-1,j))
#endif
#ifdef RHO_SURF
phix(i)=phix(i)+ &
& (fac2+fac1*(rho(i,j,N(ng))+rho(i-1,j,N(ng))))* &
& (z_w(i,j,N(ng))-z_w(i-1,j,N(ng)))
#endif
#ifdef DIAGNOSTICS_UV
!! DiaRU(i,j,N(ng),nrhs,M3pgrd)=ru(i,j,N(ng),nrhs)
#endif
!> tl_ru(i,j,N(ng),nrhs)=-0.5_r8*on_u(i,j)* &
!> & ((tl_Hz(i ,j,N(ng))+ &
!> & tl_Hz(i-1,j,N(ng)))*phix(i)+ &
!> & (Hz(i ,j,N(ng))+ &
!> & Hz(i-1,j,N(ng)))*tl_phix(i))
!>
adfac=-0.5_r8*on_u(i,j)*ad_ru(i,j,N(ng),nrhs)
adfac1=adfac*phix(i)
ad_phix(i)=ad_phix(i)+(Hz(i ,j,N(ng))+ &
& Hz(i-1,j,N(ng)))*adfac
ad_Hz(i-1,j,N(ng))=ad_Hz(i-1,j,N(ng))+adfac1
ad_Hz(i ,j,N(ng))=ad_Hz(i ,j,N(ng))+adfac1
ad_ru(i,j,N(ng),nrhs)=0.0_r8
#ifdef RHO_SURF
!> tl_phix(i)=tl_phix(i)+ &
!> & (fac1*(tl_rho(i,j,N(ng))+tl_rho(i-1,j,N(ng))))* &
!> & (z_w(i,j,N(ng))-z_w(i-1,j,N(ng)))+ &
!> & (fac2+fac1*(rho(i,j,N(ng))+rho(i-1,j,N(ng))))*
!> & (tl_z_w(i,j,N(ng))-tl_z_w(i-1,j,N(ng)))
!>
adfac1=fac1*(z_w(i,j,N(ng))-z_w(i-1,j,N(ng)))* &
& ad_phix(i)
adfac2=(fac2+fac1*(rho(i,j,N(ng))+rho(i-1,j,N(ng))))* &
& ad_phix(i)
ad_rho(i-1,j,N(ng))=ad_rho(i-1,j,N(ng))+adfac1
ad_rho(i ,j,N(ng))=ad_rho(i ,j,N(ng))+adfac1
ad_z_w(i-1,j,N(ng))=ad_z_w(i-1,j,N(ng))-adfac2
ad_z_w(i ,j,N(ng))=ad_z_w(i ,j,N(ng))+adfac2
#endif
!> tl_phix(i)=fac1* &
!> & ((tl_rho(i,j,N(ng))-tl_rho(i-1,j,N(ng)))*cff1+ &
!> & (rho(i,j,N(ng))-rho(i-1,j,N(ng)))*tl_cff1)
!>
adfac=fac1*ad_phix(i)
adfac1=adfac*cff1
ad_rho(i-1,j,N(ng))=ad_rho(i-1,j,N(ng))-adfac1
ad_rho(i ,j,N(ng))=ad_rho(i ,j,N(ng))+adfac1
ad_cff1=ad_cff1+ &
& (rho(i,j,N(ng))-rho(i-1,j,N(ng)))*adfac
ad_phix(i)=0.0
!> tl_cff1=tl_z_w(i ,j,N(ng))-tl_z_r(i ,j,N(ng))+ &
!> & tl_z_w(i-1,j,N(ng))-tl_z_r(i-1,j,N(ng))
!>
ad_z_r(i-1,j,N(ng))=ad_z_r(i-1,j,N(ng))-ad_cff1
ad_z_r(i ,j,N(ng))=ad_z_r(i ,j,N(ng))-ad_cff1
ad_z_w(i-1,j,N(ng))=ad_z_w(i-1,j,N(ng))+ad_cff1
ad_z_w(i ,j,N(ng))=ad_z_w(i ,j,N(ng))+ad_cff1
ad_cff1=0.0_r8
END DO
END DO J_LOOP
RETURN
END SUBROUTINE ad_prsgrd_tile