build.gradle

version = '0.29'

apply plugin: 'java'
apply plugin: 'eclipse'

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
	mavenCentral()
	maven { 
		url 'https://repo.eclipse.org/content/repositories/paho-releases/'
	} 
}

dependencies {
	compile 'com.eclipsesource.minimal-json:minimal-json:0.9.4'
	compile 'org.eclipse.paho:org.eclipse.paho.client.mqttv3:1.0.2'
	compile 'org.quartz-scheduler:quartz:2.2.2'
	compile('com.joestelmach:natty:0.12') {
		exclude module: 'antlr'
		exclude module: 'backport-util-concurrent'
		exclude module: 'stringtemplate'
	}
	compile 'com.sun.mail:javax.mail:1.5.5'
	testCompile 'junit:junit:4.11'
}

task listJars << {
    configurations.compile.each { File file -> println file.name }
}

jar {
	from { configurations.compile.collect { it.isDirectory() ? it : zipTree(it) } } { exclude "META-INF/**" }
	archiveName 'logic4mqtt.jar'
	manifest {
        attributes 	'Main-Class': 'com.tellerulam.logic4mqtt.Main',
        			'Implementation-Title': 'logic4mqtt Logic Engine',
                   	'Implementation-Version': version
    }
}

task generateApiDocs(type: Javadoc) {	
	source = fileTree("src/main/java/com/tellerulam/logic4mqtt/api").matching {
		exclude "InstanceManager.java"
	}
	destinationDir = file("apidocs")
	options.setMemberLevel(JavadocMemberLevel.PUBLIC)
}

uploadArchives {
    repositories {
       flatDir {
           dirs 'target'
       }
    }
}

test {
    testLogging {
        events "passed", "skipped", "failed", "standardOut", "standardError"
    }
}