API - Range: Add 'explode' method (onivim#291)

* Factor range out of types

* Refactor Range to separate module

* Add interface

* Formatting

* Test cases for explode method

src/editor/Core/Oni_Core.re

@@ -21,6 +21,8 @@ module IndentationSettings = IndentationSettings;
 module Theme = Theme;
 module Keybindings = Keybindings;
 module Filesystem = Filesystem;
+module Range = Range;
 module Ripgrep = Ripgrep;
 module Tokenizer = Tokenizer;
 module Uri = Uri;
+module VisualRange = VisualRange;

src/editor/Core/Range.re

@@ -0,0 +1,78 @@
+open Types;
+
+[@deriving show({with_path: false})]
+type t = {
+  startPosition: Position.t,
+  endPosition: Position.t,
+};
+
+let createFromPositions = (~startPosition, ~endPosition, ()) => {
+  startPosition,
+  endPosition,
+};
+
+let create = (~startLine, ~startCharacter, ~endLine, ~endCharacter, ()) =>
+  createFromPositions(
+    ~startPosition=Position.create(startLine, startCharacter),
+    ~endPosition=Position.create(endLine, endCharacter),
+    (),
+  );
+
+let zero =
+  create(
+    ~startLine=ZeroBasedIndex(0),
+    ~startCharacter=ZeroBasedIndex(0),
+    ~endLine=ZeroBasedIndex(0),
+    ~endCharacter=ZeroBasedIndex(0),
+    (),
+  );
+
+let toZeroBasedPair = (v: Position.t) => {
+  (Index.toZeroBasedInt(v.line), Index.toZeroBasedInt(v.character));
+};
+
+let explode = (measure, v) => {
+  let (startLine, startCharacter) = v.startPosition |> toZeroBasedPair;
+  let (endLine, endCharacter) = v.endPosition |> toZeroBasedPair;
+
+  if (startLine == endLine) {
+    [v];
+  } else {
+    let idx = ref(startLine);
+
+    let ranges = ref([]);
+
+    while (idx^ < endLine) {
+      let i = idx^;
+
+      let startCharacter = i == startLine ? startCharacter : 0;
+      let endCharacter = max(0, measure(i) - 1);
+
+      ranges :=
+        [
+          create(
+            ~startLine=ZeroBasedIndex(i),
+            ~startCharacter=ZeroBasedIndex(startCharacter),
+            ~endCharacter=ZeroBasedIndex(endCharacter),
+            ~endLine=ZeroBasedIndex(i),
+            (),
+          ),
+          ...ranges^,
+        ];
+
+      incr(idx);
+    };
+
+    [
+      create(
+        ~startLine=ZeroBasedIndex(endLine),
+        ~startCharacter=ZeroBasedIndex(0),
+        ~endCharacter=ZeroBasedIndex(endCharacter),
+        ~endLine=ZeroBasedIndex(endLine),
+        (),
+      ),
+      ...ranges^,
+    ]
+    |> List.rev;
+  };
+};

src/editor/Core/Range.rei

@@ -0,0 +1,38 @@
+/**
+ * Range.rei
+ *
+ * Module dealing with Range (tuples of positions)
+ */
+
+open Types;
+
+[@deriving show({with_path: false})]
+type t = {
+  startPosition: Position.t,
+  endPosition: Position.t,
+};
+
+let createFromPositions:
+  (~startPosition: Position.t, ~endPosition: Position.t, unit) => t;
+
+let create:
+  (
+    ~startLine: Index.t,
+    ~startCharacter: Index.t,
+    ~endLine: Index.t,
+    ~endCharacter: Index.t,
+    unit
+  ) =>
+  t;
+
+let zero: t;
+
+/*
+ * explode(range, measure) takes a Range.t and a measurement function (int => int),
+ * and expands a multiple-line range into a list of ranges, where there there is
+ * a single range per-line.
+ *
+ * If the input range is a single line, a single item list with the input range
+ * will be returned.
+ */
+let explode: (int => int, t) => list(t);

src/editor/Core/Types.re

@@ -93,35 +93,6 @@ module Position = {
   };
 };
 
