publish-bitbucket.gradle

apply plugin: 'maven'

repositories {
    maven { url "https://raw.githubusercontent.com/synergian/wagon-git/releases" }
}

configurations {
    deployLibrary
}

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    
    def library = "ar.com.synergian:wagon-git:0.3.0"    
    printLine()
    println(library)
    printLine()
    
    deployLibrary library
}

task androidJavadocs(type: Javadoc) {
    failOnError false
    source = android.sourceSets.main.java.sourceFiles
}

task androidSourcesJar(type: Jar) {
    classifier = 'sources'
    from android.sourceSets.main.java.sourceFiles
}

task androidJavadocsJar(type: Jar, dependsOn: androidJavadocs) {
    classifier = 'javadoc'
    from androidJavadocs.destinationDir
}

artifacts {
    archives androidSourcesJar
    archives androidJavadocsJar
}

task lookForArtifacts {
    
    doLast {
    
        def artifactName = ARTIFACT_NAME + '-' + ARTIFACT_VERSION + '.aar'
        def artifactPath = ARTIFACT_PACKAGE.replace(".", "/") + "/" + ARTIFACT_NAME + "/" + ARTIFACT_VERSION + "/" + artifactName
        def repositoryUrl = 'https://api.bitbucket.org/1.0/repositories/' + COMPANY + '/' + REPOSITORY_NAME + '/raw/releases/' + artifactPath

        printLine()
        println("Checking if artifact already exists: \n" + artifactName)
        println("\nURL: \n" + repositoryUrl)

        println("\nResponse:")
        def artifactExists = urlExists(repositoryUrl)
        println(artifactExists ? "Existing artifact found" : "No existing artifact found")
        printLine()

        if (artifactExists) {
            
            println("Artifact with version " + ARTIFACT_VERSION + " already exist - Not executing uploadArchives")
            printLine()
            
            throw new RuntimeException("")
        }
        
        return true
    }
}

uploadArchives.dependsOn lookForArtifacts

uploadArchives {

    repositories.mavenDeployer {
        configuration = configurations.deployLibrary
        repository(url: 'git:releases://git@bitbucket.org:' + COMPANY + '/' + REPOSITORY_NAME + '.git')

        uniqueVersion = true

        pom.project {
            groupId = ARTIFACT_PACKAGE
            version = ARTIFACT_VERSION
            artifactId = ARTIFACT_NAME
            packaging ARTIFACT_PACKAGING
        }
    }
}

def urlExists(String repositoryUrl) {

    try {

        def connection = (HttpURLConnection) new URL(repositoryUrl).openConnection()
        connection.setRequestProperty("Authorization", "Basic " + getBase64EncodedCredentials())
        connection.setConnectTimeout(10000)
        connection.setReadTimeout(10000)
        connection.setRequestMethod("HEAD")

        def responseCode = connection.getResponseCode()
        println("ResponseCode: " + responseCode)

        return (200 == responseCode)
 
    } catch (IOException ignored) {
        return false
    }
}

def getBase64EncodedCredentials() {
 
     def s = USERNAME + ":" + PASSWORD;
     return s.bytes.encodeBase64().toString()
} 
 
def printLine() {
    
    println("")
    println(getLine())
    println("")
}

def getLine() {
    
    return "-------------------------------------------------------------------------------------------------------------"
}