build.gradle

buildscript {
    repositories {
        google()
        mavenCentral()
        jcenter()
        mavenLocal()
    }

    dependencies {
        classpath 'com.quittle:setup-android-sdk:+'

        final String androidGradlePluginVersion = System.env.ANDROID_GRADLE_PLUGIN_VERSION ?: '4.1.0'
        classpath "com.android.tools.build:gradle:${androidGradlePluginVersion}"
    }
}

repositories {
    google()
    jcenter()
}

apply plugin: 'com.quittle.setup-android-sdk'
apply plugin: 'android'

android {
    ndkVersion '23.1.7779620'
    compileSdkVersion 29

    final String androidBuildToolsVersion = System.env.ANDROID_BUILD_TOOLS_VERSION ?: '28.0.3'
    buildToolsVersion androidBuildToolsVersion

    externalNativeBuild {
        ndkBuild {
            path 'src/main/cpp/Android.mk'
        }
    }
}

setupAndroidSdk {
    // Used by the validate_plugin script
    final String version = System.env.SDK_TOOLS_VERSION
    if (version != null) {
        sdkToolsVersion version
        sdkToolsVersion = version
    }

    final String licensesDir = System.env.LICENSES_DIR
    if (licensesDir != null) {
        licensesDirectory file(licensesDir)
        licensesDirectory = file(licensesDir)
    }

    // All of these should be supported
    final String NDK = "ndk;${android.ndkVersion}"
    packages(NDK)
    packages NDK, NDK
    packages([NDK, NDK])
    // Final version that is actually used
    packages 'cmdline-tools;1.0', 'ndk-bundle', NDK
}