forked from OpenTelecom/kazoo
-
Notifications
You must be signed in to change notification settings - Fork 0
/
ecallmgr_util.erl
1425 lines (1276 loc) · 67.5 KB
/
ecallmgr_util.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%%%-----------------------------------------------------------------------------
%%% @copyright (C) 2010-2018, 2600Hz
%%% @doc Various utilities specific to ecallmgr. More general utilities go
%%% in kazoo_util.erl
%%%
%%%
%%% @author James Aimonetti <[email protected]>
%%% @author Karl Anderson <[email protected]>
%%% @end
%%%-----------------------------------------------------------------------------
-module(ecallmgr_util).
-export([send_cmd/4]).
-export([get_fs_kv/2, get_fs_kv/3, get_fs_key_and_value/3]).
-export([get_fs_key/1]).
-export([process_fs_kv/4, format_fs_kv/4]).
-export([fs_args_to_binary/1, fs_args_to_binary/2, fs_args_to_binary/3]).
-export([multi_set_args/3, multi_unset_args/3]).
-export([multi_set_args/4, multi_unset_args/4]).
-export([multi_set_args/5, multi_unset_args/5]).
-export([get_expires/1]).
-export([get_interface_list/1, get_interface_properties/1, get_interface_properties/2]).
-export([get_sip_to/1, get_sip_from/1, get_sip_request/1, get_orig_ip/1, get_orig_port/1]).
-export([custom_channel_vars/1
,custom_application_vars/1
,conference_channel_vars/1
]).
-export([eventstr_to_proplist/1, varstr_to_proplist/1, get_setting/1, get_setting/2]).
-export([is_node_up/1, is_node_up/2]).
-export([build_bridge_string/1, build_bridge_string/2]).
-export([build_channel/1]).
-export([build_bridge_channels/1, build_simple_channels/1]).
-export([create_masquerade_event/2, create_masquerade_event/3]).
-export([media_path/1, media_path/2, media_path/3, media_path/4
,lookup_media/4
]).
-export([unserialize_fs_array/1, unserialize_fs_props/1]).
-export([convert_fs_evt_name/1, convert_kazoo_app_name/1]).
-export([fax_filename/1
,recording_filename/1
]).
-export([maybe_sanitize_fs_value/2]).
-export([custom_sip_headers/1 , is_custom_sip_header/1, normalize_custom_sip_header_name/1]).
-export([maybe_add_expires_deviation/1, maybe_add_expires_deviation_ms/1]).
-export([get_dial_separator/2]).
-export([fix_contact/3]).
-export([dialplan_application/1]).
-include("ecallmgr.hrl").
-include_lib("kazoo_amqp/src/api/kapi_dialplan.hrl").
-include_lib("kazoo_stdlib/include/kz_databases.hrl").
-include_lib("kazoo_sip/include/kzsip_uri.hrl").
-define(HTTP_GET_PREFIX, "http_cache://").
-define(FS_MULTI_VAR_SEP, ";").
-define(FS_MULTI_VAR_SEP_PREFIX, "^^").
-type send_cmd_ret() :: fs_sendmsg_ret() | fs_api_ret().
-export_type([send_cmd_ret/0]).
-record(bridge_endpoint, {invite_format = <<"username">> :: kz_term:ne_binary()
,endpoint_type = <<"sip">> :: kz_term:ne_binary()
,ip_address :: kz_term:api_binary()
,username :: kz_term:api_binary()
,user :: kz_term:api_binary()
,realm :: kz_term:api_binary()
,number :: kz_term:api_binary()
,route :: kz_term:api_binary()
,proxy_address :: kz_term:api_binary()
,forward_address :: kz_term:api_binary()
,transport :: kz_term:api_binary()
,span = <<"1">> :: kz_term:ne_binary()
,channel_selection = <<"a">> :: kz_term:ne_binary()
,interface = <<"RR">> :: kz_term:ne_binary() % for Skype
,sip_interface
,channel_vars = [] :: kz_term:ne_binaries()
,header_vars = [] :: kz_term:ne_binaries()
,include_channel_vars = 'true' :: boolean()
,failover
}).
-type bridge_endpoint() :: #bridge_endpoint{}.
%%------------------------------------------------------------------------------
%% @doc send the SendMsg proplist to the freeswitch node
%% @end
%%------------------------------------------------------------------------------
-spec send_cmd(atom(), kz_term:ne_binary(), kz_term:text(), kz_term:text()) -> send_cmd_ret().
send_cmd(Node, UUID, App, Args) when not is_list(App) ->
send_cmd(Node, UUID, kz_term:to_list(App), Args);
send_cmd(Node, UUID, "xferext", Dialplan) ->
XferExt = [begin
lager:debug("building xferext on node ~s: ~s", [Node, V]),
{kz_term:to_list(K), kz_term:to_list(V)}
end
|| {K, V} <- Dialplan,
not cmd_is_empty({kz_term:to_list(K), kz_term:to_list(V)})
],
'ok' = freeswitch:sendmsg(Node, UUID, [{"call-command", "xferext"} | XferExt]);
send_cmd(Node, UUID, App, Args) when not is_list(Args) ->
send_cmd(Node, UUID, App, kz_term:to_list(Args));
send_cmd(_Node, _UUID, "kz_multiset", "^^") -> 'ok';
send_cmd(Node, UUID, "playstop", _Args) ->
lager:debug("execute on node ~s: uuid_break(~s all)", [Node, UUID]),
freeswitch:api(Node, 'uuid_break', kz_term:to_list(<<UUID/binary, " all">>));
send_cmd(Node, UUID, "unbridge", _) ->
lager:debug("execute on node ~s: uuid_park(~s)", [Node, UUID]),
freeswitch:api(Node, 'uuid_park', kz_term:to_list(UUID));
send_cmd(Node, _UUID, "broadcast", Args) ->
lager:debug("execute on node ~s: uuid_broadcast(~s)", [Node, Args]),
Resp = freeswitch:api(Node, 'uuid_broadcast', kz_term:to_list(iolist_to_binary(Args))),
lager:debug("broadcast resulted in: ~p", [Resp]),
Resp;
send_cmd(Node, UUID, "call_pickup", Target) ->
Args = iolist_to_binary([UUID, " ", Target]),
lager:debug("execute on node ~s: uuid_bridge(~s)", [Node, Args]),
freeswitch:api(Node, 'uuid_bridge', kz_term:to_list(Args));
send_cmd(Node, UUID, "hangup", Args) ->
lager:debug("terminate call on node ~s", [Node]),
freeswitch:api(Node, 'uuid_kill', iolist_to_binary([UUID, " ", Args]));
send_cmd(Node, UUID, "break", _) ->
lager:debug("break call on node ~s", [Node]),
freeswitch:api(Node, 'uuid_break', kz_term:to_list(UUID));
send_cmd(Node, _UUID, "audio_level", Args) ->
lager:debug("execute on node ~s: uuid_audio ~p", [Node, Args]),
freeswitch:api(Node, 'uuid_audio', kz_term:to_list(iolist_to_binary(Args)));
send_cmd(Node, UUID, "conference", Args) ->
Args1 = iolist_to_binary([UUID, " conference:", Args, " inline"]),
lager:debug("starting conference on ~s: ~s", [Node, Args1]),
freeswitch:api(Node, 'uuid_transfer', kz_term:to_list(Args1));
send_cmd(Node, _UUID, "transfer", Args) ->
lager:debug("transfering on ~s: ~s", [Node, Args]),
freeswitch:api(Node, 'uuid_transfer', kz_term:to_list(Args));
send_cmd(Node, _UUID, "uuid_" ++ _ = API, Args) ->
lager:debug("using api for ~s command ~s: ~s", [API, Node, Args]),
freeswitch:api(Node, kz_term:to_atom(API, 'true'), kz_term:to_list(Args));
send_cmd(Node, _UUID, "kz_uuid_" ++ _ = API, Args) ->
lager:debug("using api for ~s command ~s: ~s", [API, Node, Args]),
freeswitch:api(Node, kz_term:to_atom(API, 'true'), kz_term:to_list(Args));
send_cmd(Node, UUID, App, Args) ->
AppName = dialplan_application(App),
case freeswitch:sendmsg(Node, UUID, [{"call-command", "execute"}
,{"execute-app-name", AppName}
,{"execute-app-arg", kz_term:to_list(Args)}
])
of
{'error', 'baduuid'} ->
lager:info("uuid ~s on node ~s is bad", [UUID, Node]),
throw({'error', 'baduuid'});
Result ->
lager:debug("execute on node ~s(~s) ~s(~s): ~p"
,[Node, UUID, AppName, Args, Result]
),
Result
end.
-spec cmd_is_empty({list(), list()}) -> boolean().
cmd_is_empty({"kz_multiset", "^^"}) -> 'true';
cmd_is_empty({_, "kz_multiset ^^"}) -> 'true';
cmd_is_empty(_) -> 'false'.
-spec dialplan_application(string()) -> string().
dialplan_application("blind_xfer") -> "transfer";
dialplan_application(App) -> App.
-spec get_expires(kz_term:proplist()) -> integer().
get_expires(Props) ->
Expiry = kz_term:to_integer(props:get_first_defined([<<"Expires">>, <<"expires">>], Props, 300)),
round(Expiry * 1.25).
-spec get_interface_list(atom()) -> kz_term:ne_binaries().
get_interface_list(Node) ->
case freeswitch:api(Node, 'sofia', "status") of
{'ok', Response} ->
R = binary:replace(Response, <<" ">>, <<>>, ['global']),
Lines = binary:split(R, <<"\n">>, ['global']),
[KV || Line <- Lines,
(KV = case binary:split(Line, <<"\t">>, ['global']) of
[<<"Name">>, _T, _A, _S] -> 'false';
[I, <<"profile">>, _A, <<"RUNNING", _/binary>>] -> I;
_Other -> 'false'
end) =/= 'false'
];
_Else -> []
end.
-spec get_interface_properties(atom()) -> kz_term:proplist().
get_interface_properties(Node) ->
[{Interface, get_interface_properties(Node, Interface)} || Interface <- get_interface_list(Node)].
-spec get_interface_properties(atom(), kz_term:ne_binary()) -> kz_term:proplist().
get_interface_properties(Node, Interface) ->
case freeswitch:api(Node, 'sofia', kz_term:to_list(list_to_binary(["status profile ", Interface]))) of
{'ok', Response} ->
R = binary:replace(Response, <<" ">>, <<>>, ['global']),
[KV || Line <- binary:split(R, <<"\n">>, ['global']),
(KV = case binary:split(Line, <<"\t">>) of
[K, V] -> {K, V};
_ -> 'false'
end) =/= 'false'
];
_Else -> []
end.
%% retrieves the sip address for the 'to' field
-spec get_sip_to(kz_term:proplist()) -> kz_term:ne_binary().
get_sip_to(Props) ->
get_sip_to(Props, kzd_freeswitch:original_call_direction(Props)).
get_sip_to(Props, <<"outbound">>) ->
case props:get_value(<<"Channel-Presence-ID">>, Props) of
'undefined' ->
Number = props:get_first_defined([<<"Other-Leg-Callee-ID-Number">>
,<<"variable_sip_to_user">>
], Props, <<"nouser">>),
Realm = props:get_first_defined([?GET_CCV(<<"Realm">>)
,<<"variable_sip_to_host">>
], Props, ?DEFAULT_REALM),
<<Number/binary, "@", Realm/binary>>;
PresenceId -> PresenceId
end;
get_sip_to(Props, _) ->
case props:get_first_defined([<<"variable_sip_to_uri">>
,<<"variable_sip_req_uri">>
], Props) of
'undefined' -> get_sip_request(Props);
ToUri -> ToUri
end.
%% retrieves the sip address for the 'from' field
-spec get_sip_from(kz_term:proplist()) -> kz_term:ne_binary().
get_sip_from(Props) ->
get_sip_from(Props, kzd_freeswitch:original_call_direction(Props)).
-spec get_sip_from(kz_term:proplist(), kz_term:api_binary()) -> kz_term:ne_binary().
get_sip_from(Props, <<"outbound">>) ->
Num = props:get_first_defined([<<"Other-Leg-RDNIS">>
,<<"Other-Leg-Caller-ID-Number">>
,<<"variable_sip_from_user">>
,<<"variable_sip_from_uri">>
], Props, <<"nouser">>),
[Number | _] = binary:split(Num, <<"@">>, ['global']),
Realm = props:get_first_defined([?GET_CCV(<<"Realm">>)
,<<"variable_sip_auth_realm">>
], Props, ?DEFAULT_REALM),
<<Number/binary, "@", Realm/binary>>;
get_sip_from(Props, _) ->
Default = list_to_binary([props:get_value(<<"sip_from_user">>, Props, <<"nouser">>)
,"@"
,props:get_first_defined([?GET_CCV(<<"Realm">>)
,<<"variable_sip_from_host">>
,<<"sip_from_host">>
]
,Props
,?DEFAULT_REALM
)
]),
props:get_first_defined([<<"Channel-Presence-ID">>
,<<"variable_sip_from_uri">>
]
,Props
,Default
).
%% retrieves the sip address for the 'request' field
-spec get_sip_request(kz_term:proplist()) -> kz_term:ne_binary().
get_sip_request(Props) ->
U = props:get_first_defined([<<"Hunt-Destination-Number">>
,<<"variable_sip_req_uri">>
,<<"variable_sip_loopback_req_uri">>
,<<"Caller-Destination-Number">>
,<<"variable_sip_to_user">>
]
,Props
,<<"nouser">>
),
[User | _] = binary:split(U, <<"@">>, ['global']),
Realm = props:get_first_defined([?GET_CCV(<<"Realm">>)
,<<"variable_sip_auth_realm">>
,<<"variable_sip_to_host">>
,<<"variable_sip_req_host">>
]
,Props
,?DEFAULT_REALM
),
<<User/binary, "@", Realm/binary>>.
-spec get_orig_ip(kz_term:proplist()) -> kz_term:api_binary().
get_orig_ip(Prop) ->
props:get_first_defined([<<"X-AUTH-IP">>, <<"ip">>], Prop).
-spec get_orig_port(kz_term:proplist()) -> kz_term:api_binary().
get_orig_port(Prop) ->
case props:get_first_defined([<<"X-AUTH-PORT">>, <<"port">>], Prop) of
<<>> -> 'undefined';
<<"0">> -> 'undefined';
Port -> Port
end.
-spec get_sip_interface_from_db(kz_term:ne_binaries()) -> kz_term:ne_binary().
get_sip_interface_from_db([FsPath]) ->
NetworkMap = ecallmgr_config:get_json(<<"network_map">>, kz_json:new()),
case map_fs_path_to_sip_profile(FsPath, NetworkMap) of
'undefined' ->
lager:debug("unable to find network map for ~s, using default interface '~s'"
,[FsPath, ?SIP_INTERFACE]),
?SIP_INTERFACE;
Else ->
lager:debug("found custom interface '~s' in network map for ~s", [Else, FsPath]),
Else
end.
-spec map_fs_path_to_sip_profile(kz_term:ne_binary(), kz_json:object()) -> kz_term:api_binary().
map_fs_path_to_sip_profile(FsPath, NetworkMap) ->
SIPInterfaceObj = kz_json:filter(fun({K, _}) ->
kz_network_utils:verify_cidr(FsPath, K)
end, NetworkMap),
case kz_json:get_values(SIPInterfaceObj) of
{[], _Keys} -> 'undefined';
{[V|_], _Keys} -> kz_json:get_ne_value(<<"custom_sip_interface">>, V)
end.
-spec conference_channel_vars(kzd_freeswitch:data()) -> kz_term:proplist().
conference_channel_vars(Props) ->
[conference_channel_var_map(KV) || KV <- conference_channel_vars(Props, [])].
conference_channel_vars(Props, Initial) ->
lists:foldl(fun conference_channel_vars_fold/2, Initial, Props).
-spec conference_channel_vars_fold({kz_term:ne_binary(), kz_term:ne_binary()}, kz_term:proplist()) -> kz_term:proplist().
conference_channel_vars_fold({Key, V}, Acc) ->
case lists:member(Key, ?CONFERENCE_VARS) of
'true' -> [{Key, V} | Acc];
'false' -> Acc
end.
conference_channel_var_map({Key, Value}=KV) ->
case props:get_value(Key, ?CONFERENCE_VAR_MAP) of
'undefined' -> KV;
{NewName, Fun} -> {NewName, Fun(Value)};
Fun -> {Key, Fun(Value)}
end.
-spec channel_var_map({kz_term:ne_binary(), kz_term:ne_binary()}) -> {kz_term:ne_binary(), kz_term:ne_binary() | kz_term:ne_binaries()}.
channel_var_map({Key, <<"ARRAY::", Serialized/binary>>}) ->
{Key, binary:split(Serialized, <<"|:">>, ['global'])};
channel_var_map({Key, Other}) -> {Key, Other}.
%% Extract custom channel variables to include in the event
-spec custom_channel_vars(kzd_freeswitch:data()) -> kz_term:proplist().
custom_channel_vars(Props) ->
lists:map(fun channel_var_map/1, custom_channel_vars(Props, [])).
-spec custom_channel_vars(kz_term:proplist(), kz_term:proplist()) -> kz_term:proplist().
custom_channel_vars(Props, Initial) ->
CCVs = lists:foldl(fun custom_channel_vars_fold/2, Initial, Props),
maybe_update_referred_ccv(Props, channel_vars_sort(CCVs)).
-spec channel_vars_sort(kz_term:proplist()) -> kz_term:proplist().
channel_vars_sort(ChannelVars) ->
lists:usort(fun channel_var_sort/2, ChannelVars).
-spec channel_var_sort(tuple(), tuple()) -> boolean().
channel_var_sort({A, _}, {B, _}) -> A =< B.
-spec custom_channel_vars_fold({kz_term:ne_binary(), kz_term:ne_binary()}, kz_term:proplist()) -> kz_term:proplist().
custom_channel_vars_fold({?GET_CCV(Key), V}, Acc) ->
[{Key, V} | Acc];
custom_channel_vars_fold({?CCV(Key), V}, Acc) ->
[{Key, V} | Acc];
custom_channel_vars_fold({?GET_CCV_HEADER(Key), V}, Acc) ->
case props:is_defined(Key, Acc) of
'true' -> Acc;
'false' -> [{Key, V} | Acc]
end;
custom_channel_vars_fold(_, Acc) -> Acc.
-spec custom_application_vars(kzd_freeswitch:data()) -> kz_term:proplist().
custom_application_vars(Props) ->
lists:map(fun application_var_map/1, custom_application_vars(Props, [])).
-spec custom_application_vars(kz_term:proplist(), kz_term:proplist()) -> kz_term:proplist().
custom_application_vars(Props, Initial) ->
CCVs = lists:foldl(fun custom_application_vars_fold/2, Initial, Props),
application_vars_sort(CCVs).
-spec application_vars_sort(kz_term:proplist()) -> kz_term:proplist().
application_vars_sort(ApplicationVars) ->
lists:usort(fun application_var_sort/2, ApplicationVars).
-spec application_var_sort(tuple(), tuple()) -> boolean().
application_var_sort({A, _}, {B, _}) -> A =< B.
-spec custom_application_vars_fold({kz_term:ne_binary(), kz_term:ne_binary()}, kz_term:proplist()) -> kz_term:proplist().
custom_application_vars_fold({?GET_CAV(Key), V}, Acc) ->
[{Key, V} | Acc];
custom_application_vars_fold({?CAV(Key), V}, Acc) ->
[{Key, V} | Acc];
custom_application_vars_fold({?GET_CAV_HEADER(Key), V}, Acc) ->
case props:is_defined(Key, Acc) of
'true' -> Acc;
'false' -> [{Key, V} | Acc]
end;
custom_application_vars_fold(_, Acc) -> Acc.
-spec application_var_map({kz_term:ne_binary(), kz_term:ne_binary()}) -> {kz_term:ne_binary(), kz_term:ne_binary() | kz_term:ne_binaries()}.
application_var_map({Key, <<"ARRAY::", Serialized/binary>>}) ->
{Key, binary:split(Serialized, <<"|:">>, ['global'])};
application_var_map({Key, Other}) -> {Key, Other}.
-spec maybe_update_referred_ccv(kz_term:proplist(), kz_term:proplist()) -> kz_term:proplist().
maybe_update_referred_ccv(Props, CCVs) ->
ReferTo = props:get_value(<<"variable_sip_refer_to">>, Props),
update_referred_by_ccv(props:get_value(<<"variable_sip_h_Referred-By">>, Props)
,update_referred_to_ccv(ReferTo, CCVs)
).
-spec update_referred_by_ccv(kz_term:api_binary(), kz_term:proplist()) -> kz_term:proplist().
update_referred_by_ccv('undefined', CCVs) -> props:delete(<<"Referred-By">>, CCVs);
update_referred_by_ccv(ReferredBy, CCVs) ->
props:set_value(<<"Referred-By">>
,kz_http_util:urldecode(ReferredBy)
,CCVs
).
-spec update_referred_to_ccv(kz_term:api_binary(), kz_term:proplist()) -> kz_term:proplist().
update_referred_to_ccv('undefined', CCVs) -> props:delete(<<"Referred-To">>, CCVs);
update_referred_to_ccv(ReferredTo, CCVs) ->
props:set_value(<<"Referred-To">>
,kz_http_util:urldecode(ReferredTo)
,CCVs
).
%% convert a raw FS string of headers to a proplist
%% "Event-Name: NAME\nEvent-Timestamp: 1234\n" -> [{<<"Event-Name">>, <<"NAME">>}, {<<"Event-Timestamp">>, <<"1234">>}]
-spec eventstr_to_proplist(kz_term:text()) -> kz_term:proplist().
eventstr_to_proplist(EvtStr) ->
[to_kv(X, ": ") || X <- string:tokens(kz_term:to_list(EvtStr), "\n")].
-spec to_kv(nonempty_string(), nonempty_string()) -> {kz_term:ne_binary(), kz_term:ne_binary()}.
to_kv(X, Separator) ->
[K, V] = string:tokens(X, Separator),
[{V1, _}] = kz_http_util:parse_query_string(list_to_binary(V)),
{kz_term:to_binary(K), kz_term:to_binary(fix_value(K, V1))}.
fix_value("Event-Date-Timestamp", TStamp) ->
kz_time:microseconds_to_seconds(kz_term:to_integer(TStamp));
fix_value(_K, V) -> V.
-spec unserialize_fs_array(kz_term:api_binary()) -> kz_term:ne_binaries().
unserialize_fs_array('undefined') -> [];
unserialize_fs_array(<<"ARRAY::", Serialized/binary>>) ->
binary:split(Serialized, <<"|:">>, ['global']);
unserialize_fs_array(List)
when is_list(List) ->
List;
unserialize_fs_array(Single) ->
[Single].
-spec unserialize_fs_props(kz_term:proplist()) -> kz_term:proplist().
unserialize_fs_props(Props) ->
lists:map(fun unserialize_fs_prop/1, Props).
-spec unserialize_fs_prop(tuple()) -> tuple().
unserialize_fs_prop({K, <<"ARRAY::", _/binary>> = V}) ->
{K, unserialize_fs_array(V)};
unserialize_fs_prop(KV) -> KV.
%% convert a raw FS list of vars to a proplist
%% "Event-Name=NAME,Event-Timestamp=1234" -> [{<<"Event-Name">>, <<"NAME">>}, {<<"Event-Timestamp">>, <<"1234">>}]
-spec varstr_to_proplist(nonempty_string()) -> kz_term:proplist().
varstr_to_proplist(VarStr) ->
[to_kv(X, "=") || X <- string:tokens(kz_term:to_list(VarStr), ",")].
-spec get_setting(kz_json:path()) -> {'ok', any()}.
get_setting(<<"default_ringback">>) ->
{'ok', ecallmgr_config:get(<<"default_ringback">>, <<"%(2000,4000,440,480)">>)};
get_setting(Setting) -> {'ok', ecallmgr_config:get(Setting)}.
-spec get_setting(kz_json:path(), Default) -> {'ok', Default | any()}.
get_setting(Setting, Default) -> {'ok', ecallmgr_config:get(Setting, Default)}.
-spec is_node_up(atom()) -> boolean().
is_node_up(Node) -> ecallmgr_fs_nodes:is_node_up(Node).
-spec is_node_up(atom(), kz_term:ne_binary()) -> boolean().
is_node_up(Node, UUID) ->
ecallmgr_fs_nodes:is_node_up(Node)
andalso ecallmgr_fs_channel:exists(UUID).
%%------------------------------------------------------------------------------
%% @doc set channel and call variables in FreeSWITCH
%% @end
%%------------------------------------------------------------------------------
-spec multi_set_args(atom(), kz_term:ne_binary(), kz_term:proplist()) -> binary().
multi_set_args(Node, UUID, KVs) ->
multi_set_args(Node, UUID, KVs, <<?FS_MULTI_VAR_SEP>>).
-spec multi_set_args(atom(), kz_term:ne_binary(), kz_term:proplist(), kz_term:ne_binary()) -> binary().
multi_set_args(Node, UUID, KVs, Separator) ->
multi_set_args(Node, UUID, KVs, Separator, ?FS_MULTI_VAR_SEP_PREFIX).
-spec multi_set_args(atom(), kz_term:ne_binary(), kz_term:proplist(), kz_term:ne_binary(), binary() | string()) -> binary().
multi_set_args(Node, UUID, KVs, Separator, Prefix) ->
fs_args_to_binary(lists:reverse(process_fs_kv(Node, UUID, KVs, 'set')), Separator, Prefix).
-spec multi_unset_args(atom(), kz_term:ne_binary(), kz_term:proplist()) -> binary().
multi_unset_args(Node, UUID, KVs) ->
multi_unset_args(Node, UUID, KVs, <<?FS_MULTI_VAR_SEP>>).
-spec multi_unset_args(atom(), kz_term:ne_binary(), kz_term:proplist(), kz_term:ne_binary()) -> binary().
multi_unset_args(Node, UUID, KVs, Separator) ->
multi_unset_args(Node, UUID, KVs, Separator, ?FS_MULTI_VAR_SEP_PREFIX).
-spec multi_unset_args(atom(), kz_term:ne_binary(), kz_term:proplist(), kz_term:ne_binary(), binary() | string()) -> binary().
multi_unset_args(Node, UUID, KVs, Separator, Prefix) ->
fs_args_to_binary(lists:reverse(process_fs_kv(Node, UUID, KVs, 'unset')), Separator, Prefix).
-spec fs_args_to_binary(list()) -> binary().
fs_args_to_binary([_]=Args) ->
list_to_binary(Args);
fs_args_to_binary(Args) ->
fs_args_to_binary(Args, <<?FS_MULTI_VAR_SEP>>).
-spec fs_args_to_binary(list(), kz_term:ne_binary()) -> binary().
fs_args_to_binary(Args, Sep) ->
fs_args_to_binary(Args, Sep, ?FS_MULTI_VAR_SEP_PREFIX).
-spec fs_args_to_binary(list(), kz_term:ne_binary(), binary() | string()) -> binary().
fs_args_to_binary(Args, Sep, Prefix) ->
Bins = [list_to_binary([Sep, Arg]) || Arg <- Args],
list_to_binary([Prefix, Bins]).
-spec process_fs_kv(atom(), kz_term:ne_binary(), kz_term:proplist(), atom()) -> [binary()].
process_fs_kv(_, _, [], _) -> [];
process_fs_kv(Node, UUID, [{K, V}|KVs], Action) ->
X1 = format_fs_kv(K, V, UUID, Action),
lists:foldl(fun(Prop, Acc) ->
process_fs_kv_fold(Node, UUID, Prop, Action, Acc)
end, X1, KVs);
process_fs_kv(Node, UUID, [K|KVs], 'unset'=Action)
when is_binary(K) ->
X1 = get_fs_key(K),
lists:foldl(fun(Prop, Acc) ->
process_fs_kv_fold(Node, UUID, Prop, Action, Acc)
end, [<<X1/binary, "=">>], KVs).
process_fs_kv_fold(_Node, UUID, {K, V}, Action, Acc) ->
[format_fs_kv(K, V, UUID, Action) | Acc];
process_fs_kv_fold(_Node, _UUID, K, 'unset', Acc)
when is_binary(K) ->
Key = get_fs_key(K),
[<<Key/binary, "=">> | Acc];
process_fs_kv_fold(_, _, _, _, Acc) ->
Acc.
-spec format_fs_kv(kz_term:ne_binary(), binary(), kz_term:ne_binary(), atom()) -> [binary()].
format_fs_kv(Key, Value, UUID, 'unset') ->
case get_fs_key_and_value(Key, Value, UUID) of
'skip' -> [];
{K, _V} -> [<<K/binary, "=">>];
KVs -> [<<K/binary, "=">> || {K,_V} <- KVs]
end;
format_fs_kv(_Key, 'undefined', _UUID, _) -> [];
format_fs_kv(Key, Value, UUID, _) ->
case get_fs_key_and_value(Key, Value, UUID) of
'skip' -> [];
{K, V} -> [<<K/binary, "=", V/binary>>];
KVs -> [<<K/binary, "=", V/binary>> || {K,V} <- KVs]
end.
-spec get_fs_kv(kz_term:ne_binary(), kz_term:ne_binary()) -> binary().
get_fs_kv(Key, Value) ->
get_fs_kv(Key, Value, 'undefined').
-spec get_fs_kv(kz_term:ne_binary(), kz_term:ne_binary(), kz_term:api_binary()) -> binary().
get_fs_kv(<<"Hold-Media">>, Media, UUID) ->
list_to_binary(["hold_music="
,kz_term:to_list(media_path(Media, 'extant', UUID, kz_json:new()))
]);
get_fs_kv(?CCV(Key), Val, UUID) ->
get_fs_kv(Key, Val, UUID);
get_fs_kv(Key, Val, _) ->
list_to_binary([get_fs_key(Key), "=", maybe_sanitize_fs_value(Key, Val)]).
-spec get_fs_key(kz_term:ne_binary()) -> binary().
get_fs_key(?CCV(Key)) -> get_fs_key(Key);
get_fs_key(?CAV(_)=CAV) -> CAV;
get_fs_key(<<"X-", _/binary>>=Key) -> <<"sip_h_", Key/binary>>;
get_fs_key(Key) ->
case lists:keyfind(Key, 1, ?SPECIAL_CHANNEL_VARS) of
'false' -> ?CCV(Key);
{_, Prefix} -> Prefix
end.
-spec get_fs_key_and_value(kz_term:ne_binary()
,kz_term:ne_binary() | kz_term:ne_binaries() | kz_json:object()
,kz_term:ne_binary()
) ->
{kz_term:ne_binary(), binary()} |
[{kz_term:ne_binary(), binary()}] |
'skip'.
get_fs_key_and_value(<<"Hold-Media">>=Key, Media, UUID) ->
{get_fs_key(Key), media_path(Media, 'extant', UUID, kz_json:new())};
get_fs_key_and_value(<<"Diversions">>=Key, Diversions, _UUID) ->
K = get_fs_key(Key),
lager:debug("setting diversions ~p on the channel", [Diversions]),
[{K, D} || D <- Diversions];
get_fs_key_and_value(<<"Auto-Answer">> = Key, Value, _UUID) ->
[{get_fs_key(<<"Alert-Info">>), <<"intercom">>}
,{get_fs_key(Key), maybe_sanitize_fs_value(Key, Value)}
];
get_fs_key_and_value(<<"Auto-Answer-Suppress-Notify">> = Key, Value, _UUID) ->
[{get_fs_key(<<"Alert-Info">>), <<"intercom">>}
,{get_fs_key(<<"Auto-Answer">>), maybe_sanitize_fs_value(<<"Auto-Answer">>, <<"true">>)}
,{get_fs_key(Key), maybe_sanitize_fs_value(Key, Value)}
];
get_fs_key_and_value(<<"ringback">>=Key, Value, _UUID) ->
[{<<"ringback">>, maybe_sanitize_fs_value(Key, Value)}
,{<<"transfer_ringback">>, maybe_sanitize_fs_value(<<"transfer_ringback">>, Value)}
];
get_fs_key_and_value(?CCV(Key), Val, UUID) ->
get_fs_key_and_value(Key, Val, UUID);
get_fs_key_and_value(Key, Val, _UUID)
when is_binary(Val);
is_atom(Val);
is_number(Val);
is_list(Val);
is_boolean(Val) ->
{get_fs_key(Key), maybe_sanitize_fs_value(Key, Val)};
get_fs_key_and_value(_, _, _) -> 'skip'.
%%------------------------------------------------------------------------------
%% @doc
%% @end
%%------------------------------------------------------------------------------
-spec maybe_sanitize_fs_value(kz_term:text(), kz_term:text()) -> binary().
maybe_sanitize_fs_value(<<"Outbound-Caller-ID-Name">>, Val) ->
re:replace(Val, <<"[^a-zA-Z0-9-\s]">>, <<>>, ['global', {'return', 'binary'}]);
maybe_sanitize_fs_value(<<"Outbound-Callee-ID-Name">>, Val) ->
re:replace(Val, <<"[^a-zA-Z0-9-\s]">>, <<>>, ['global', {'return', 'binary'}]);
maybe_sanitize_fs_value(<<"Caller-ID-Name">>, Val) ->
re:replace(Val, <<"[^a-zA-Z0-9-\s]">>, <<>>, ['global', {'return', 'binary'}]);
maybe_sanitize_fs_value(<<"Callee-ID-Name">>, Val) ->
re:replace(Val, <<"[^a-zA-Z0-9-\s]">>, <<>>, ['global', {'return', 'binary'}]);
maybe_sanitize_fs_value(Key, Val) when not is_binary(Key) ->
maybe_sanitize_fs_value(kz_term:to_binary(Key), Val);
maybe_sanitize_fs_value(Key, Val) when not is_binary(Val) ->
maybe_sanitize_fs_value(Key, kz_term:to_binary(Val));
maybe_sanitize_fs_value(_, Val) -> Val.
%%------------------------------------------------------------------------------
%% @doc takes endpoints (/sofia/foo/bar), and optionally a caller id name/num
%% and create the dial string ([origination_caller_id_name=Name
%% ,origination_caller_id_number=Num]Endpoint)
%% joined by the optional seperator. Saves time by not spawning
%% endpoints with the invite format of "route" (about 100ms per endpoint)
%% @end
%%------------------------------------------------------------------------------
-type bridge_channel() :: kz_term:ne_binary().
-type bridge_channels() :: kz_term:ne_binaries().
-type build_return() :: bridge_channel() | {'worker', pid()}.
-type build_returns() :: [build_return()].
-type bridge_endpoints() :: [bridge_endpoint()].
-spec build_bridge_string(kz_json:objects()) -> kz_term:ne_binary().
build_bridge_string(Endpoints) ->
build_bridge_string(Endpoints, ?SEPARATOR_SINGLE).
-spec build_bridge_string(kz_json:objects(), kz_term:ne_binary()) -> kz_term:ne_binary().
build_bridge_string(Endpoints, Seperator) ->
%% De-dup the bridge strings by matching those with the same
%% Invite-Format, To-IP, To-User, To-realm, To-DID, and Route
BridgeStrings = build_bridge_channels(Endpoints),
%% NOTE: dont use binary_join here as it will crash on an empty list...
kz_binary:join(lists:reverse(BridgeStrings), Seperator).
-spec endpoint_jobjs_to_records(kz_json:objects()) -> bridge_endpoints().
endpoint_jobjs_to_records(Endpoints) ->
endpoint_jobjs_to_records(Endpoints, 'true').
-spec endpoint_jobjs_to_records(kz_json:objects(), boolean()) -> bridge_endpoints().
endpoint_jobjs_to_records(Endpoints, IncludeVars) ->
[BridgeEndpoints
|| {_, BridgeEndpoints} <-
endpoint_jobjs_to_records(Endpoints, IncludeVars, [])
].
endpoint_jobjs_to_records([], _, BridgeEndpoints) ->
lists:reverse(BridgeEndpoints);
endpoint_jobjs_to_records([Endpoint|Endpoints], IncludeVars, BridgeEndpoints) ->
Key = endpoint_key(Endpoint),
case kapi_dialplan:bridge_endpoint_v(Endpoint)
andalso (not lists:keymember(Key, 1, BridgeEndpoints))
of
'false' ->
lager:debug("skipping invalid or duplicate endpoint: ~-300p~n", [Key]),
endpoint_jobjs_to_records(Endpoints, IncludeVars, BridgeEndpoints);
'true' ->
lager:debug("building bridge endpoint: ~-300p~n", [Key]),
BridgeEndpoint = endpoint_jobj_to_record(Endpoint, IncludeVars),
endpoint_jobjs_to_records(Endpoints, IncludeVars
,[{Key, BridgeEndpoint}|BridgeEndpoints]
)
end.
-spec endpoint_key(kz_json:object()) -> kz_term:api_binaries().
endpoint_key(Endpoint) ->
[kz_json:get_value(<<"Invite-Format">>, Endpoint)
,kz_json:get_value(<<"To-User">>, Endpoint)
,kz_json:get_value(<<"To-Realm">>, Endpoint)
,kz_json:get_value(<<"To-DID">>, Endpoint)
,kz_json:get_value(<<"Route">>, Endpoint)
,kz_json:get_value(<<"Proxy-Zone">>, Endpoint)
,kz_json:get_value(<<"Proxy-IP">>, Endpoint)
].
-spec endpoint_jobj_to_record(kz_json:object()) -> bridge_endpoint().
endpoint_jobj_to_record(Endpoint) ->
endpoint_jobj_to_record(Endpoint, 'true').
-spec endpoint_jobj_to_record(kz_json:object(), boolean()) -> bridge_endpoint().
endpoint_jobj_to_record(Endpoint, IncludeVars) ->
ToUser = kz_json:get_ne_value(<<"To-User">>, Endpoint),
Bridge = #bridge_endpoint{invite_format = kz_json:get_ne_value(<<"Invite-Format">>, Endpoint, <<"username">>)
,endpoint_type = kz_json:get_ne_value(<<"Endpoint-Type">>, Endpoint, <<"sip">>)
,ip_address = kz_json:get_ne_value(<<"To-IP">>, Endpoint)
,username = kz_json:get_ne_value(<<"To-Username">>, Endpoint, ToUser)
,user = ToUser
,realm = kz_json:get_ne_value(<<"To-Realm">>, Endpoint)
,number = kz_json:get_ne_value(<<"To-DID">>, Endpoint)
,route = kz_json:get_ne_value(<<"Route">>, Endpoint)
,proxy_address = kz_json:get_ne_value(<<"Proxy-IP">>, Endpoint)
,forward_address = kz_json:get_ne_value(<<"Forward-IP">>, Endpoint)
,transport = kz_json:get_ne_value(<<"SIP-Transport">>, Endpoint)
,span = get_endpoint_span(Endpoint)
,channel_selection = get_endpoint_channel_selection(Endpoint)
,interface = get_endpoint_interface(Endpoint)
,sip_interface = kz_json:get_ne_value(<<"SIP-Interface">>, Endpoint)
,include_channel_vars = IncludeVars
,failover = kz_json:get_value(<<"Failover">>, Endpoint)
},
endpoint_jobj_to_record_vars(Endpoint, Bridge).
-spec endpoint_jobj_to_record_vars(kz_json:object(), bridge_endpoint()) -> bridge_endpoint().
endpoint_jobj_to_record_vars(Endpoint, #bridge_endpoint{include_channel_vars='true'}=Bridge) ->
Bridge#bridge_endpoint{channel_vars=ecallmgr_fs_xml:build_leg_vars(Endpoint)};
endpoint_jobj_to_record_vars(Endpoint, #bridge_endpoint{include_channel_vars='false'}=Bridge) ->
Props = lists:filter(fun({<<"Custom-SIP-Headers">>, _}) -> 'true';
(_) -> 'false'
end
,kz_json:to_proplist(Endpoint)
),
Bridge#bridge_endpoint{header_vars=ecallmgr_fs_xml:build_leg_vars(Props)}.
-spec get_endpoint_span(kz_json:object()) -> kz_term:ne_binary().
get_endpoint_span(Endpoint) ->
kz_json:get_binary_value([<<"Endpoint-Options">>, <<"Span">>], Endpoint, <<"1">>).
-spec get_endpoint_channel_selection(kz_json:object()) -> kz_term:ne_binary().
get_endpoint_channel_selection(Endpoint) ->
case kz_json:get_binary_value([<<"Endpoint-Options">>, <<"Span">>], Endpoint) of
<<"descending">> -> <<"A">>;
_Else -> <<"a">>
end.
-spec get_endpoint_interface(kz_json:object()) -> kz_term:ne_binary().
get_endpoint_interface(Endpoint) ->
case kz_json:is_true([<<"Endpoint-Options">>, <<"Skype-RR">>], Endpoint, 'false') of
'false' -> kz_json:get_value([<<"Endpoint-Options">>, <<"Skype-Interface">>], Endpoint);
'true' -> <<"RR">>
end.
-spec build_simple_channels(bridge_endpoints()) -> bridge_channels().
build_simple_channels(Endpoints) ->
EPs = endpoint_jobjs_to_records(Endpoints, 'false'),
build_bridge_channels(EPs, []).
-spec build_bridge_channels(kz_json:objects()) -> bridge_channels().
build_bridge_channels(Endpoints) ->
CWEP = maybe_apply_call_waiting(Endpoints),
EPs = endpoint_jobjs_to_records(CWEP),
build_bridge_channels(EPs, []).
-spec maybe_apply_call_waiting(kz_json:objects()) -> kz_json:objects().
maybe_apply_call_waiting(Endpoints) ->
[call_waiting_map(E) || E <- Endpoints].
-spec call_waiting_map(kz_json:object()) -> kz_json:object().
call_waiting_map(Endpoint) ->
CCVs = kz_json:get_json_value(<<"Custom-Channel-Vars">>, Endpoint, kz_json:new()),
case kz_json:is_true(<<"Call-Waiting-Disabled">>, CCVs) of
'false' -> Endpoint;
'true' ->
OwnerId = kz_json:get_value(<<"Owner-ID">>, CCVs),
maybe_add_respond_header(Endpoint, OwnerId)
end.
-spec maybe_add_respond_header(kz_json:object(), kz_term:ne_binary()) -> kz_json:object().
maybe_add_respond_header(Endpoint, OwnerId) ->
case ecallmgr_fs_channels:has_channels_for_owner(OwnerId) of
'true' ->
lager:debug("Channel must be busy!"),
kz_json:set_value([<<"Custom-SIP-Headers">>, <<"X-KAZOO-Respond-With">>], <<"486 User Busy">>, Endpoint);
'false' ->
Endpoint
end.
-spec build_bridge_channels(bridge_endpoints(), build_returns()) -> bridge_channels().
%% If the Invite-Format is "route" then we have been handed a sip route, do that now
build_bridge_channels([#bridge_endpoint{invite_format = <<"route">>}=Endpoint|Endpoints], Channels) ->
case build_channel(Endpoint) of
{'error', _} -> build_bridge_channels(Endpoints, Channels);
{'ok', Channel} -> build_bridge_channels(Endpoints, [Channel|Channels])
end;
build_bridge_channels([#bridge_endpoint{invite_format = <<"loopback">>}=Endpoint|Endpoints], Channels) ->
case build_channel(Endpoint) of
{'error', _} -> build_bridge_channels(Endpoints, Channels);
{'ok', Channel} -> build_bridge_channels(Endpoints, [Channel|Channels])
end;
%% If this does not have an explicted sip route and we have no ip address, lookup the registration
build_bridge_channels([#bridge_endpoint{ip_address='undefined'}=Endpoint|Endpoints], Channels) ->
S = self(),
Pid = kz_util:spawn(fun() -> S ! {self(), build_channel(Endpoint)} end),
build_bridge_channels(Endpoints, [{'worker', Pid}|Channels]);
%% If we have been given a IP to route to then do that now
build_bridge_channels([Endpoint|Endpoints], Channels) ->
case build_channel(Endpoint) of
{'error', _} -> build_bridge_channels(Endpoints, Channels);
{'ok', Channel} -> build_bridge_channels(Endpoints, [Channel|Channels])
end;
%% wait for any registration lookups to complete
build_bridge_channels([], IntermediateResults) ->
lists:foldr(fun intermediate_results_fold/2, [], IntermediateResults).
-spec intermediate_results_fold(build_return(), bridge_channels()) -> bridge_channels().
intermediate_results_fold({'worker', Pid}, Channels) ->
maybe_collect_worker_channel(Pid, Channels);
intermediate_results_fold(Channel, Channels) ->
[Channel|Channels].
-spec maybe_collect_worker_channel(pid(), bridge_channels()) -> bridge_channels().
maybe_collect_worker_channel(Pid, Channels) ->
receive
{Pid, {'error', _}} -> Channels;
{Pid, {'ok', Channel}} -> [Channel|Channels]
after
2 * ?MILLISECONDS_IN_SECOND -> Channels
end.
-spec build_channel(bridge_endpoint() | kz_json:object()) ->
{'ok', bridge_channel()} |
{'error', any()}.
build_channel(#bridge_endpoint{endpoint_type = <<"freetdm">>}=Endpoint) ->
build_freetdm_channel(Endpoint);
build_channel(#bridge_endpoint{endpoint_type = <<"skype">>}=Endpoint) ->
build_skype_channel(Endpoint);
build_channel(#bridge_endpoint{endpoint_type = <<"sip">>}=Endpoint) ->
build_sip_channel(Endpoint);
build_channel(EndpointJObj) ->
build_channel(endpoint_jobj_to_record(EndpointJObj)).
-spec build_freetdm_channel(bridge_endpoint()) ->
{'ok', bridge_channel()} |
{'error', 'number_not_provided'}.
build_freetdm_channel(#bridge_endpoint{number='undefined'}) ->
{'error', 'number_not_provided'};
build_freetdm_channel(#bridge_endpoint{invite_format = <<"e164">>
,number=Number
,span=Span
,channel_selection=ChannelSelection
}) ->
{'ok', <<"freetdm/", Span/binary, "/", ChannelSelection/binary, "/", (knm_converters:normalize(Number))/binary>>};
build_freetdm_channel(#bridge_endpoint{invite_format = <<"npan">>
,number=Number
,span=Span
,channel_selection=ChannelSelection
}) ->
{'ok', <<"freetdm/", Span/binary, "/", ChannelSelection/binary, "/", (knm_converters:to_npan(Number))/binary>>};
build_freetdm_channel(#bridge_endpoint{invite_format = <<"1npan">>
,number=Number
,span=Span
,channel_selection=ChannelSelection
}) ->
{'ok', <<"freetdm/", Span/binary, "/", ChannelSelection/binary, "/", (knm_converters:to_1npan(Number))/binary>>};
build_freetdm_channel(#bridge_endpoint{number=Number
,span=Span
,channel_selection=ChannelSelection
}) ->
{'ok', <<"freetdm/", Span/binary, "/", ChannelSelection/binary, "/", Number/binary>>}.
-spec build_skype_channel(bridge_endpoint()) ->
{'ok', bridge_channel()} |
{'error', 'number_not_provided'}.
build_skype_channel(#bridge_endpoint{user='undefined'}) ->
{'error', 'number_not_provided'};
build_skype_channel(#bridge_endpoint{user=User, interface=IFace}) ->
{'ok', <<"skypopen/", IFace/binary, "/", User/binary>>}.
-spec build_sip_channel(bridge_endpoint()) ->
{'ok', bridge_channel()} |
{'error', any()}.
build_sip_channel(#bridge_endpoint{failover=Failover}=Endpoint) ->
Routines = [fun get_sip_contact/1
,fun maybe_clean_contact/2
,fun ensure_username_present/2
,fun maybe_replace_fs_path/2
,fun maybe_replace_transport/2
,fun maybe_format_user/2
,fun maybe_set_interface/2
,fun maybe_append_channel_vars/2
],
try lists:foldl(fun build_sip_channel_fold/2, Endpoint, Routines) of
{Channel, _} -> {'ok', Channel}
catch
_E:{'badmatch', {'error', 'not_found'}} ->
lager:warning("Failed to build sip channel trying failover", []),
maybe_failover(Failover);
_E:_R ->
ST = erlang:get_stacktrace(),
lager:warning("Failed to build sip channel (~s): ~p", [_E, _R]),
kz_util:log_stacktrace(ST),
{'error', 'invalid'}
end.
-type build_channel_fun_1() :: fun((bridge_endpoint()) -> bridge_channel() | {bridge_channel(), bridge_endpoint()}).
-type build_channel_fun_2() :: fun((bridge_channel(), bridge_endpoint()) -> bridge_channel() | {bridge_channel(), bridge_endpoint()}).
-type build_channel_fun() :: build_channel_fun_1() | build_channel_fun_2().
-type build_channel_acc() :: bridge_channel() | {bridge_channel(), bridge_endpoint()}.
-spec build_sip_channel_fold(build_channel_fun(), build_channel_acc()) -> build_channel_acc().
build_sip_channel_fold(Fun, {Contact, Endpoint}) ->
case Fun(Contact, Endpoint) of
{NewContact, NewEndpoint} -> {NewContact, NewEndpoint};
NewContact -> {NewContact, Endpoint}
end;
build_sip_channel_fold(Fun, Endpoint) ->
case Fun(Endpoint) of
{NewContact, NewEndpoint} -> {NewContact, NewEndpoint};
NewContact -> {NewContact, Endpoint}
end.
-spec maybe_failover(kz_json:object()) ->
{'ok', bridge_channel()} |
{'error', any()}.
maybe_failover(Endpoint) ->
case kz_term:is_empty(Endpoint) of
'true' -> {'error', 'invalid'};
'false' -> build_sip_channel(endpoint_jobj_to_record(Endpoint))
end.
-spec get_sip_contact(bridge_endpoint()) -> kz_term:ne_binary().
-ifdef(TEST).
get_sip_contact(#bridge_endpoint{invite_format = <<"route">>, route = <<"loopback/", Route/binary>>}) ->
<<"loopback/", Route/binary, "/", (?DEFAULT_FREESWITCH_CONTEXT)/binary>>;
get_sip_contact(#bridge_endpoint{invite_format = <<"route">>, route=Route}) ->
Route;
get_sip_contact(#bridge_endpoint{invite_format = <<"loopback">>, route=Route}) ->
<<"loopback/", Route/binary, "/", (?DEFAULT_FREESWITCH_CONTEXT)/binary>>;
get_sip_contact(#bridge_endpoint{ip_address='undefined'
,realm=Realm
,username=Username
}) ->
<<Username/binary, "@", Realm/binary>>;
get_sip_contact(#bridge_endpoint{ip_address=IPAddress}) -> IPAddress.
-else.
get_sip_contact(#bridge_endpoint{invite_format = <<"route">>, route = <<"loopback/", Route/binary>>}) ->
<<"loopback/", Route/binary, "/", (?DEFAULT_FREESWITCH_CONTEXT)/binary>>;
get_sip_contact(#bridge_endpoint{invite_format = <<"route">>, route=Route}) ->
Route;
get_sip_contact(#bridge_endpoint{invite_format = <<"loopback">>, route=Route}) ->
<<"loopback/", Route/binary, "/", (?DEFAULT_FREESWITCH_CONTEXT)/binary>>;
get_sip_contact(#bridge_endpoint{ip_address='undefined'
,realm=Realm
,username=Username
,channel_vars=CVs
}=EP) ->
{'ok', Contact, Props} = ecallmgr_registrar:lookup_contact(Realm, Username),
Vars = ecallmgr_fs_xml:build_leg_vars(Props),
NewEP = EP#bridge_endpoint{channel_vars=Vars ++ CVs},
{binary:replace(Contact, <<">">>, <<>>), NewEP};
get_sip_contact(#bridge_endpoint{ip_address=IPAddress}) -> IPAddress.
-endif.
-spec maybe_clean_contact(kz_term:ne_binary(), bridge_endpoint()) -> kz_term:ne_binary().
maybe_clean_contact(<<"sip:", Contact/binary>>, _Endpoint) -> Contact;
maybe_clean_contact(<<"sips:", Contact/binary>>, _Endpoint) -> Contact;