reitit

A fast data-driven router for Clojure(Script).

• Simple data-driven route syntax
• Route conflict resolution
• First-class route data
• Bi-directional routing
• Pluggable coercion (schema & clojure.spec)
• Extendable
• Modular
• Fast

Posts:

• Reitit, Data-Driven Routing with Clojure(Script)
• Data-Driven Ring with Reitit

See the full documentation for details.

Modules

• reitit-core - the routing core
• reitit-ring with data-driven middleware
• reitit-spec clojure.spec coercion
• reitit-schema Schema coercion
• reitit-swagger Swagger2 apidocs
• reitit-swagger-ui Integrated Swagger UI.

Bubblin' under:

• reitit-http with enchanced Pedestal-style Interceptors (WIP)
• reitit-frontend with Keechma-style Controllers (WIP)

Latest version

All bundled:

[metosin/reitit "0.1.3"]

Optionally, the parts can be required separately:

[metosin/reitit-core "0.1.3"]
[metosin/reitit-ring "0.1.3"]
[metosin/reitit-spec "0.1.3"]
[metosin/reitit-schema "0.1.3"]
[metosin/reitit-swagger "0.1.3"]
[metosin/reitit-swagger-ui "0.1.3"]

Quick start

(require '[reitit.core :as r])

(def router
  (r/router
    [["/api/ping" ::ping]
     ["/api/orders/:id" ::order]]))

(r/match-by-path router "/api/ping")
; #Match{:template "/api/ping"
;        :data {:name ::ping}
;        :result nil
;        :path-params {}
;        :path "/api/ping"}

(r/match-by-name router ::order {:id 2})
; #Match{:template "/api/orders/:id",
;        :data {:name ::order},
;        :result nil,
;        :path-params {:id 2},
;        :path "/api/orders/2"}

Ring example

A Ring routing app with input & output coercion using data-specs.

(require '[reitit.ring :as ring])
(require '[reitit.coercion.spec])
(require '[reitit.ring.coercion :as rrc])

(def app
  (ring/ring-handler
    (ring/router
      ["/api"
       ["/math" {:get {:parameters {:query {:x int?, :y int?}}
                       :responses {200 {:body {:total pos-int?}}}
                       :handler (fn [{{{:keys [x y]} :query} :parameters}]
                                  {:status 200
                                   :body {:total (+ x y)}})}}]]
      ;; router data effecting all routes
      {:data {:coercion reitit.coercion.spec/coercion
              :middleware [rrc/coerce-exceptions-middleware
                           rrc/coerce-request-middleware
                           rrc/coerce-response-middleware]}})))

Valid request:

(app {:request-method :get
      :uri "/api/math"
      :query-params {:x "1", :y "2"}})
; {:status 200
;  :body {:total 3}}

Invalid request:

(app {:request-method :get
      :uri "/api/math"
      :query-params {:x "1", :y "a"}})
;{:status 400,
; :body {:type :reitit.coercion/request-coercion,
;        :coercion :spec,
;        :spec "(spec-tools.core/spec {:spec (clojure.spec.alpha/keys :req-un [:$spec20745/x :$spec20745/y]), :type :map, :keys #{:y :x}, :keys/req #{:y :x}})",
;        :problems [{:path [:y],
;                    :pred "clojure.core/int?",
;                    :val "a",
;                    :via [:$spec20745/y],
;                    :in [:y]}],
;        :value {:x "1", :y "a"},
;        :in [:request :query-params]}}

NOTE: Reitit is not a batteries included web-stack. You should also include at least:

• content negotiation library like Muuntaja
• some default Ring-middleware like ring.middleware.params/wrap-params

See Ring with Swagger Example for a runnable example. Plan is to have more batteries as separate modules, templates and example projects. Stay tuned.

More info

Check out the full documentation!

Join #reitit channel in Clojurians slack.

Roadmap is mostly written in issues.

Special thanks

• Existing Clojure(Script) routing libs, expecially to Ataraxy, Bide, Bidi, Compojure and Pedestal.
• Compojure-api, Kekkonen, Ring-swagger and Yada and for ideas, coercion & stuff.
• Schema and clojure.spec for the validation part.

License

Copyright © 2017-2018 Metosin Oy

Distributed under the Eclipse Public License, the same as Clojure.