libcopp-config.cmake.in

#.rst:
# Libcoppconfig.cmake
# --------
#
# Find the native libcopp includes and library.
#
#
# Result Variables
# ^^^^^^^^^^^^^^^^
#
# This module defines the following variables:
#
# ::
#
#   <PackageName>_INCLUDE_DIRS    - where to find libcopp/utils/config/libcopp_build_features.h , etc.
#   <PackageName>_LIBRARY_DIRS    - where to find (lib)copp/cotask.(a/so/lib/dll/dylib), etc.
#   <PackageName>_LIBRARIES       - List of libraries when using libcopp.
#   Libcotask_LIBRARIES           - List of libraries when using libcotask.
#   libcotask_LIBRARIES           - List of libraries when using libcotask.
#   <PackageName>_FOUND           - True if libcopp found.
#   LIBCOPP_FOUND                 - True if libcopp found.
#   <PackageName>_VERSION         - Full version of libcopp
#
# ::
#   libcopp::copp           - Imported target of libcopp
#   libcopp::cotask         - Imported target of libcotask if available
#

# =============================================================================
# Copyright 2020 OWenT.
#
# Distributed under the OSI-approved BSD License (the "License"); see accompanying file Copyright.txt for details.
#
# This software is distributed WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
# A PARTICULAR PURPOSE. See the License for more information.
# =============================================================================
# (To distribute this file outside of CMake, substitute the full License text for the above reference.)

set(${CMAKE_FIND_PACKAGE_NAME}_VERSION "@PROJECT_VERSION@")

@PACKAGE_INIT@

# ######################################################################################################################
# libcopp source dir
set(${CMAKE_FIND_PACKAGE_NAME}_SOURCE_DIR "@PROJECT_SOURCE_DIR@")

set_and_check(${CMAKE_FIND_PACKAGE_NAME}_INCLUDE_DIRS "@PACKAGE_INCLUDE_INSTALL_DIR@")
set_and_check(${CMAKE_FIND_PACKAGE_NAME}_LIBRARY_DIRS "@PACKAGE_CMAKE_INSTALL_LIBDIR@")

include("${CMAKE_CURRENT_LIST_DIR}/@PROJECT_LIBCOPP_EXPORT_NAME@.cmake")
if(EXISTS "${CMAKE_CURRENT_LIST_DIR}/@PROJECT_LIBCOTASK_EXPORT_NAME@.cmake")
  include("${CMAKE_CURRENT_LIST_DIR}/@PROJECT_LIBCOTASK_EXPORT_NAME@.cmake")
endif()
# Normal search.
set(${CMAKE_FIND_PACKAGE_NAME}_LIBRARIES libcopp::copp)
if(TARGET libcopp::cotask)
  set(Libcotask_LIBRARIES libcopp::cotask)
  set(libcotask_LIBRARIES libcopp::cotask)
endif()

set(LIBCOPP_FOUND ${${CMAKE_FIND_PACKAGE_NAME}_FOUND})

# check_required_components(Libcopp)