-
Notifications
You must be signed in to change notification settings - Fork 6
/
Copy pathMain.iss
999 lines (885 loc) · 64.2 KB
/
Main.iss
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
; Input defines: ConfigurationName (Debug or Release), PlatformName (Win32, x64, etc.)
; Change from "Yes" to "No" on the next line if you don't compile an alpha build
#define alpha "Yes"
#if VER < 0x05010700
#error Inno Setup version 5.1.7 or higher is needed for this script
#endif
#if PREPROCVER < 0x05020000
#error PreProcessor version 5.2.0.0 or higher is needed for this script
#endif
; Select file source root
#ifexist "..\VS2005\" + ConfigurationName + PlatformName + "\PeerProject.exe"
#define root "..\VS2005\" + ConfigurationName + PlatformName
#endif
#ifndef root
#error You must compile PeerProject and all plugins before compiling Setup
#endif
; Project definitions
#define peerproject "..\" + root + "\PeerProject.exe"
#define internal_name GetStringFileInfo(peerproject, INTERNAL_NAME);
#if ConfigurationName == "Debug"
#define name internal_name + " Debug Build"
#else
#define name internal_name
#endif
#define version GetFileVersion(peerproject)
#define Publisher "PeerProject Development Team"
#define Description internal_name + " Filesharing System"
#define date GetDateTimeString('yyyy/mm/dd', '-', '')
#if ConfigurationName == "Debug"
#define output_name internal_name + "_" + version + "_" + date + "_" + PlatformName + "_" + ConfigurationName
#elif alpha == "Yes"
#define output_name internal_name + "_" + version + "_" + date + "_VS2005"
#elif PlatformName == "x64"
#define output_name internal_name + "_" + version + "_" + PlatformName
#else
#define output_name internal_name + "_" + version
#endif
[Setup]
AppComments={#Description}
AppId={#internal_name}
AppName={#name}
AppVersion={#version}
AppVerName={#name} {#version}
AppMutex={#internal_name},Global\TorrentWizard
DefaultDirName={ini:{param:SETTINGS|},Locations,Path|{reg:HKLM\SOFTWARE\{#internal_name},|{pf}\{#internal_name}}}
DirExistsWarning=no
DefaultGroupName={#internal_name}
#if VER > 0x05030200
DisableProgramGroupPage=auto
#endif
AllowNoIcons=yes
OutputDir=VS2005\Installer
OutputBaseFilename={#output_name}
SolidCompression=yes
Compression=lzma/max
InternalCompressLevel=max
PrivilegesRequired=poweruser
ShowLanguageDialog=yes
ShowUndisplayableLanguages=yes
LanguageDetectionMethod=locale
AppModifyPath="{app}\Uninstall\Setup.exe"
UninstallDisplayIcon={app}\Uninstall\Setup.exe
UninstallDisplayName={#internal_name} {#version}
UninstallFilesDir={app}\Uninstall
SetupIconFile=Installer\Res\Install.ico
WizardImageFile=Installer\Res\Sidebar.bmp
WizardSmallImageFile=Installer\Res\CornerLogo.bmp
ShowComponentSizes=no
ChangesAssociations=yes
ChangesEnvironment=yes
OutputManifestFile=Manifest_{#ConfigurationName}{#PlatformName}.txt
MinVersion=0,5.0
#if PlatformName == "x64"
ArchitecturesAllowed=x64
ArchitecturesInstallIn64BitMode=x64
#endif
; Set the SVN root as source dir (up 2 levels)
SourceDir=..\..
VersionInfoVersion={#version}
VersionInfoDescription={#Description}
AppPublisher={#Publisher}
AppCopyright=Copyright © {#Publisher}. All rights reserved.
; Links to website for software panel
AppPublisherURL=http://PeerProject.org
AppSupportURL=http://support.peerproject.org/
AppUpdatesURL=http://download.peerproject.org/
[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"
Name: "quicklaunch"; Description: "{cm:CreateQuickLaunchIcon}"
Name: "language"; Description: "{cm:tasks_languages}";
Name: "multiuser"; Description: "{cm:tasks_multisetup}";
Name: "upnp"; Description: "{cm:tasks_upnp}"; MinVersion: 0,5.01; Check: CanUserModifyServices;
;Name: "firewall"; Description: "{cm:tasks_firewall}"; MinVersion: 0,5.01sp2
Name: "resetdiscoveryhostcache"; Description: "{cm:tasks_resetdiscoveryhostcache}"; Flags: unchecked
#if alpha == "No"
Name: "deleteoldsetup"; Description: "{cm:tasks_deleteoldsetup}"; Check: EnableDeleteOldSetup
#endif
[Files]
; Main files
Source: "{#root}\PeerProject.exe"; DestDir: "{app}"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
Source: "{#root}\SkinInstaller.exe"; DestDir: "{app}"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
Source: "{#root}\TorrentWizard.exe"; DestDir: "{app}"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
; Save/Restore scripts
Source: "Services\SaveSettings.bat"; DestDir: "{app}"; DestName: "SaveSettings.bat"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension skipifsourcedoesntexist
Source: "Services\RestoreSettings.bat"; DestDir: "{app}"; DestName: "RestoreSettings.bat"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension skipifsourcedoesntexist
;--== Dynamic Link Libraries ==--
; Main files
Source: "{#root}\*.dll"; DestDir: "{app}"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
; ZLib
#if PlatformName == "Win32"
Source: "Services\zlibwapi.dll"; DestDir: "{app}"; DestName: "zlibwapi.dll"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
Source: "Services\zlibwapi.dll"; DestDir: "{app}\Plugins"; DestName: "zlibwapi.dll"; Flags: overwritereadonly replacesameversion uninsremovereadonly sortfilesbyextension deleteafterinstall
#elif PlatformName == "x64"
Source: "Services\zlibwapi-x64.dll"; DestDir: "{app}"; DestName: "zlibwapi.dll"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
Source: "Services\zlibwapi-x64.dll"; DestDir: "{app}\Plugins"; DestName: "zlibwapi.dll"; Flags: overwritereadonly replacesameversion uninsremovereadonly sortfilesbyextension deleteafterinstall
#endif
; Plugins
Source: "{#root}\Plugins\*.dll"; DestDir: "{app}"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension regserver; Excludes: "LibGFL*.dll,zlibwapi.dll,Unrar.dll,Unrar64.dll,WebHook*.dll"
Source: "{#root}\Plugins\*.dll"; DestDir: "{app}"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension; Excludes: "LibGFL*.dll,zlibwapi.dll"
;Source: "Plugins\MediaPlayer.dll"; DestDir: "{app}"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension regserver
; Don't register WebHook.dll since it will setup PeerProject as download manager
;Source: "Plugins\WebHook.dll"; DestDir: "{app}"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
;--== Debug Databases ==--
#if ConfigurationName == "Debug"
Source: "{#root}\PeerProject.pdb"; DestDir: "{app}"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
; ** The next line can be uncommented to include geoip, skin & zlibwapi debug database files
;Source: "{#root}\*.pdb"; DestDir: "{app}"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
; ** This section can be uncommented to include the debug database files for all the plugins
;Source: "{#root}\Plugins\*.pdb"; DestDir: "{app}\Plugins"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
#if PlatformName == "Win32"
Source: "Services\BugTrap\BugTrapU.dll"; DestDir: "{app}"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
Source: "Services\BugTrap\dbghelp.dll"; DestDir: "{sys}"; DestName: "dbghelp.dll"; Flags: overwritereadonly restartreplace uninsneveruninstall sortfilesbyextension
#elif PlatformName == "x64"
Source: "Services\BugTrap\BugTrapU-x64.dll"; DestDir: "{app}"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
Source: "Services\BugTrap\dbghelp-x64.dll"; DestDir: "{sys}"; DestName: "dbghelp.dll"; Flags: overwritereadonly restartreplace uninsneveruninstall sortfilesbyextension
#endif
#endif
;--== Include Files ==--
; Main Data Files
Source: "Data\*.*"; DestDir: "{app}\Data"; Flags: ignoreversion overwritereadonly uninsremovereadonly sortfilesbyextension; Excludes: ".svn,*.bak,*.url,GPL*,WorldGPS.xml"
; GeoIP
;Source: "Data\GeoIP.dat"; DestDir: "{app}\Data"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
; Icon files
Source: "Installer\Res\Uninstall.ico"; DestDir: "{app}\Uninstall"; Flags: ignoreversion overwritereadonly uninsremovereadonly sortfilesbyextension
; Schemas
Source: "Schemas\*"; DestDir: "{app}\Schemas"; Flags: ignoreversion overwritereadonly uninsremovereadonly sortfilesbyextension; Excludes: ".svn"
; Skins
Source: "Skins\*"; DestDir: "{app}\Skins"; Flags: ignoreversion overwritereadonly uninsremovereadonly sortfilesbyextension recursesubdirs; Excludes: ".svn,.bak"
; Templates
Source: "Templates\*"; DestDir: "{app}\Templates"; Flags: ignoreversion overwritereadonly uninsremovereadonly sortfilesbyextension recursesubdirs; Excludes: ".svn"
; Languages
;Source: "Languages\*"; DestDir: "{app}\Skins\Languages"; Flags: ignoreversion overwritereadonly uninsremovereadonly sortfilesbyextension; Tasks: "language"; Excludes: ".svn,*.bak,default-en.*"
; Visualizations
;Source: "Plugins\MediaVis\*"; DestDir: "{app}\Vis"; Flags: ignoreversion overwritereadonly uninsremovereadonly sortfilesbyextension recursesubdirs; Excludes: ".svn"
; Tools
;Source: "Repository\Bittorrent Tempfile Chopper.exe"; DestDir: "{app}"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
;Source: "Repository\Pilo Torrent Tempfile Splitter.exe"; DestDir: "{app}"; Flags: overwritereadonly replacesameversion restartreplace uninsremovereadonly sortfilesbyextension
; Licenses
; Source: "Installer\License\LICENSE-GeoIP.txt"; DestDir: "{app}"; Flags: ignoreversion overwritereadonly uninsremovereadonly sortfilesbyextension
Source: "Installer\License\License (GPL 3.0).html"; DestDir: "{app}"; Flags: ignoreversion overwritereadonly uninsremovereadonly sortfilesbyextension
;--== Copy files ==--
; Copy skins back from {userappdata}\PeerProject\Skins
Source: "{userappdata}\PeerProject\Skins\*"; DestDir: "{app}\Skins"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist recursesubdirs; AfterInstall: DeleteFolder('{userappdata}\PeerProject\Skins')
; Copy templates back from {userappdata}\PeerProject\Templates
Source: "{userappdata}\PeerProject\Templates\*"; DestDir: "{app}\Templates"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist recursesubdirs; AfterInstall: DeleteFolder('{userappdata}\PeerProject\Templates')
; Switch user data between locations
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\Library1.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\Library2.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\DownloadGroups.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\TigerTree.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\Security.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\UploadQueues.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\Searches.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\Schedule.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\Profile.xml"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\Library1.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\Library2.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\DownloadGroups.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\TigerTree.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\Security.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\UploadQueues.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\Searches.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\Schedule.dat"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\Profile.xml"; DestDir: "{userappdata}\PeerProject\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\Library1.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\Library2.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\DownloadGroups.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\TigerTree.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\Security.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\UploadQueues.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\Searches.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\Schedule.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data\Profile.xml"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\Library1.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\Library2.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\DownloadGroups.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\TigerTree.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\Security.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\UploadQueues.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\Searches.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\Schedule.dat"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
Source: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data\Profile.xml"; DestDir: "{app}\Data"; Flags: ignoreversion uninsremovereadonly sortfilesbyextension external onlyifdoesntexist skipifsourcedoesntexist; Tasks: not multiuser
; Copy installer into download and uninstall dir
#if alpha == "No"
Source: "{srcexe}"; DestDir: "{ini:{param:SETTINGS|},Locations,CompletePath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{userdocs}\PeerProject Downloads}}"; DestName: "{#output_name}.exe"; Flags: ignoreversion overwritereadonly uninsremovereadonly sortfilesbyextension external onlyifdoesntexist; Tasks: multiuser
Source: "{srcexe}"; DestDir: "{ini:{param:SETTINGS|},Locations,CompletePath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{app}\Downloads}}"; DestName: "{#output_name}.exe"; Flags: ignoreversion overwritereadonly uninsremovereadonly sortfilesbyextension external onlyifdoesntexist; Tasks: not multiuser
#endif
Source: "{srcexe}"; DestDir: "{app}\Uninstall"; DestName: "setup.exe"; Flags: ignoreversion overwritereadonly uninsremovereadonly sortfilesbyextension external
; Copy repair installer
;Source: "Installer\Builds\Repair.exe"; DestDir: "{app}\Uninstall"; Flags: overwritereadonly replacesameversion uninsremovereadonly sortfilesbyextension; Check: not WizardSilent
; Copy default security rules
Source: "Data\DefaultSecurity.dat"; DestDir: "{userappdata}\PeerProject\Data"; DestName: "Security.dat"; Flags: onlyifdoesntexist uninsremovereadonly sortfilesbyextension; Tasks: multiuser
Source: "Data\DefaultSecurity.dat"; DestDir: "{app}\Data"; DestName: "Security.dat"; Flags: onlyifdoesntexist uninsremovereadonly sortfilesbyextension; Tasks: not multiuser
[Icons]
; PeerProject Start Menu Shortcuts
Name: "{group}\{#internal_name}"; Filename: "{app}\PeerProject.exe"; WorkingDir: "{app}"; Comment: "{cm:reg_apptitle}"
Name: "{group}\TorrentWizard"; Filename: "{app}\TorrentWizard.exe"; WorkingDir: "{app}"; Comment: "PeerProject Torrent File Creator"
Name: "{group}\GUI Modes\{#internal_name} ({cm:icons_basicmode})"; Filename: "{app}\PeerProject.exe"; Parameters: "-basic"; WorkingDir: "{app}"; Comment: "{cm:reg_apptitle}"
Name: "{group}\GUI Modes\{#internal_name} ({cm:icons_tabbedmode})"; Filename: "{app}\PeerProject.exe"; Parameters: "-tabbed"; WorkingDir: "{app}"; Comment: "{cm:reg_apptitle}"
Name: "{group}\GUI Modes\{#internal_name} ({cm:icons_windowedmode})"; Filename: "{app}\PeerProject.exe"; Parameters: "-windowed"; WorkingDir: "{app}"; Comment: "{cm:reg_apptitle}"
Name: "{commondesktop}\{#internal_name}"; Filename: "{app}\PeerProject.exe"; WorkingDir: "{app}"; Comment: "{cm:reg_apptitle}"; Tasks: desktopicon
Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\{#internal_name}"; Filename: "{app}\PeerProject.exe"; WorkingDir: "{app}"; Comment: "{cm:reg_apptitle}"; Tasks: quicklaunch
; Other icons in user language
Name: "{group}\{cm:icons_license}"; Filename: "{app}\Uninstall\GPL License.rtf"; WorkingDir: "{app}\Uninstall"; Comment: "{cm:icons_license}"
Name: "{group}\{cm:icons_uninstall}"; Filename: "{uninstallexe}"; WorkingDir: "{app}\Uninstall"; Comment: "{cm:UninstallProgram,PeerProject}"; IconFilename: "{app}\Uninstall\uninstall.ico"
;Name: "{userprograms}\{groupname}\{cm:icons_downloads}"; Filename: "{ini:{param:SETTINGS|},Locations,CompletePath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{userdocs}\PeerProject Downloads}}"; WorkingDir: "{ini:{param:SETTINGS|},Locations,CompletePath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{userdocs}\PeerProject Downloads}}"; Comment: "{cm:icons_downloads}"; Tasks: multiuser; Check: not WizardNoIcons
;Name: "{group}\{cm:icons_downloads}"; Filename: "{ini:{param:SETTINGS|},Locations,CompletePath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{app}\Downloads}}"; WorkingDir: "{ini:{param:SETTINGS|},Locations,CompletePath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{app}\Downloads}}"; Comment: "{cm:icons_downloads}"; Tasks: not multiuser; Check: not WizardNoIcons
[Messages]
; Overwrite standard ISL entries
; DO NOT use for localized messages
BeveledLabel=PeerProject Development Team
SetupAppTitle=Setup | {#internal_name}
[Run]
; Run the skin installer at end of installation
Filename: "{app}\SkinInstaller.exe"; Parameters: "/installsilent"; WorkingDir: "{app}"; StatusMsg: "{cm:run_skinexe}"
; Run PeerProject at end of installation
Filename: "{app}\PeerProject.exe"; Description: "{cm:LaunchProgram,PeerProject}"; WorkingDir: "{app}"; Flags: postinstall skipifsilent nowait
[UninstallRun]
; Run the skin installer at start of uninstallation and make sure it only runs once
Filename: "{app}\SkinInstaller.exe"; Parameters: "/uninstallsilent"; WorkingDir: "{app}"; StatusMsg: "{cm:run_skinexe}"; RunOnceId: "uninstallskinexe"
[Registry]
Root: HKLM; Subkey: "SOFTWARE\PeerProject\PeerProject"; ValueType: dword; ValueName: "MultiUser"; ValueData: 1; Flags: deletevalue; Tasks: multiuser
Root: HKLM; Subkey: "SOFTWARE\PeerProject\PeerProject"; ValueType: dword; ValueName: "MultiUser"; ValueData: 0; Flags: deletevalue; Tasks: not multiuser
; Write installation path to registry
Root: HKLM; Subkey: "SOFTWARE\PeerProject"; ValueType: string; ValueName: ; ValueData: "{app}"; Flags: uninsdeletekey deletevalue
Root: HKCU; Subkey: "Software\PeerProject\PeerProject"; ValueType: string; ValueName: "Path" ; ValueData: "{app}"; Flags: uninsdeletekey deletevalue
Root: HKCU; Subkey: "Software\PeerProject\PeerProject"; ValueType: string; ValueName: "UserPath" ; ValueData: "{ini:{param:SETTINGS|},Locations,UserPath|{userappdata}\PeerProject}"; Flags: uninsdeletekey deletevalue ; Tasks: multiuser
Root: HKCU; Subkey: "Software\PeerProject\PeerProject"; ValueType: string; ValueName: "UserPath" ; ValueData: "{ini:{param:SETTINGS|},Locations,UserPath|{app}}"; Flags: uninsdeletekey deletevalue; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\PeerProject.exe"; ValueType: string; ValueName: ; ValueData: "{app}\PeerProject.exe"; Flags: uninsdeletekey deletevalue
Root: HKLM; Subkey: "SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\PeerProject.exe"; ValueType: string; ValueName: "Path"; ValueData: "{app}"; Flags: uninsdeletekey deletevalue
; Set directory locations
Root: HKCU; Subkey: "Software\PeerProject\PeerProject\Downloads"; ValueType: string; ValueName: "CompletePath"; ValueData: "{ini:{param:SETTINGS|},Locations,CompletePath|{userdocs}\PeerProject Downloads}"; Flags: uninsdeletekey createvalueifdoesntexist; Tasks: multiuser
Root: HKCU; Subkey: "Software\PeerProject\PeerProject\Downloads"; ValueType: string; ValueName: "IncompletePath"; ValueData: "{ini:{param:SETTINGS|},Locations,IncompletePath|{localappdata}\PeerProject\Incomplete}"; Flags: uninsdeletekey createvalueifdoesntexist; Tasks: multiuser
Root: HKCU; Subkey: "Software\PeerProject\PeerProject\Downloads"; ValueType: string; ValueName: "TorrentPath"; ValueData: "{ini:{param:SETTINGS|},Locations,TorrentPath|{userappdata}\PeerProject\Torrents}"; Flags: uninsdeletekey createvalueifdoesntexist; Tasks: multiuser
Root: HKCU; Subkey: "Software\PeerProject\PeerProject\Downloads"; ValueType: string; ValueName: "CollectionPath"; ValueData: "{ini:{param:SETTINGS|},Locations,CollectionPath|{userappdata}\PeerProject\Collections}"; Flags: uninsdeletekey createvalueifdoesntexist; Tasks: multiuser
Root: HKCU; Subkey: "Software\PeerProject\PeerProject\Downloads"; ValueType: string; ValueName: "CompletePath"; ValueData: "{ini:{param:SETTINGS|},Locations,CompletePath|{app}\Downloads}"; Flags: uninsdeletekey createvalueifdoesntexist; Tasks: not multiuser
Root: HKCU; Subkey: "Software\PeerProject\PeerProject\Downloads"; ValueType: string; ValueName: "IncompletePath"; ValueData: "{ini:{param:SETTINGS|},Locations,IncompletePath|{app}\Incomplete}"; Flags: uninsdeletekey createvalueifdoesntexist; Tasks: not multiuser
Root: HKCU; Subkey: "Software\PeerProject\PeerProject\Downloads"; ValueType: string; ValueName: "TorrentPath"; ValueData: "{ini:{param:SETTINGS|},Locations,TorrentPath|{app}\Torrents}"; Flags: uninsdeletekey createvalueifdoesntexist; Tasks: not multiuser
Root: HKCU; Subkey: "Software\PeerProject\PeerProject\Downloads"; ValueType: string; ValueName: "CollectionPath"; ValueData: "{ini:{param:SETTINGS|},Locations,CollectionPath|{app}\Collections}"; Flags: uninsdeletekey createvalueifdoesntexist; Tasks: not multiuser
; Install chat notify sound
Root: HKCU; Subkey: "AppEvents\EventLabels\Sound_IncomingChat"; ValueType: string; ValueName: ; ValueData: "{cm:reg_incomingchat}"; Flags: uninsdeletekey
Root: HKCU; Subkey: "AppEvents\Schemes\Apps\PeerProject"; ValueType: string; ValueName: ; ValueData: "{cm:reg_apptitle}"; Flags: uninsdeletekey
Root: HKCU; Subkey: "AppEvents\Schemes\Apps\PeerProject\Sound_IncomingChat\.current"; ValueType: string; ValueName: ; ValueData: "%SystemRoot%\Media\notify.wav"; Flags: uninsdeletekey
Root: HKCU; Subkey: "AppEvents\Schemes\Apps\PeerProject\Sound_IncomingChat\.default"; ValueType: string; ValueName: ; ValueData: "%SystemRoot%\Media\notify.wav"; Flags: uninsdeletekey
; Set UPNP as chosen during the setup
Root: HKCU; Subkey: "Software\PeerProject\PeerProject\Connection"; ValueType: dword; ValueName: "EnableUPnP"; ValueData: 1; Flags: deletevalue; Tasks: upnp
Root: HKCU; Subkey: "Software\PeerProject\PeerProject\Connection"; ValueType: dword; ValueName: "EnableUPnP"; ValueData: 0; Flags: deletevalue; Tasks: not upnp
; ShareMonkey CID
Root: HKCU; Subkey: "Software\PeerProject\PeerProject\WebServices"; ValueType: string; ValueName: "ShareMonkeyCid"; ValueData: "197506"; Flags: deletevalue uninsdeletekey
; Set permissions on registry keys
Root: HKLM; Subkey: "SOFTWARE\Classes\.co"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\.collection"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\.torrent"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\bittorrent"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\ed2k"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\gnet"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\gnutella"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\gnutella1"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\gnutella2"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\uhc"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\ukhl"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\magnet"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\mp2p"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\gwc"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\PeerProject"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\PeerProject.Collection"; Permissions: users-modify; Tasks: not multiuser
Root: HKLM; Subkey: "SOFTWARE\Classes\Applications\PeerProject.exe"; Permissions: users-modify; Tasks: not multiuser
; Delete keys at uninstall
Root: HKLM; Subkey: "SOFTWARE\PeerProject"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "Software\PeerProject"; Flags: dontcreatekey uninsdeletekey
Root: HKU; Subkey: ".DEFAULT\Software\PeerProject"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "Software\Microsoft\Windows\CurrentVersion\Run"; ValueName: "PeerProject"; Flags: dontcreatekey uninsdeletevalue
Root: HKLM; Subkey: "SOFTWARE\Classes\.psk"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\.sks"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\.co"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\.collection"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\.torrent"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\bittorrent"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\ed2k"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\gnet"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\gnutella"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\gnutella1"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\gnutella2"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\uhc"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\ukhl"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\magnet"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\mp2p"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\gwc"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\peerproject"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\PeerProject.*"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\Applications\PeerProject.exe"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Classes\Applications\SkinInstaller.exe"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\.psk"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\.sks"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\.co"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\.collection"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\.emulecollection"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\.torrent"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\bittorrent"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\ed2k"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\gnet"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\gnutella"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\gnutella1"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\gnutella2"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\uhc"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\ukhl"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\magnet"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\mp2p"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\gwc"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\peerproject"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\PeerProject.*"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\Applications\PeerProject.exe"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "SOFTWARE\Classes\Applications\SkinInstaller.exe"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.psk"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.sks"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.torrent"; Flags: dontcreatekey uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Microsoft\Windows\CurrentVersion\App Management\ARPCache\PeerProject_is1"; Flags: dontcreatekey uninsdeletekey
Root: HKCU; Subkey: "Software\Microsoft\Windows\ShellNoRoam\MUICache"; ValueName:"{app}\PeerProject.exe"; Flags: dontcreatekey uninsdeletevalue
Root: HKLM; Subkey: "SOFTWARE\Magnet"; Flags: dontcreatekey uninsdeletekey
; Delete NSIS entry on software panel
Root: HKLM; Subkey: "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\PeerProject"; Flags: dontcreatekey deletekey
; Clear version check key
Root: HKCU; Subkey: "Software\PeerProject\PeerProject\VersionCheck"; Flags: dontcreatekey deletekey
Root: HKLM; Subkey: "Software\PeerProject\PeerProject\VersionCheck"; Flags: dontcreatekey deletekey
; Create TorrentWizard default dir locations
Root: HKCU; Subkey: "Software\PeerProject\TorrentWizard\Folders"; ValueType: string; ValueName: "001.Path"; ValueData: "{userappdata}\PeerProject\Torrents"; Flags: createvalueifdoesntexist; Tasks: multiuser
Root: HKCU; Subkey: "Software\PeerProject\TorrentWizard\Folders"; ValueType: string; ValueName: "Last"; ValueData: "{userappdata}\PeerProject\Torrents"; Flags: createvalueifdoesntexist; Tasks: multiuser
Root: HKCU; Subkey: "Software\PeerProject\TorrentWizard\Folders"; ValueType: string; ValueName: "001.Path"; ValueData: "{app}\Torrents"; Flags: createvalueifdoesntexist; Tasks: not multiuser
Root: HKCU; Subkey: "Software\PeerProject\TorrentWizard\Folders"; ValueType: string; ValueName: "Last"; ValueData: "{app}\Torrents"; Flags: createvalueifdoesntexist; Tasks: not multiuser
Root: HKCU; Subkey: "Software\PeerProject\PeerProject\BitTorrent"; ValueType: string; ValueName: "TorrentCreatorPath"; ValueData: "TorrentWizard.exe" ; Flags: createvalueifdoesntexist uninsdeletekey
; Disable extensions for plugins which make trouble
; Since it is image services plugin we need to add extensions required for the first run
Root: HKCU; Subkey: "Software\PeerProject\PeerProject\Plugins"; ValueType: string; ValueName: "{{C9314782-CB91-40B8-B375-F631FF30C1C8}"; ValueData: "|-.pdf||.bmp||.png||.jpg|"; Flags: createvalueifdoesntexist uninsdeletekey
[Dirs]
; Make complete, incomplete, torrent and collection dir
; Note: download dir will be created when installer is copied but we create also here to be sure
Name: "{ini:{param:SETTINGS|},Locations,UserPath|{reg:HKCU\Software\PeerProject\PeerProject,UserPath|{userappdata}\PeerProject}}\Data"; Flags: uninsalwaysuninstall; Tasks: multiuser
Name: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data"; Flags: uninsalwaysuninstall; Tasks: multiuser
Name: "{ini:{param:SETTINGS|},Locations,CompletePath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{userdocs}\PeerProject Downloads}}"; Flags: uninsalwaysuninstall; Tasks: multiuser
Name: "{ini:{param:SETTINGS|},Locations,IncompletePath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,IncompletePath|{localappdata}\PeerProject\Incomplete}}"; Flags: uninsalwaysuninstall; Tasks: multiuser
Name: "{ini:{param:SETTINGS|},Locations,TorrentPath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,TorrentPath|{userappdata}\PeerProject\Torrents}}"; Flags: uninsalwaysuninstall; Tasks: multiuser
Name: "{ini:{param:SETTINGS|},Locations,CollectionPath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CollectionPath|{userappdata}\PeerProject\Collections}}"; Flags: uninsalwaysuninstall; Tasks: multiuser
Name: "{ini:{param:SETTINGS|},Locations,Path|{reg:HKCU\Software\PeerProject\PeerProject,Path|{app}}}\Data"; Flags: uninsalwaysuninstall; Permissions: users-modify; Tasks: not multiuser
Name: "{ini:{param:SETTINGS|},Locations,CompletePath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{app}\Downloads}}"; Flags: uninsalwaysuninstall; Permissions: users-modify; Tasks: not multiuser
Name: "{ini:{param:SETTINGS|},Locations,IncompletePath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,IncompletePath|{app}\Incomplete}}"; Flags: uninsalwaysuninstall; Permissions: users-modify; Tasks: not multiuser
Name: "{ini:{param:SETTINGS|},Locations,TorrentPath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,TorrentPath|{app}\Torrents}}"; Flags: uninsalwaysuninstall; Permissions: users-modify; Tasks: not multiuser
Name: "{ini:{param:SETTINGS|},Locations,CollectionPath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CollectionPath|{app}\Collections}}"; Flags: uninsalwaysuninstall; Permissions: users-modify; Tasks: not multiuser
Name: "{app}\Skins"; Flags: uninsalwaysuninstall; Permissions: users-modify
[InstallDelete]
; Very basic malware removal
Type: files; Name: "{app}\PeerProject.exe"; Check: IsMalwareDetected
Type: files; Name: "{app}\vc2.dll"
; Clean up old files from PeerProject
Type: files; Name: "{app}\*.pdb"
Type: files; Name: "{app}\zlib.dll"
Type: files; Name: "{app}\libgfl*.dll"
Type: filesandordirs; Name: "{app}\Plugins"
Type: files; Name: "{app}\GPL-License.txt"
Type: files; Name: "{app}\uninstall.exe"
Type: files; Name: "{app}\Uninstall\repair.exe"
Type: files; Name: "{app}\*.dat"
Type: files; Name: "{app}\*.xml"
Type: files; Name: "{app}\*.png"
Type: files; Name: "{app}\*.bmp"
Type: files; Name: "{app}\Data\*.url"
Type: filesandordirs; Name: "{userappdata}\PeerProject\Remote"
Type: filesandordirs; Name: "{userappdata}\PeerProject\Schemas"
Type: filesandordirs; Name: "{userappdata}\PeerProject\Skins"
Type: files; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{userdocs}\PeerProject Downloads}\Thumbs.db"; Tasks: multiuser
Type: files; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{app}\Downloads}\Thumbs.db"
Type: files; Name: "{userappdata}\PeerProject\Data\DefaultAvatar.png"
; Clean up old PeerProject Shortcuts
Type: files; Name: "{userdesktop}\PeerProject.lnk"; Tasks: not desktopicon
Type: files; Name: "{commondesktop}\PeerProject.lnk"; Tasks: not desktopicon
Type: files; Name: "{userdesktop}\Start PeerProject.lnk"; Check: NSISUsed
Type: files; Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\PeerProject.lnk"; Tasks: not quicklaunch
Type: filesandordirs; Name: "{userprograms}\PeerProject"; Check: NSISUsed
Type: filesandordirs; Name: "{commonprograms}\PeerProject"; Check: NSISUsed
Type: filesandordirs; Name: "{userprograms}\PeerProject"; Check: InnoSetupUsed
Type: filesandordirs; Name: "{commonprograms}\PeerProject"; Check: InnoSetupUsed
;Following two lines may delete data not created by PeerProject (Instead)
;Type: filesandordirs; Name: "{userprograms}\{reg:HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\PeerProject_is1,Inno Setup: Icon Group|{groupname}}"; Check: InnoSetupUsed
;Type: filesandordirs; Name: "{commonprograms}\{reg:HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\PeerProject_is1,Inno Setup: Icon Group|{groupname}}"; Check: InnoSetupUsed
; Delete extra components so installer can "uninstall" them
Type: filesandordirs; Name: "{app}\Remote"
Type: filesandordirs; Name: "{app}\Skins\Languages"; Tasks: not language
; Delete old PeerProject installers
#if alpha == "No"
Type: files; Name: "{ini:{param:SETTINGS|},Locations,CompletePath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{userdocs}\PeerProject Downloads}}\PeerProject*.exe"; Tasks: deleteoldsetup and multiuser
Type: files; Name: "{ini:{param:SETTINGS|},Locations,CompletePath|{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{app}\Downloads}}\PeerProject*.exe"; Tasks: deleteoldsetup and not multiuser
#endif
; Delete Discovery.dat and HostCache.dat
Type: files; Name: "{app}\Data\Discovery.dat"; Tasks: resetdiscoveryhostcache
Type: files; Name: "{app}\Data\HostCache.dat"; Tasks: resetdiscoveryhostcache
Type: files; Name: "{userappdata}\PeerProject\Data\Discovery.dat"; Tasks: resetdiscoveryhostcache and multiuser
Type: files; Name: "{userappdata}\PeerProject\Data\HostCache.dat"; Tasks: resetdiscoveryhostcache and multiuser
[UninstallDelete]
; Clean up files created after installation
Type: filesandordirs; Name: "{app}\Data"
Type: filesandordirs; Name: "{userappdata}\PeerProject\Data"
Type: filesandordirs; Name: "{app}\Skins"
Type: filesandordirs; Name: "{app}\Templates"
Type: filesandordirs; Name: "{app}\Schemas"
Type: filesandordirs; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{userdocs}\PeerProject Downloads}\Metadata"; Tasks: multiuser
Type: files; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{userdocs}\PeerProject Downloads}\Thumbs.db"; Tasks: multiuser
Type: files; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{userdocs}\PeerProject Downloads}\SThumbs.dat"; Tasks: multiuser
Type: files; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{userdocs}\PeerProject Downloads}\desktop.ini"; Tasks: multiuser
Type: filesandordirs; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,TorrentPath|{userappdata}\PeerProject\Torrents}\Metadata"; Tasks: multiuser
Type: files; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,TorrentPath|{userappdata}\PeerProject\Torrents}\desktop.ini"; Tasks: multiuser
Type: filesandordirs; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CollectionPath|{userappdata}\PeerProject\Collections}\Metadata"; Tasks: multiuser
Type: files; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CollectionPath|{userappdata}\PeerProject\Collections}\desktop.ini"; Tasks: multiuser
Type: filesandordirs; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{app}\Downloads}\Metadata"
Type: files; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{app}\Downloads}\Thumbs.db"
Type: files; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{app}\Downloads}\SThumbs.dat"
Type: files; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CompletePath|{app}\Downloads}\desktop.ini"
Type: filesandordirs; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,TorrentPath|{app}\Torrents}\Metadata"
Type: files; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,TorrentPath|{app}\Torrents}\desktop.ini"
Type: filesandordirs; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CollectionPath|{app}\Collections}\Metadata"
Type: files; Name: "{reg:HKCU\Software\PeerProject\PeerProject\Downloads,CollectionPath|{app}\Collections}\desktop.ini"
; Pull in languages and localized files
#include "..\Installer\Scripts\Languages.iss"
; Code sections need to be the last section in a script or the compiler will get confused
[Code]
type
SERVICE_STATUS = record
dwServiceType: cardinal;
dwCurrentState: cardinal;
dwControlsAccepted: cardinal;
dwWin32ExitCode: cardinal;
dwServiceSpecificExitCode: cardinal;
dwCheckPoint: cardinal;
dwWaitHint: cardinal;
end;
HANDLE = cardinal;
const
WM_CLOSE = $0010;
KeyLoc1 = 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\PeerProject_is1';
KeyLoc2 = 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\PeerProject';
KeyName = 'UninstallString';
NET_FW_SCOPE_ALL = 0;
NET_FW_IP_VERSION_ANY = 2;
SERVICE_QUERY_CONFIG = $1;
SERVICE_CHANGE_CONFIG = $2;
SERVICE_QUERY_STATUS = $4;
SERVICE_START = $10;
SERVICE_STOP = $20;
SERVICE_ALL_ACCESS = $f01ff;
SC_MANAGER_ALL_ACCESS = $f003f;
SERVICE_AUTO_START = $2;
SERVICE_DEMAND_START = $3;
SERVICE_RUNNING = $4;
SERVICE_NO_CHANGE = $ffffffff;
var
CurrentPath: string;
Installed: Boolean;
MalwareDetected: Boolean;
FirewallFailed: string;
HasUserPrivileges: Boolean;
// NT API functions for services
Function OpenSCManager(lpMachineName, lpDatabaseName: string; dwDesiredAccess: cardinal): HANDLE;
external '[email protected] stdcall setuponly';
Function OpenService(hSCManager: HANDLE; lpServiceName: string; dwDesiredAccess: cardinal): HANDLE;
external '[email protected] stdcall setuponly';
Function CloseServiceHandle(hSCObject: HANDLE): Boolean;
external '[email protected] stdcall setuponly';
Function StartNTService(hService: HANDLE; dwNumServiceArgs: cardinal; lpServiceArgVectors: cardinal): Boolean;
external '[email protected] stdcall setuponly';
Function QueryServiceStatus(hService: HANDLE; var ServiceStatus: SERVICE_STATUS): Boolean;
external '[email protected] stdcall setuponly';
Function ChangeServiceConfig(hService: HANDLE; dwServiceType, dwStartType, dwErrorControl: cardinal;
lpBinaryPathName, lpLoadOrderGroup: string; lpdwTagId: cardinal;
lpDependencies, lpServiceStartName, lpPassword, lpDisplayName: string): Boolean;
external '[email protected] stdcall setuponly';
Function InnoSetupUsed(): boolean;
Begin
Result := RegKeyExists(HKEY_LOCAL_MACHINE, KeyLoc1);
End;
Function NSISUsed(): boolean;
Begin
Result := RegKeyExists(HKEY_LOCAL_MACHINE, KeyLoc2);
End;
// check if the current install path exists
Function DoesPathExist(): boolean;
Begin
if RegQueryStringValue(HKEY_LOCAL_MACHINE, 'SOFTWARE\PeerProject','', CurrentPath) then
Result := DirExists(CurrentPath)
else
Result := False;
End;
Function OpenServiceManager(): HANDLE;
begin
Result := 0;
if (InstallOnThisVersion('0,5.01', '0,0') = irInstall) then
Result := OpenSCManager('', 'ServicesActive', SC_MANAGER_ALL_ACCESS);
end;
Function CanUserModifyServices(): Boolean;
var
hSCManager: HANDLE;
begin
hSCManager := 0;
Result := false;
HasUserPrivileges := false;
if (InstallOnThisVersion('0,5.01', '0,0') = irInstall) then begin
hSCManager := OpenSCManager('', 'ServicesActive', SC_MANAGER_ALL_ACCESS);
if (hSCManager <> 0) then begin
HasUserPrivileges := true;
Result := true;
CloseServiceHandle(hSCManager);
end;
end;
end;
Function IsServiceInstalled(ServiceName: string): boolean;
var
hSCManager: HANDLE;
hService: HANDLE;
begin
hSCManager := OpenServiceManager();
Result := false;
if (hSCManager <> 0) then begin
hService := OpenService(hSCManager, ServiceName, SERVICE_QUERY_CONFIG);
if (hService <> 0) then begin
Result := true;
CloseServiceHandle(hService);
end;
CloseServiceHandle(hSCManager);
end;
end;
Function StartService(ServiceName: string): boolean;
var
hSCManager: HANDLE;
hService: HANDLE;
begin
hSCManager := OpenServiceManager();
Result := false;
if (hSCManager <> 0) then begin
hService := OpenService(hSCManager, ServiceName, SERVICE_START);
if (hService <> 0) then begin
Result := StartNTService(hService, 0, 0);
CloseServiceHandle(hService);
end;
CloseServiceHandle(hSCManager);
end;
end;
Function IsServiceRunning(ServiceName: string): boolean;
var
hSCManager: HANDLE;
hService: HANDLE;
sStatus: SERVICE_STATUS;
begin
hSCManager := OpenServiceManager();
Result := false;
if (hSCManager <> 0) then begin
hService := OpenService(hSCManager, ServiceName, SERVICE_QUERY_STATUS);
if (hService <> 0) then begin
if (QueryServiceStatus(hService, sStatus)) then
Result := (sStatus.dwCurrentState = SERVICE_RUNNING);
CloseServiceHandle(hService);
end;
CloseServiceHandle(hSCManager);
end;
end;
Function ChangeServiceStartup(ServiceName: string; dwStartType: cardinal): boolean;
var
hSCManager: HANDLE;
hService: HANDLE;
begin
hSCManager := OpenServiceManager();
Result := false;
if (hSCManager <> 0) then begin
hService := OpenService(hSCManager, ServiceName, SERVICE_CHANGE_CONFIG);
if (hService <> 0) then begin
Result := ChangeServiceConfig(hService, SERVICE_NO_CHANGE, dwStartType, SERVICE_NO_CHANGE, '','',0,'','','','');
CloseServiceHandle(hService);
end;
CloseServiceHandle(hSCManager);
end;
end;
Function NextButtonClick(CurPageID: integer): Boolean;
var
Wnd: HWND;
Shutdownmessage: string;
begin
Result := True;
if (CurPageID = wpWelcome) then begin
Wnd := FindWindowByClassName('PeerProjectMainWnd');
if Wnd <> 0 then begin
Shutdownmessage := ExpandConstant('{cm:dialog_shutdown,PeerProject}');
if MsgBox(Shutdownmessage, mbConfirmation, MB_OKCANCEL) = IDOK then begin
SendMessage(Wnd, WM_CLOSE, 0, 0);
while Wnd <> 0 do begin
Sleep(100);
Wnd := FindWindowByClassName('PeerProjectMainWnd');
end;
end else Result := False;
end;
end;
end;
Function MalwareCheck(MalwareFile: string): Boolean;
Begin
Result := False;
if FileExists( MalwareFile ) then Begin
if MsgBox(ExpandConstant( '{cm:dialog_malwaredetected,' + MalwareFile + '}' ), mbConfirmation, MB_OKCANCEL) = IDOK then begin
Result := True;
End;
MalwareDetected := True;
End;
End;
Function InitializeSetup: Boolean;
Begin
Result := True;
Installed := (RegValueExists(HKEY_LOCAL_MACHINE, KeyLoc1, KeyName) or RegValueExists(HKEY_LOCAL_MACHINE, KeyLoc2, KeyName)) and DoesPathExist();
MalwareDetected := False;
// Malware check
Result := NOT MalwareCheck( ExpandConstant('{win}\vgraph.dll') );
;
if Result then Begin Result := NOT MalwareCheck( ExpandConstant('{win}\PeerProject.exe') ); End;
if Result then Begin Result := NOT MalwareCheck( ExpandConstant('{sys}\PeerProject.exe') ); End;
if Result then Begin Result := NOT MalwareCheck( ExpandConstant('{pf}\PeerProject\vc2.dll') ); End;
End;
Function IsMalwareDetected: Boolean;
Begin
Result := MalwareDetected;
End;
Function EnableDeleteOldSetup: Boolean;
Begin
Result := Installed;
End;
Function WeOwnTorrentAssoc: boolean;
var
CommandString: string;
Position: Integer;
Begin
Result := False;
if RegQueryStringValue(HKEY_CLASSES_ROOT, 'bittorrent\shell\open\command','', CommandString) then
Begin
Position := Pos('PeerProject.exe', LowerCase(CommandString));
Result := (Position > 0);
End
End;
Function ShouldSkipPage(PageID: Integer): Boolean;
Begin
Result := False;
if PageID = wpSelectDir then Result := Installed;
End;
Procedure DeleteFolder(Param: String);
var
Foldername: string;
Begin
Foldername := ExpandConstant(Param);
DelTree(Foldername, True, True, True);
End;
Procedure DeleteFile(Param: String);
var
Filename: string;
Begin
Filename := ExpandConstant(Param);
DelayDeleteFile(Filename,3);
End;
// We don't allow to modify the setting of MultiUser if was already selected.
Procedure CurPageChanged(const CurrentPage: integer);
var
i : integer;
MultiUserValue: DWORD;
Begin
if CurrentPage = wpSelectTasks then begin
i := WizardForm.TasksList.Items.IndexOf(ExpandConstant('{cm:tasks_multisetup}'));
if i <> -1 then begin
if RegQueryDWordValue(HKEY_LOCAL_MACHINE, 'SOFTWARE\PeerProject\PeerProject', 'MultiUser', MultiUserValue) then begin
if MultiUserValue = 1 then
Wizardform.TasksList.Checked[i] := true
else
Wizardform.TasksList.Checked[i] := false;
WizardForm.TasksList.ItemEnabled[i] := false;
End;
End;
End;
End;
Procedure CurUninstallStepChanged(CurUninstallStep: TUninstallStep);
var
InstallFolder: string;
FirewallManager: Variant;
FirewallProfile: Variant;
Wnd: HWND;
Begin
if CurUninstallStep = usUninstall then begin
if InstallOnThisVersion('0,5.01sp2','0,0') = irInstall then begin
try
InstallFolder := ExpandConstant('{app}\PeerProject.exe');
FirewallManager := CreateOleObject('HNetCfg.FwMgr');
FirewallProfile := FirewallManager.LocalPolicy.CurrentProfile;
FirewallProfile.AuthorizedApplications.Remove(InstallFolder);
except
End;
End;
Wnd := FindWindowByClassName('PeerProjectMainWnd');
if Wnd <> 0 then begin
SendMessage(Wnd, WM_CLOSE, 0, 0);
while Wnd <> 0 do
begin
Sleep(100);
Wnd := FindWindowByClassName('PeerProjectMainWnd');
End;
End;
if WeOwnTorrentAssoc then begin
RegDeleteKeyIncludingSubkeys(HKEY_CLASSES_ROOT,'.torrent');
RegDeleteKeyIncludingSubkeys(HKEY_CLASSES_ROOT,'bittorrent');
End;
End;
End;
Function IsLanguageRTL(LangCode: String): String;
Begin
if ( (LangCode = 'heb') or (LangCode = 'ar') ) then
Result := '1'
else
Result := '0';
End;
Function GetRelFilePath(LangCode: String): String;
Begin
StringChangeEx(LangCode, '_', '-', True);
if ( LangCode = 'en-uk' ) then
Result := 'Languages\default-alt.xml'
else if ( LangCode = 'pt' ) then
Result := 'Languages\default-pt-br.xml'
else if ( LangCode = 'af' ) then
Result := 'Languages\default-za.xml'
else
Result := 'Languages\default-' + LangCode + '.xml';
End;
Function ResetLanguages: boolean;
var
Names: TArrayOfString;
I: Integer;
S: String;
Value: String;
begin
if RegGetValueNames(HKEY_CURRENT_USER, 'Software\PeerProject\PeerProject\Skins', Names) then
begin
S := '';
Value := LowerCase(GetRelFilePath(ExpandConstant('{language}')));
for I := 0 to GetArrayLength(Names)-1 do
begin
S := LowerCase(Names[I]);
if Pos('languages', S) <> 0 then
if Value <> S then
RegWriteDWordValue(HKEY_CURRENT_USER, 'Software\PeerProject\PeerProject\Skins', S, 0);
end;
RegWriteDWordValue(HKEY_CURRENT_USER, 'Software\PeerProject\PeerProject\Skins', Value, 1);
Value := IsLanguageRTL(ExpandConstant('{language}'));
RegWriteDWordValue(HKEY_CURRENT_USER, 'Software\PeerProject\PeerProject\Settings', 'LanguageRTL', StrToInt(Value));
RegWriteStringValue(HKEY_CURRENT_USER, 'Software\PeerProject\PeerProject\Settings', 'Language', ExpandConstant('{language}'));
// Set default values for other users
RegWriteDWordValue(HKEY_LOCAL_MACHINE, 'Software\PeerProject\PeerProject', 'DefaultLanguageRTL', StrToInt(Value));
RegWriteStringValue(HKEY_LOCAL_MACHINE, 'Software\PeerProject\PeerProject', 'DefaultLanguage', ExpandConstant('{language}'));
end;
Result := True;
end;
Procedure CurStepChanged(CurStep: TSetupStep);
var
InstallFolder: string;
FirewallObject: Variant;
FirewallManager: Variant;
FirewallProfile: Variant;
Reset: boolean;
Success: boolean;
Path: string;
Begin
if CurStep=ssPostInstall then begin
if IsTaskSelected('firewall') then begin
if WizardSilent = True then begin
try
FirewallObject := CreateOleObject('HNetCfg.FwAuthorizedApplication');
InstallFolder := ExpandConstant('{app}\PeerProject.exe');
FirewallObject.ProcessImageFileName := InstallFolder;
FirewallObject.Name := 'PeerProject';
FirewallObject.Scope := NET_FW_SCOPE_ALL;
FirewallObject.IpVersion := NET_FW_IP_VERSION_ANY;
FirewallObject.Enabled := True;
FirewallManager := CreateOleObject('HNetCfg.FwMgr');
FirewallProfile := FirewallManager.LocalPolicy.CurrentProfile;
FirewallProfile.AuthorizedApplications.Add(FirewallObject);
except
End;
End else begin
FirewallFailed := ExpandConstant('{cm:dialog_firewall}')
try
FirewallObject := CreateOleObject('HNetCfg.FwAuthorizedApplication');
InstallFolder := ExpandConstant('{app}\PeerProject.exe');
FirewallObject.ProcessImageFileName := InstallFolder;
FirewallObject.Name := 'PeerProject';
FirewallObject.Scope := NET_FW_SCOPE_ALL;
FirewallObject.IpVersion := NET_FW_IP_VERSION_ANY;
FirewallObject.Enabled := True;
FirewallManager := CreateOleObject('HNetCfg.FwMgr');
FirewallProfile := FirewallManager.LocalPolicy.CurrentProfile;
FirewallProfile.AuthorizedApplications.Add(FirewallObject);
except
MsgBox(FirewallFailed, mbInformation, MB_OK);
End;
End;
End;
if IsTaskSelected('upnp') then begin
if (HasUserPrivileges) then begin
Success := false;
if (IsServiceInstalled('SSDPSRV') and IsServiceInstalled('upnphost')) then begin
if (not IsServiceRunning('SSDPSRV')) then begin
// Change the startup type to manual if it was disabled;
// we don't need to start it since UPnP Device Host service depends on it;
// assuming that user didn't modify the dependencies manually.
// Note: probably, we could elevate user rights with AdjustTokenPrivileges(?)
Success := ChangeServiceStartup('SSDPSRV', SERVICE_DEMAND_START);
end else
Success := true;
if (Success) then begin
// We succeeded to change the startup type, so we will change another service
Success := ChangeServiceStartup('upnphost', SERVICE_AUTO_START);
if (Success and not IsServiceRunning('upnphost')) then
StartService('upnphost');
end;
end;
end;
end;
End;
if CurStep=ssInstall then begin
if not IsTaskSelected('firewall') then begin
if InstallOnThisVersion('0,5.01sp2','0,0') = irInstall then begin
try
InstallFolder := ExpandConstant('{app}\PeerProject.exe');
FirewallManager := CreateOleObject('HNetCfg.FwMgr');
FirewallProfile := FirewallManager.LocalPolicy.CurrentProfile;
FirewallProfile.AuthorizedApplications.Remove(InstallFolder);
except
End;
End;
End;
End;
// Check if the needed paths exist otherwise delete it from the registry (They will be recreated later in the installation process)
if CurStep=ssInstall then begin
if RegQueryStringValue(HKEY_CURRENT_USER, 'SOFTWARE\PeerProject\PeerProject\Downloads', 'CompletePath', Path) and (not DirExists(Path)) then begin
if not RegDeleteValue(HKEY_CURRENT_USER, 'SOFTWARE\PeerProject\PeerProject\Downloads', 'CompletePath') then begin
MsgBox(ExpandConstant('{cm:PathNotExist,complete}'), mbError, MB_OK);
End;
End;
if RegQueryStringValue(HKEY_CURRENT_USER, 'SOFTWARE\PeerProject\PeerProject\Downloads', 'IncompletePath', Path) and (not DirExists(Path)) then begin
if not RegDeleteValue(HKEY_CURRENT_USER, 'SOFTWARE\PeerProject\PeerProject\Downloads', 'IncompletePath') then begin
MsgBox(ExpandConstant('{cm:PathNotExist,incomplete}'), mbError, MB_OK);
End;
End;
if RegQueryStringValue(HKEY_CURRENT_USER, 'SOFTWARE\PeerProject\PeerProject\Downloads', 'CollectionPath', Path) and (not DirExists(Path)) then begin
if not RegDeleteValue(HKEY_CURRENT_USER, 'SOFTWARE\PeerProject\PeerProject\Downloads', 'CollectionPath') then begin
MsgBox(ExpandConstant('{cm:PathNotExist,collection}'), mbError, MB_OK);
End;
End;
if RegQueryStringValue(HKEY_CURRENT_USER, 'SOFTWARE\PeerProject\PeerProject\Downloads', 'TorrentPath', Path) and (not DirExists(Path)) then begin
if not RegDeleteValue(HKEY_CURRENT_USER, 'SOFTWARE\PeerProject\PeerProject\Downloads', 'TorrentPath') then begin
MsgBox(ExpandConstant('{cm:PathNotExist,torrent}'), mbError, MB_OK);
End;
End;
End;
if CurStep=ssDone then Reset := ResetLanguages;
End;
{ Pull in custom wizard pages }
#include "..\Installer\Scripts\Pages.iss"
; Pull in PeerProject settings to write to registry
#include "..\Installer\Scripts\Settings.iss"
#expr SaveToFile("..\Installer\Scripts\Preprocessed.iss")