build.gradle

buildscript {
    repositories {
        maven { url "https://repo.grails.org/grails/core" }
    }
    dependencies {
        classpath "io.micronaut.build.internal:micronaut-gradle-plugins:3.0.1"
    }
}

subprojects { Project subproject ->

    repositories {
        mavenCentral()
        maven { url "https://s01.oss.sonatype.org/content/repositories/snapshots/" }
    }

    if (subproject.getPath().startsWith(":test-")) {
        return
    }
    group "io.micronaut.r2dbc"

    boolean isExampleOrBenchmark = subproject.parent.name == "docs-examples" || subproject.name.contains("example") || subproject.name.contains("benchmark")

    if (!isExampleOrBenchmark) {
        if (subproject.name.endsWith('-bom')) {
            apply plugin: "java-platform"
            version projectVersion
            apply plugin: "io.micronaut.build.internal.dependency-updates"
            apply plugin: "io.micronaut.build.internal.publishing"
        }  else {

            apply plugin: "io.micronaut.build.internal.common"
            apply plugin: "io.micronaut.build.internal.dependency-updates"
            apply plugin: "io.micronaut.build.internal.publishing"

            micronautBuild {
                resolutionStrategy {
                    force "jakarta.persistence:jakarta.persistence-api:$jakartaPersistenceVersion"
                    force "jakarta.transaction:jakarta.transaction-api:$jakartaTxVersion"
                }
            }
            dependencies {
                testImplementation platform('org.testcontainers:testcontainers-bom:1.15.2')
            }
        }
    }
}

apply plugin: "io.micronaut.build.internal.docs"
apply plugin: "io.micronaut.build.internal.dependency-updates"