-module Range = {
-  [@deriving show({with_path: false})]
-  type t = {
-    startPosition: Position.t,
-    endPosition: Position.t,
-  };
-
-  let createFromPositions = (~startPosition, ~endPosition, ()) => {
-    startPosition,
-    endPosition,
-  };
-
-  let create = (~startLine, ~startCharacter, ~endLine, ~endCharacter, ()) =>
-    createFromPositions(
-      ~startPosition=Position.create(startLine, startCharacter),
-      ~endPosition=Position.create(endLine, endCharacter),
-      (),
-    );
-
-  let zero =
-    create(
-      ~startLine=ZeroBasedIndex(0),
-      ~startCharacter=ZeroBasedIndex(0),
-      ~endLine=ZeroBasedIndex(0),
-      ~endCharacter=ZeroBasedIndex(0),
-      (),
-    );
-};
-
 [@deriving show({with_path: false})]
 type buftype =
   | Empty
@@ -294,60 +265,3 @@ module Input = {
     command: string,
   };
 };
-
-module VisualRange = {
-  [@deriving show({with_path: false})]
-  type mode =
-    | None
-    | Visual /* "v" */
-    | BlockwiseVisual /* "<C-v>" */
-    | LinewiseVisual; /* "V" */
-
-  [@deriving show({with_path: false})]
-  type t = {
-    range: Range.t,
-    mode,
-  };
-
-  let _modeFromString = s => {
-    switch (s) {
-    | "V" => LinewiseVisual
-    | "vb" => BlockwiseVisual
-    | "v" => Visual
-    | _ => None
-    };
-  };
-
-  /*
-   * The range might not always come through in the correct 'order' -
-   * this method normalizes the range so that the (startLine, startColumn) is
-   * before or equal to (endLine, endColumn)
-   */
-  let _normalizeRange = (startLine, startColumn, endLine, endColumn) =>
-    if (startLine > endLine) {
-      (endLine, endColumn, startLine, startColumn);
-    } else if (startLine == endLine && startColumn > endColumn) {
-      (endLine, endColumn, startLine, startColumn);
-    } else {
-      (startLine, startColumn, endLine, endColumn);
-    };
-
-  let create =
-      (~startLine=1, ~startColumn=1, ~endLine=1, ~endColumn=1, ~mode="", ()) => {
-    let (startLine, startColumn, endLine, endColumn) =
-      _normalizeRange(startLine, startColumn, endLine, endColumn);
-
-    let range =
-      Range.create(
-        ~startLine=OneBasedIndex(startLine),
-        ~startCharacter=OneBasedIndex(startColumn),
-        ~endLine=OneBasedIndex(endLine),
-        ~endCharacter=OneBasedIndex(endColumn),
-        (),
-      );
-
-    let mode = _modeFromString(mode);
-
-    {range, mode};
-  };
-};

src/editor/Core/VisualRange.re

@@ -0,0 +1,54 @@
+[@deriving show({with_path: false})]
+type mode =
+  | None
+  | Visual /* "v" */
+  | BlockwiseVisual /* "<C-v>" */
+  | LinewiseVisual; /* "V" */
+
+[@deriving show({with_path: false})]
+type t = {
+  range: Range.t,
+  mode,
+};
+
+let _modeFromString = s => {
+  switch (s) {
+  | "V" => LinewiseVisual
+  | "vb" => BlockwiseVisual
+  | "v" => Visual
+  | _ => None
+  };
+};
+
+/*
+ * The range might not always come through in the correct 'order' -
+ * this method normalizes the range so that the (startLine, startColumn) is
+ * before or equal to (endLine, endColumn)
+ */
+let _normalizeRange = (startLine, startColumn, endLine, endColumn) =>
+  if (startLine > endLine) {
+    (endLine, endColumn, startLine, startColumn);
+  } else if (startLine == endLine && startColumn > endColumn) {
+    (endLine, endColumn, startLine, startColumn);
+  } else {
+    (startLine, startColumn, endLine, endColumn);
+  };
+
+let create =
+    (~startLine=1, ~startColumn=1, ~endLine=1, ~endColumn=1, ~mode="", ()) => {
+  let (startLine, startColumn, endLine, endColumn) =
+    _normalizeRange(startLine, startColumn, endLine, endColumn);
+
+  let range =
+    Range.create(
+      ~startLine=OneBasedIndex(startLine),
+      ~startCharacter=OneBasedIndex(startColumn),
+      ~endLine=OneBasedIndex(endLine),
+      ~endCharacter=OneBasedIndex(endColumn),
+      (),
+    );
+
+  let mode = _modeFromString(mode);
+
+  {range, mode};
+};

