build.gradle

import org.gradle.crypto.checksum.Checksum

plugins {
    id 'java'
    id 'jacoco'
    id 'checkstyle'
    id 'distribution'
    id 'signing'
    id 'org.gradle.crypto.checksum' version '1.4.0'
    id 'com.diffplug.spotless' version '6.0.0'
    id 'org.omegat.gradle' version '1.5.9'
    id 'com.palantir.git-version' version '0.13.0'
}

def baseVersion = versionDetails().lastTag.substring(1)
if (versionDetails().isCleanTag) {
    version = baseVersion
} else {
    version = baseVersion + "-" + versionDetails().commitDistance + "-" + versionDetails().gitHash + "-SNAPSHOT"
}

omegat {
    version = "6.0.0"
    pluginClass = "org.omegat.connectors.machinetranslators.moses.MosesTranslate"
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(11)
        vendor = JvmVendorSpec.ADOPTIUM
    }
}

repositories {
    mavenCentral()
}

dependencies {
    packIntoJar 'org.omegat:xmlrpc-client:3.1.3-20230209'
    packIntoJar 'org.omegat:xmlrpc-common:3.1.3-20230209'
    implementation "com.github.ben-manes.caffeine:caffeine:2.9.3"
    implementation "com.github.ben-manes.caffeine:jcache:2.9.3"
    testImplementation 'org.junit.jupiter:junit-jupiter:5.8.2'
    testImplementation 'org.wiremock:wiremock:3.9.2'
    testImplementation 'commons-io:commons-io:2.14.0'
}

checkstyle {
    ignoreFailures = true
    toolVersion = '7.1'
}

test {
    useJUnitPlatform()
}

distributions {
    main {
        contents {
            from(jar)
            from('README.md', 'COPYING', 'CHANGELOG.md')
        }
    }
}

spotless {
    enforceCheck false
    java {
        eclipse().configFile 'config/spotless/eclipse-formatting.xml'
        removeUnusedImports()
    }
}

signing {
    if (!findProperty('signing.keyId')) {
        useGpgCmd()
    }
    sign tasks.distZip
    sign tasks.jar
}

tasks.register('checksum', Checksum) {
    dependsOn tasks.distZip
    inputFiles.setFrom([tasks.jar.archiveFile, tasks.distZip.archiveFile])
    outputDirectory.set(file("$buildDir/distributions"))
    checksumAlgorithm.set(Checksum.Algorithm.SHA512)
    appendFileNameToChecksum.set(true)
}