The conformal Einstein equations

Alfonso García-Parrado (alfonso@math.uminho.pt)

Initialization

<<xAct`xTensor`

Preliminary arrangements

<<xAct`ShowTime1`

$PrePrint=ScreenDollarIndices;

SetOptions[ContractMetric,AllowUpperDerivatives->True];

ApplyRule[expr_]:=MakeRule[Evaluate[List@@expr],MetricOn->All,ContractMetrics->True];

ApplyRuleN[expr_]:=MakeRule[Evaluate[List@@expr],MetricOn->None];

Here, we work in  dimension four

DefManifold[M4,4,Complement[IndexRange[α,ρ],{π}]]

Unphysical metric (default)

We define the unphysical metric. This is the default metric which means that indices are always raised and lowered with this metric.

DefMetric[-1,Unphysicalg[-α,-β ],CDg,SymbolOfCovD->{";","∇"},PrintAs->"g"]

SignatureOfMetric@Unphysicalg^={3,1,0};

Physical metric and its relation to the unphysical one

We introduce the physical metric

DefMetric[-1,Physicalg[-α,-β ],CDTildeg,SymbolOfCovD->{";","(OverTilde[∇])"},PrintAs->"(OverTilde[g])"]

PrintAs@InvPhysicalg^="((OverTilde[g])^(#))";

The conformal factor

DefTensor[Θ[],M4]

The unphysical and the physical metric are related as follows

Unphysicalg[-α,-β]==Θ[]^2Physicalg[-α,-β]

UnphysicalToPhysical=%;

