build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
subprojects { project ->
  group = GROUP
  version = VERSION_NAME

  apply plugin: 'checkstyle'

  task checkstyle(type: Checkstyle) {
    configFile rootProject.file('checkstyle.xml')
    source 'src/main/java'
    ignoreFailures false
    showViolations true
    include '**/*.java'

    classpath = files()
  }

  afterEvaluate {
    if (project.tasks.findByName('check')) {
      check.dependsOn('checkstyle')
    }
  }

  buildscript {
    repositories {
      google()
      jcenter()
    }
    dependencies {
      classpath 'com.android.tools.build:gradle:3.0.1'
    }
  }

  repositories {
    google()
    jcenter()
  }
}

ext {
  minSdkVersion = 8
  targetSdkVersion = 27
  compileSdkVersion = 27
  buildToolsVersion = '27.0.3'
  sourceCompatibilityVersion = JavaVersion.VERSION_1_7
  targetCompatibilityVersion = JavaVersion.VERSION_1_7
}

ext.deps = [
    // Test dependencies
    junit             : 'junit:junit:4.12',
    truth             : 'com.google.truth:truth:0.28',
    robolectric       : 'org.robolectric:robolectric:3.3',
    mockito           : "org.mockito:mockito-core:1.10.19",
    json              : "org.json:json:20160810",
    supportAnnotations: "com.android.support:support-annotations:27.1.0"
]