app-admin/bitwarden-desktop-bin: add 2024.8.2

Signed-off-by: Yixun Lan <[email protected]>

app-admin/bitwarden-desktop-bin/Manifest

@@ -1,2 +1,3 @@
 DIST Bitwarden-2024.7.1-amd64.deb 81805416 BLAKE2B 8d3a02e0fb86ecf42f47815c39dd4510fea535694f8764e91bdbe260123e2e39600ff70a45b741069bed8fbf497270b74c13c6996309d1dfa72c10d1f0a70614 SHA512 bfdf9574ee3b3ab56592fb8b20d39991315eff096b875e8d077ec7a08b54a67b3539936c1ed64df2e5ee5aa99942916073038795407f69d563734a01dca3cc87
 DIST Bitwarden-2024.8.1-amd64.deb 82435858 BLAKE2B 72a10049ceeabcf8607d204cece7fa22634e1091d9ca4ddbefb8780901e358ff9f609e1b0fcd5e864caf616defbf040b4f3c5e16cd1a72daf612b4a7aa6da94d SHA512 9d28a39414aef4dcbf989d9b36d997f44df2caaa2ced10e9c72266b3100855127ba1b841b6766949ab7a177ba46cfbd92bad37d4ee2cdcd5afdad0f9118a1ef0
+DIST Bitwarden-2024.8.2-amd64.deb 82798736 BLAKE2B b9c39f689a394ed8ab24e600c47670f10e89de3c318ccf00de3001ba64c4bb5d9a0bfe43549cc5af824138bd676d63a71a1266a9a7d86d20ef0779095e23de4d SHA512 6dc90c0ccdaa14bf8d2724289ee100cd11a6fd21048a15859e3e91c4cea698d87e549c7d1992be08e863da174bfd0b3e620f044f56e7a9e9bc0852d7ed747655

app-admin/bitwarden-desktop-bin/bitwarden-desktop-bin-2024.8.2.ebuild

@@ -0,0 +1,89 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop unpacker xdg-utils
+
+MY_PN="Bitwarden"
+
+DESCRIPTION="Bitwarden password manager desktop client"
+HOMEPAGE="https://bitwarden.com/"
+SRC_URI="https://github.com/bitwarden/clients/releases/download/desktop-v${PV}/Bitwarden-${PV}-amd64.deb"
+S="${WORKDIR}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-crypt/libsecret
+	dev-libs/expat
+	dev-libs/glib
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/util-linux
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxkbcommon
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXScrnSaver
+	x11-libs/libxshmfence
+	x11-libs/libXtst
+	x11-libs/pango
+"
+IDEPEND="
+	dev-util/desktop-file-utils
+	dev-util/gtk-update-icon-cache
+"
+
+QA_PREBUILT="
+	opt/Bitwarden/*.so*
+	opt/Bitwarden/bitwarden
+	opt/Bitwarden/bitwarden-app
+	opt/Bitwarden/chrome-sandbox
+	opt/Bitwarden/chrome_crashpad_handler
+"
+
+src_install() {
+	insinto /opt
+	doins -r opt/${MY_PN}
+	fperms 755 /opt/Bitwarden/bitwarden \
+		/opt/Bitwarden/bitwarden-app
+	fperms 4755 /opt/Bitwarden/chrome-sandbox
+
+	domenu usr/share/applications/bitwarden.desktop
+
+	local x
+	for x in 16 32 64 128 256 512; do
+		doicon -s ${x} usr/share/icons/hicolor/${x}*/*
+	done
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}