src/editor/Model/Diagnostics.re

@@ -7,7 +7,6 @@
  */
 
 open Oni_Core;
-open Oni_Core.Types;
 
 module Diagnostic = {
   type t = {range: Range.t};

src/editor/Model/Diagnostics.rei

@@ -6,7 +6,7 @@
  * or minimap.
  */
 
-open Oni_Core.Types;
+open Oni_Core;
 
 module Diagnostic: {
   type t = {range: Range.t};

src/editor/Model/Selection.re

@@ -5,6 +5,7 @@
  * based on the visual selection state
  */
 
+open Oni_Core;
 open Oni_Core.Types;
 
 let getRangesForLinewiseSelection = (startLine, endLine, buffer) => {

src/editor/Neovim/Notification.re

@@ -56,7 +56,7 @@ type t =
   | WildmenuShow(Wildmenu.t)
   | WildmenuHide(Wildmenu.t)
   | WildmenuSelected(int)
-  | VisualRangeUpdate(Core.Types.VisualRange.t)
+  | VisualRangeUpdate(Core.VisualRange.t)
   | Ignored;
 
 type commandlineInput = {input: string};
@@ -259,7 +259,7 @@ let parse = (t: string, msg: Msgpck.t) => {
         ]),
       ) =>
       let visRange =
-        Core.Types.VisualRange.create(
+        Core.VisualRange.create(
           ~startLine,
           ~startColumn,
           ~endLine,

src/editor/UI/EditorSurface.re

@@ -421,7 +421,7 @@ let createElement =
               switch (activeBuffer) {
               | Some(b) =>
                 let ranges = Selection.getRanges(editor.selection, b);
-                Oni_Core.Types.Range.(
+                Oni_Core.Range.(
                   List.iter(
                     (r: Range.t) => {
                       let line = Index.toZeroBasedInt(r.startPosition.line);

test/editor/Core/Helpers.re

@@ -1,3 +1,6 @@
+open Oni_Core;
+open Oni_Core.Types;
+
 exception OptionInvalidException(string);
 let getOrThrow: option('a) => 'a =
   v =>
@@ -21,3 +24,32 @@ let repeat = (~iterations: int=5, f) => {
     count := count^ + 1;
   };
 };
+
+let validateRange =
+    (
+      expect: Rely__DefaultMatchers.matchers(unit),
+      actualRange: Range.t,
+      expectedRange: Range.t,
+    ) => {
+  expect.int(Index.toZeroBasedInt(actualRange.startPosition.line)).toBe(
+    Index.toZeroBasedInt(expectedRange.startPosition.line),
+  );
+  expect.int(Index.toZeroBasedInt(actualRange.endPosition.line)).toBe(
+    Index.toZeroBasedInt(expectedRange.endPosition.line),
+  );
+  expect.int(Index.toZeroBasedInt(actualRange.startPosition.character)).toBe(
+    Index.toZeroBasedInt(expectedRange.startPosition.character),
+  );
+  expect.int(Index.toZeroBasedInt(actualRange.endPosition.character)).toBe(
+    Index.toZeroBasedInt(expectedRange.endPosition.character),
+  );
+};
+
+let validateRanges =
+    (
+      expect: Rely__DefaultMatchers.matchers(unit),
+      actualRanges,
+      expectedRanges,
+    ) => {
+  List.iter2(validateRange(expect), actualRanges, expectedRanges);
+};