Equal@@(Solve[UnphysicalToPhysical,Physicalg[-α,-β]]//Flatten//First)

PhysicalToUnPhysical=%;

Times[#,Unphysicalg[γ,α]]&/@UnphysicalToPhysical

InvPhysicalg[α,β]==Unphysicalg[α,β]Θ[]^2

InvPhysicalToPhysical=%;

InvPhysicalToPhysicalUp=(InvPhysicalToPhysical/.ApplyRule@UnphysicalToPhysical);

Relation between the unphysical and the physical connections

We start from the relation

UnphysicalToPhysical

We take the unphysical covariant derivative on both sides of this equation.

CDg[-γ]/@%

This relation can be written in terms of the physical covariant derivative as follows

ChangeCovD[#,CDg,CDTildeg]&/@%

expr1=%;

We permute indices cyclically

expr2=ReplaceIndex[#,{-α->-β,-β->-γ,-γ->-α}]&/@expr1

expr3=ReplaceIndex[#,{-α->-β,-β->-γ,-γ->-α}]&/@expr2

0==Last@expr1+Last@expr2-Last@expr3

ToCanonical/@%

This expression enables us to find the value of  ({{Γ[∇,(OverTilde[∇])], ({{d,  ,  }, { , a, c}})}})

Times[#,InvPhysicalg[ε,β]]&/@%

ToCanonical[#,UseMetricOnVBundle->None]&/@%

%/.CDTildeg->CDg

%/.ApplyRuleN@InvPhysicalToPhysical

%/.ApplyRule@PhysicalToUnPhysical

Equal@@(Solve[%,Union@Cases[%,_ChristoffelCDgCDTildeg,Infinity]]//Flatten//First)

ExpandChristoffelCDgCDTildeg=%;

We wish to rewrite this relation in an alternative form. To that end we define a "temporary delta"

DefTensor[deltaM[-α,β],M4]

The reason of introducing the "temporary delta" is to avoid the automatic contraction of the ordinary Kronecker delta when it has any of its indices contracted.

(ExpandChristoffelCDgCDTildeg/.CDg[-α_]@Θ[]->deltaM[-α,ρ]CDg[-ρ]@Θ[])

Collect[#,CDg[-ρ]@Θ[]]&/@%

We replace the "temporary delta" by the normal Kronecker delta

%/.deltaM->delta

ExpandChristoffelCDgCDTildeg=%;

The quantity in brackets is used to define a new tensor.

DefTensor[SUnphysical[-α,-β,γ,δ],M4,GenSet[Cycles[{-α,-β}],Cycles[{γ,δ}]],PrintAs->"S"]

By definition

SUnphysical[-γ,-α,ε,ρ]==ExpandChristoffelCDgCDTildeg[[2,1]]

ExpandSUnphysical=%;

For later use we derive an expression for the product ({{g, ({{ ,  }, {γ, α}})}}) ({{g, ({{ε, ρ}, { ,  }})}})

MapAt[Hold,ExpandSUnphysical,{2,-1}]

Solve[%,Union@Cases[%,_Hold,Infinity]]//Flatten//ReleaseHold

Equal@@First@%

Times[#,-1]&/@%

UnphysicalgSquare=%;

The relation between the connections is now rendered in the form

ExpandChristoffelCDgCDTildeg/.ApplyRuleN@UnphysicalgSquare

ToCanonical/@%

ExpandChristoffelCDgCDTildegS=%;

Relation between the unphysical and the physical curvature

This is the relation between the unphysical and the physical curvature

RiemannCDg[-α,-β,-γ,δ]==ChangeCurvature[RiemannCDg[-α,-β,-γ,δ],CDg,CDTildeg]

ChangeCovD[#,CDTildeg,CDg]&/@%

We replace the connection tensors using the result of previous subsection

%/.ApplyRuleN@ExpandChristoffelCDgCDTildeg

ToCanonical/@(ContractMetric/@%)

ContractMetric/@%

ToCanonical/@%

RiemannUnphysToRiemannPhys=%;

We use this to compute the relation between the Ricci tensors and the scalar curvatures

RiemannUnphysToRiemannPhys/.δ->β

ToCanonical/@(ContractMetric/@%)

RicciUnphysToRicciPhys=%;

Times[#,InvPhysicalg[α,γ]]&/@ RicciUnphysToRicciPhys

Expand/@%

%/.ApplyRuleN@InvPhysicalToPhysical

ToCanonical/@(ContractMetric/@%)

Solve[%,RicciScalarCDg[]]//Flatten//First

Equal@@%

RicciScalarUnphysToRicciScalarPhys=%;

Weyl Connection

We define here a Weyl connection

DefTensor[𝒻[-α],M4]

DefCovD[WeylCD[-α],SymbolOfCovD->{";","(OverHat[∇])"}]

WeylCDUnphysicalg=WeylCD[-α]@Unphysicalg[-β,-γ]==-2𝒻[-α]Unphysicalg[-β,-γ]

Relation between the Weyl and the  unphysical connection

We follow the standard procedure to compute the difference between the unphysical connection and the Weyl connection

ChangeCovD[#,WeylCD,CDg]&/@WeylCDUnphysicalg

expr1=%;

expr2=ReplaceIndex[#,{-α->-β,-β->-γ,-γ->-α}]&/@expr1

expr3=ReplaceIndex[#,{-α->-β,-β->-γ,-γ->-α}]&/@expr2

First@expr1+First@expr2-First@expr3==Last@expr1+Last@expr2-Last@expr3

ToCanonical/@%

%/.-γ->γ

Equal@@(Solve[%,Union@Cases[%,_ChristoffelCDgWeylCD,Infinity]]//Flatten//First)

(%/.𝒻[-α_]->deltaM[-α,ρ]𝒻[-ρ])

(%/.𝒻[α_Symbol]->Unphysicalg[α,ρ]𝒻[-ρ])

Collect[#,𝒻[-ρ]]&/@%

We remove the "temporary delta"

%/.deltaM->delta

%/.ApplyRule@UnphysicalgSquare

ExpandChristoffelCDgWeylCD=%;

Relation between the Weyl curvature and the unphysical curvature

RiemannWeylCD[-α,-β,-γ,δ]==ChangeCurvature[RiemannWeylCD[-α,-β,-γ,δ],WeylCD,CDg]

%/.ApplyRuleN@ExpandChristoffelCDgWeylCD

%/.ApplyRuleN@ExpandSUnphysical

ToCanonical/@(ContractMetric/@%)

ContractMetric/@%

ToCanonical/@%

RiemannWeylToRiemannUnphys=%;

RiemannWeylToRiemannUnphys/.δ->β

ToCanonical/@(ContractMetric/@%)

RicciWeylToRicciUnphys=%;

RicciWeylToRicciUnphys/.-α->γ

ToCanonical/@%

RicciScalarWeylToRicciScalarUnphysical=%;

The Schouten tensor

Unphysical Schouten tensor

DefTensor[LUnphysg[-α,-β],M4,Symmetric[{-α,-β}],PrintAs->"L"]

LUnphysg[-α,-β]==1/2(RicciCDg[-α,-β]-1/6 RicciScalarCDg[]Unphysicalg[-α,-β])

SchoutenUnphys=%;

Equal@@(Solve[SchoutenUnphys,RicciCDg[-α,-β]]//Flatten//First)

RicciCDgToSchouten=%;

The decomposition of the Riemann tensor into irreducible parts adopts a simpler form if one writes it in terms of the Schouten tensor

RiemannCDg[-α,-β,-γ,δ]==(RiemannCDg[-α,-β,-γ,δ]//RiemannToWeyl)

%/.ApplyRule@RicciCDgToSchouten

ToCanonical/@%

RiemannUnphysToSchoutenUnphys=%;

Covariant divergence of the Unphysical Weyl tensor in terms of the unphysical Schouten tensor

We note now the second Bianchi identity

0==ToCanonical@Antisymmetrize[3CDg[-η]@RiemannCDg[-α,-β,-γ,δ],{-η,-α,-β}]

%/.ApplyRule@RiemannUnphysToSchoutenUnphys

ToCanonical/@%

AntisCovDivWeylUnphysical=%;

%/.δ->η

ToCanonical/@(ContractMetric/@%)

Solve[%,CDg[-η]@WeylCDg[-α,-β,-γ,η]]//Flatten

Equal@@First@%

CovDivWeylUnphysical=%

The trace of this equation yields a relation involving the covariand divergence of the Schouten tensor

%/.-β->γ

ToCanonical/@(ContractMetric/@%)

Solve[%,CDg[-γ]@LUnphysg[-α,γ]]//Flatten//First

Equal@@%

We declare this as an automatic rule

AutomaticRules[LUnphysg,ApplyRule@%]

CovDivWeylUnphysical=ToCanonical/@CovDivWeylUnphysical

Physical Schouten tensor

DefTensor[LPhysg[-α,-β],M4,Symmetric[{-α,-β}],PrintAs->"(OverTilde[L])"]

LPhysg[-α,-β]==1/2(RicciCDTildeg[-α,-β]-1/6 RicciScalarCDTildeg[]Physicalg[-α,-β])

SchoutenPhys=%;

Solve[SchoutenPhys,RicciCDTildeg[-α,-β]]//Flatten

Equal@@First@%

RicciCDTildegToSchoutenPhys=%;

Weyl connection Schouten tensor

DefTensor[LWeylg[-α,-β],M4,PrintAs->"(OverHat[L])"]

LWeylg[-β,-α]==1/2(Symmetrize[RicciWeylCD[-α,-β],{-α,-β}]-1/2Antisymmetrize[RicciWeylCD[-α,-β],{-α,-β}]-1/6  RicciWeylCD[η,-η]Unphysicalg[-α,-β])

SchoutenWeyl=%;

Solve[SchoutenWeyl,RicciWeylCD[-α,-β]]//Flatten

Equal@@First@%

RicciWeylToSchoutenWeyl=%;

Relation between the Weyl Schouten tensor and the unphysical Schouten tensor

SchoutenWeyl

%/.ApplyRuleN@RicciWeylToRicciUnphys

%/.ApplyRuleN@RicciScalarWeylToRicciScalarUnphysical

%/.ApplyRuleN@RicciCDgToSchouten

ToCanonical/@%

SchoutenWeylToSchoutenUnphysical=%;

Solve[SchoutenWeylToSchoutenUnphysical,LUnphysg[-α,-β]]//Flatten

Equal@@First@%

ChangeCovD[#,CDg,WeylCD]&/@%

%/.ApplyRule@ExpandChristoffelCDgWeylCD

ToCanonical/@%

%/.ApplyRule@ExpandSUnphysical

ToCanonical/@(ContractMetric/@%)

SchoutenUnphysicalToSchoutenWeyl=%;

Solve[SchoutenUnphysicalToSchoutenWeyl,WeylCD[-β]@𝒻[-α]]//Flatten

Equal@@First@%

WeylCD𝒻=%;

Relation between the  unphysical Schouten tensor and the physical Schouten tensor

SchoutenUnphys

%/.ApplyRuleN@RicciUnphysToRicciPhys

%/.ApplyRuleN@RicciScalarUnphysToRicciScalarPhys

%/.ApplyRuleN@RicciCDTildegToSchoutenPhys

ToCanonical/@(ContractMetric[#,AllowUpperDerivatives->True]&/@%)

%/.ApplyRuleN@PhysicalToUnPhysical

SchoutenUnphysicalToSchoutenPhysical=%;

Relation between the Weyl Schouten tensor and the physical Schouten tensor

It is convenient to introduce now a new variable.

DefTensor[B[α],M4]

B[-α]==𝒻[-α]+CDg[-α]@Θ[]/Θ[]

ChangeCovD[#,CDg,WeylCD]&/@%

BTo𝒻=%;

Solve[BTo𝒻,𝒻[-α]]//Flatten

Equal@@First@%

𝒻ToB=%

SchoutenUnphysicalToSchoutenWeyl

%/.ApplyRule@SchoutenUnphysicalToSchoutenPhysical

ChangeCovD[#,CDg,WeylCD]&/@%

%/.ApplyRule@ExpandChristoffelCDgWeylCD

%/.ApplyRule@ExpandSUnphysical

Solve[%,LWeylg[-β,-α]]//Flatten

Equal@@First@%

ToCanonical/@(ContractMetric/@%)

%/.ApplyRule@𝒻ToB

ToCanonical/@%

SchoutenWeylToSchoutenPhysical=%;

Relation between the Weyl Riemann and the unphysical Riemann.

ChangeCovD[#,CDg,WeylCD]&/@RiemannWeylToRiemannUnphys

%/.ApplyRule@ExpandChristoffelCDgWeylCD

%/.ApplyRule@ExpandSUnphysical

ToCanonical/@(ContractMetric/@%)

%/.MakeRule[{𝒻[-α],𝒻[-α]},MetricOn->All,ContractMetrics->False]

%/.ApplyRuleN@WeylCDUnphysicalg

ToCanonical/@(ContractMetric/@%)

%/.ApplyRuleN@WeylCD𝒻

ToCanonical/@(ContractMetric/@%)

Collect[#,{_delta,_Unphysicalg}]&/@%

RiemannWeylToRiemannUnphysWeylCD=%;

Metric conformal field equations

Henceforth, we assume the condition

EinsteinMetric=RicciCDTildeg[-α,-β]==1/4RicciScalarCDTildeg[]Physicalg[-α,-β]

Derivation of the relation (Subscript[∇, b])({{Σ, ({{ }, {a}})}})==s ({{g, ({{ ,  }, {a, b}})}})-({{L, ({{ ,  }, {a, b}})}}) Θ

Start from the identity

SchoutenUnphysicalToSchoutenPhysical

Solve[%,CDg[-β]@CDg[-α]@Θ[]]//Flatten//First

Equal@@%

%/.ApplyRule@SchoutenPhys

ToCanonical/@%

We impose now that we are in an Einstein manifold

%/.ApplyRule@EinsteinMetric

%/.IndexSolve[RicciScalarUnphysToRicciScalarPhys,RicciScalarCDTildeg[]]

%/.ApplyRuleN@PhysicalToUnPhysical

ToCanonical/@(ContractMetric/@%)

Collect[#,Unphysicalg[-α,-β]]&/@%

CDg2θ=%;

We introduce new quantities

DefTensor[sUnphys[],M4,PrintAs->"s"];DefTensor[ΣUnphys[-α],M4,PrintAs->"Σ"];

By definition

sUnphys[]==CDg2θ[[-1,-1,-1]]

ExpandsUnphys=%;

CDgΘ=CDg[-α]@Θ[]==ΣUnphys[-α]

So we have that the relation CDg2θ takes the form

CDg2θ/.IndexSolve[ExpandsUnphys,RicciScalarCDg[]]/.ApplyRule@CDgΘ

ToCanonical/@%

Conf1=%;

Relation (Subscript[∇, a])s==-({{L, ({{ ,  }, {a, b}})}}) ({{Σ, ({{b}, { }})}})

Take the covariant derivative of s and replace this scalar quantity by its value:

CDg[-α]@sUnphys[]==(CDg[-α]@sUnphys[]/.ApplyRule@ExpandsUnphys)

%//SortCovDs

%/.ApplyRule@CDgΘ

%/.ApplyRule@Conf1

%/.ApplyRule@CDgΘ

ToCanonical/@%

Solve[%,CDg[-α]@sUnphys[]]//Flatten

Equal@@First@%

%/.ApplyRule@SchoutenUnphys

ToCanonical/@(ContractMetric/@%)

%/.ApplyRule@RicciCDgToSchouten

ToCanonical/@(ContractMetric/@%)

CDgSUnphys=%;

Integrability condition of  (Subscript[∇, b])({{Σ, ({{ }, {a}})}})==s ({{g, ({{ ,  }, {a, b}})}})-({{L, ({{ ,  }, {a, b}})}}) Θ  => Relation ({{𝒹, ({{ ,  ,  ,  }, {a, c, b, d}})}}) ({{Σ, ({{d}, { }})}})+(Subscript[∇, a])({{L, ({{ ,  }, {b, c}})}})-(Subscript[∇, c])({{L, ({{ ,  }, {a, b}})}})==0

We start from the condition

CDg[-γ]@CDg[-α]@ΣUnphys[-β]-CDg[-α]@CDg[-γ]@ΣUnphys[-β]==(CDg[-γ]@CDg[-α]@ΣUnphys[-β]-CDg[-α]@CDg[-γ]@ΣUnphys[-β]//SortCovDs)

We know the covariant derivative of ({{Σ, ({{ }, {b}})}}) so we replace it

%/.ApplyRule@Conf1

%/.ApplyRule@CDgΘ

%/.ApplyRule@Conf1

%/.ApplyRule@CDgSUnphys

ToCanonical/@%

RiemannToWeyl/@%

%/.ApplyRule@RicciCDgToSchouten

ToCanonical/@(ContractMetric/@%)

First@%-Last@%==0

ToCanonical/@%

Int1=%;

This is best expressed in terms of the "rescaled Weyl tensor"

DefTensor[𝒹[-δ,-α,-β,-γ],M4,RiemannSymmetric[{-δ,-α,-β,-γ}]]

By definition

RescaledWeylUnphys=𝒹[-δ,-α,-β,-γ]==WeylCDg[-δ,-α,-β,-γ]/Θ[]

Solve[RescaledWeylUnphys,WeylCDg[-δ,-α,-β,-γ]]//Flatten

Equal@@First@%

WeylToRescaledWeylUnphys=%;

Also ({{𝒹, ({{ ,  ,  ,  }, {d, a, b, c}})}}) is traceless

AutomaticRules[𝒹,ApplyRule[𝒹[α,-β,-α,-γ]==0]]

So the integrability condition takes the following form

Int1/.ApplyRule@WeylToRescaledWeylUnphys

Times[#,1/Θ[]]&/@%

Expand/@%

Conf3=%;

For later use, we rewrite this condition as follows:

Conf3/.𝒹[-a_,-b_,-c_,-d_]ΣUnphys[d_]:>Hold[𝒹[-a,-b,-c,-d]ΣUnphys[d]]

Solve[%,Union@Cases[%,_Hold,Infinity]]//Flatten//ReleaseHold

Equal@@First@%

ReConf3=%;

We compute now the covariant divergence of the rescaled Weyl tensor:

CDg[-α]@𝒹[α,-β,-γ,-δ]==(CDg[-α]@𝒹[α,-β,-γ,-δ]/.ApplyRule@RescaledWeylUnphys)

%/.ApplyRule@CovDivWeylUnphysical

%/.ApplyRule@WeylToRescaledWeylUnphys

%/.ApplyRule@CDgΘ

%/.ApplyRule@ReConf3

ToCanonical/@%

Conf4=%;

Integrability conditions of (Subscript[∇, a])s==-({{L, ({{ ,  }, {a, b}})}}) ({{Σ, ({{b}, { }})}}) => identically fulfilled.

As the connection ∇ has no torsion,  the quantity (Subscript[∇, b])(Subscript[∇, a])s must be symmetric in the indices b,a

0==CDg[-β]@CDg[-α]@sUnphys[]-CDg[-α][CDg[-β]@sUnphys[]/.ApplyRule@CDgSUnphys]

%/.ApplyRule@CDgSUnphys

%/.ApplyRule@Conf1

ToCanonical/@%

This relation is implied by one of the conformal field equations as we explicitly check

Times[#,ΣUnphys[β]]&/@Conf3

ToCanonical/@%

Summary (set of  "metric conformal field equations")

We introduce the expression

conf2=RiemannUnphysToSchoutenUnphys/.ApplyRule@WeylToRescaledWeylUnphys

This is the list of "metric conformal field equations"

MetricConformalEquations={CDgΘ,Conf1,conf2,CDgSUnphys,Conf3,Conf4}

The extended conformal field equations

We write next the metric conformal field equations in terms of the Weyl connection. This yields the so called "extended conformal field equations".

RiemannWeylToRiemannUnphysWeylCD

RiemannWeylToRiemannUnphysWeylCD/.ApplyRule@conf2

ToCanonical/@%

Collect[#,{HoldPattern@delta[__],Unphysicalg[__]},Simplify]&/@%

conf2Weyl=%;

Equation (Subscript[(OverHat[∇]), a])Θ==({{Σ, ({{ }, {a}})}})

ChangeCovD[#,CDg,WeylCD]&/@CDgΘ

CDgWeyl=%;

Equation (Subscript[(OverHat[∇]), b])({{Σ, ({{ }, {a}})}})==-({{L, ({{ ,  }, {a, b}})}}) Θ-({{𝒻, ({{ }, {b}})}}) ({{Σ, ({{ }, {a}})}})-({{𝒻, ({{ }, {a}})}}) ({{Σ, ({{ }, {b}})}})+({{g, ({{ ,  }, {a, b}})}}) (s+({{𝒻, ({{c}, { }})}}) ({{Σ, ({{ }, {c}})}}))

MetricConformalEquations[[2]]

ChangeCovD[#,CDg,WeylCD]&/@%

%/.ApplyRule@ExpandChristoffelCDgWeylCD

%/.ApplyRule@SchoutenUnphysicalToSchoutenWeyl

Solve[%,WeylCD[-β]@ΣUnphys[-α]]//Flatten

Equal@@First@%

ToCanonical/@%

%/.ApplyRule@ExpandSUnphysical

ToCanonical/@(ContractMetric/@%)

Simplification/@%

%/.ApplyRuleN@WeylCD𝒻

ToCanonical/@(ContractMetric/@%)

Simplification/@%

Conf1Weyl=%;

Equation (Subscript[(OverHat[∇]), a])s==-({{L, ({{ ,  }, {a, b}})}}) ({{Σ, ({{b}, { }})}})

MetricConformalEquations[[4]]

ChangeCovD[#,CDg,WeylCD]&/@%

CDgSUnphysWeyl=%;

Equation -({{𝒹, ({{ ,  ,  ,  }, {c, a, b, d}})}}) ({{𝒻, ({{d}, { }})}}) Θ-({{𝒹, ({{ ,  ,  ,  }, {c, a, b, d}})}}) ({{Σ, ({{d}, { }})}})+(Subscript[(OverHat[∇]), a])({{(OverHat[L]), ({{ ,  }, {b, c}})}})-(Subscript[(OverHat[∇]), c])({{(OverHat[L]), ({{ ,  }, {a, b}})}})==0

MetricConformalEquations[[5]]

ChangeCovD[#,CDg,WeylCD]&/@%

%/.ApplyRule@ExpandChristoffelCDgWeylCD

%/.ApplyRule@ExpandSUnphysical

ToCanonical/@(ContractMetric/@%)

exp=%;

Solve[exp,WeylCD[-α]@LUnphysg[-β,-γ]]//Flatten//Simplify

Equal@@First@%

WeylCDLUnphysg=%;

exp/.ApplyRule@SchoutenUnphysicalToSchoutenWeyl

%/.ApplyRule@ExpandSUnphysical;

%/.MakeRule[{𝒻[-α],𝒻[-α]},MetricOn->All,ContractMetrics->False];

%/.ApplyRuleN@WeylCDUnphysicalg;

ToCanonical/@(ContractMetric/@%)

%//SortCovDs

%/.ApplyRule@conf2Weyl;

%/.ApplyRuleN@WeylCD𝒻;

%/.MakeRule[{𝒻[-α],𝒻[-α]},MetricOn->All,ContractMetrics->False];

%/.ApplyRuleN@WeylCDUnphysicalg;

%/.ApplyRuleN@WeylCD𝒻;

ToCanonical/@(ContractMetric/@%)

Collect[#,𝒹[__],Simplify]&/@%

Conf3Weyl=%;

Equation ({{𝒹, ({{ ,  ,  ,  }, {α, β, δ, γ}})}}) ({{𝒻, ({{α}, { }})}})+(Subscript[(OverHat[∇]), α])({{𝒹, ({{ ,  ,  , α}, {δ, γ, β,  }})}})==0

Conf4

ChangeCovD[#,CDg,WeylCD]&/@%

%/.ApplyRule@ExpandChristoffelCDgWeylCD

%/.ApplyRule@ExpandSUnphysical

ToCanonical/@(ContractMetric/@%)

%/.𝒹[-γ,-β,-δ,-α]->-𝒹[-β,-δ,-γ,-α]-𝒹[-δ,-γ,-β,-α]

ToCanonical/@%

Conf4Weyl=%;

Summary

ExtendedConformalEqs={CDgWeyl,Conf1Weyl,CDgSUnphysWeyl,Conf3Weyl,WeylCD𝒻,Conf4Weyl}

Extended conformal field equations in terms of  ({{d, ({{ }, {δ}})}})

It is convenient to introduce here a new variable.

DefTensor[dθS[-α],M4,PrintAs->"d"]

By definition

DefinedθS=dθS[-δ]==𝒻[-δ]Θ[]+ΣUnphys[-δ]

Solve[%,ΣUnphys[-δ]]//Flatten//Simplify

Equal@@First@%

ΣUnphysTodθS=%;

CDgWeyl/.ApplyRule@ΣUnphysTodθS

CDgWeyldθS=%;

WeylCD[-α]/@DefinedθS

%/.ApplyRuleN@CDgWeyl

%/.ApplyRuleN@WeylCD𝒻

%/.ApplyRuleN@Conf1Weyl

ToCanonical@ContractMetric@%

%/.ApplyRule@ΣUnphysTodθS

ToCanonical/@(ContractMetric/@%)

ScreenDollarIndices/@%

%/.𝒻[β_]dθS[-β_]↦𝒻[-β]dθS[β]

First@%==(Last@%/.dθS[-δ]->SeparateMetric[Unphysicalg][dθS[-δ],-δ])

ScreenDollarIndices/@%

Collect[#,dθS[β]]&/@%

WeylCDdθS=%

CDgSUnphysWeyl

%/.ApplyRule@ΣUnphysTodθS

%/.ApplyRule[Equal@@First[Solve[WeylCD𝒻,LUnphysg[-α,-β]]//Flatten]]

ToCanonical/@(ContractMetric/@%)

Simplification/@%

FullSimplify/@%

CDgSUnphysWeyldθS=%;

Conf3Weyl/.ApplyRule@ΣUnphysTodθS

Conf3WeyldθS=%;

{CDgWeyldθS,WeylCDdθS,Conf3WeyldθS,CDgSUnphysWeyldθS,Conf4Weyl}

NewExtendedConformalEqs=Map[FullSimplify,%,{2}]

ExtendedConformalEqs

Simplification of -({{𝒻, ({{ }, {a}})}}) ({{𝒻, ({{a}, { }})}}) Θ+2 (s+({{𝒻, ({{a}, { }})}}) ({{Ξ, ({{ }, {a}})}})) => causal character of the conformal boundary

We study the following quantitty

expA=𝒻[-α]𝒻[α]Θ[]+2(sUnphys[]+𝒻[α]dθS[-α])

%/.ApplyRule@ExpandsUnphys

ChangeCovD[%,CDg,WeylCD]

%/.ApplyRule@ExpandChristoffelCDgWeylCD

%/.ApplyRule@ExpandSUnphysical

ChangeCurvature[%,CDg,CDTildeg]//NoScalar

ChangeCovD[%,CDTildeg,CDg]

%/.ApplyRule@ExpandChristoffelCDgCDTildegS

ChangeCovD[%,CDg,WeylCD]

%/.ApplyRule@ExpandChristoffelCDgWeylCD

%/.ApplyRule@ExpandSUnphysical

ToCanonical@%

%/.ApplyRuleN@WeylCDUnphysicalg

%/.Unphysicalg[α_,β_]WeylCD[-β_]@WeylCD[-α_]@Θ[]↦WeylCD[-β]@ContractMetric[Unphysicalg[α,β]WeylCD[-α]@Θ[]]-WeylCD[-β]@Unphysicalg[α,β]WeylCD[-α]@Θ[]

%/.ApplyRuleN@WeylCDUnphysicalg

%/.ApplyRule@EinsteinMetric

%/.ApplyRule@PhysicalToUnPhysical

ContractMetric@%

ToCanonical@%

%//.ApplyRule@NewExtendedConformalEqs[[1]]

ToCanonical@ContractMetric@%

expA==%

ContractMetric/@%

Solve[%,sUnphys[]]//Flatten//Simplify

Equal@@First@%

sUnphysToRicciPhys=%;

Times[#,24,Θ[]]&/@sUnphysToRicciPhys

At the conformal boundary the conformal factor vanishes (but not its covariant derivative). Hence

%/.Θ[]->0

%/.(ApplyRule[DefinedθS/.Θ[]->0])

We recall that ({{Σ, ({{ }, {α}})}}) is just the gradient of the conformal factor which is different from zero at the conformal boundary. Therefore the previous expression enables us to determine the “causal character” of the conformal boundary.