dev-libs/sord: move PCRE dependency under tools USE flag

Signed-off-by: Cristian Othón Martínez Vera <[email protected]> Closes: gentoo#33518 Signed-off-by: Miroslav Šulc <[email protected]>
AndCycle · Oct 26, 2023 · 91e6385 · 91e6385
1 parent 6eba331
commit 91e6385
Show file tree

Hide file tree

Showing 3 changed files with 57 additions and 2 deletions.
diff --git a/dev-libs/sord/sord-0.16.14-r2.ebuild b/dev-libs/sord/sord-0.16.14-r2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson-multilib
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/drobilla/sord.git"
+else
+	SRC_URI="https://download.drobilla.net/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+DESCRIPTION="Library for storing RDF data in memory"
+HOMEPAGE="https://drobilla.net/software/sord.html"
+
+LICENSE="ISC"
+SLOT="0"
+IUSE="doc test tools"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+# Take care on bumps to check minimum versions!
+RDEPEND="
+	>=dev-libs/serd-0.30.10[${MULTILIB_USEDEP}]
+	tools? ( dev-libs/libpcre[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# fix doc installation path
+	sed -i "s/versioned_name/'${PF}'/g" doc/meson.build || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_feature doc docs)
+		$(meson_feature test tests)
+		$(meson_feature tools)
+	)
+
+	meson_src_configure
+}
+
+multilib_src_install_all() {
+	local DOCS=( AUTHORS NEWS README.md )
+	einstalldocs
+}
diff --git a/dev-libs/sord/sord-0.16.16.ebuild → dev-libs/sord/sord-0.16.16-r1.ebuild b/dev-libs/sord/sord-0.16.16.ebuild → dev-libs/sord/sord-0.16.16-r1.ebuild
@@ -32,9 +32,9 @@ BDEPEND="
 "
 # Take care on bumps to check minimum versions!
 RDEPEND="
-	dev-libs/libpcre2[${MULTILIB_USEDEP}]
 	dev-libs/serd[${MULTILIB_USEDEP}]
 	dev-libs/zix[${MULTILIB_USEDEP}]
+	tools? ( dev-libs/libpcre2[${MULTILIB_USEDEP}] )
 "
 DEPEND="${RDEPEND}"
 

diff --git a/dev-libs/sord/sord-9999.ebuild b/dev-libs/sord/sord-9999.ebuild
@@ -32,9 +32,9 @@ BDEPEND="
 "
 # Take care on bumps to check minimum versions!
 RDEPEND="
-	dev-libs/libpcre2[${MULTILIB_USEDEP}]
 	dev-libs/serd[${MULTILIB_USEDEP}]
 	dev-libs/zix[${MULTILIB_USEDEP}]
+	tools? ( dev-libs/libpcre2[${MULTILIB_USEDEP}] )
 "
 DEPEND="${RDEPEND}"