archrelease: copy trunk to staging-x86_64

git-svn-id: file:///srv/repos/svn-packages/svn@366668 eb2447ed-0c53-47e4-bac8-5bc4a241df78

389-ds-base/repos/staging-x86_64/389-ds-base.sysusers

@@ -0,0 +1 @@
+u dirsrv   440      "389 Directory Server" /var/lib/389-ds-base

389-ds-base/repos/staging-x86_64/389-ds-base.tmpfiles

@@ -0,0 +1,2 @@
+d /var/log/dirsrv 0700 dirsrv dirsrv -
+d /var/lib/dirsrv 0700 dirsrv dirsrv -

389-ds-base/repos/staging-x86_64/PKGBUILD

@@ -0,0 +1,80 @@
+# Maintainer: Sven-Hendrik Haase <[email protected]>
+# Contributor: Javier Torres <javitonino [at] gmail [dot] com>
+# Contributor: Jameson Pugh <[email protected]>
+# Contributor: Xiao-Long Chen <[email protected]>
+
+pkgname=389-ds-base
+pkgver=1.4.2.2
+pkgdesc="389 Directory Server (base)"
+pkgrel=2
+arch=(x86_64)
+url="http://port389.org/"
+license=(GPL)
+provides=(libsvrcore.so)
+replaces=(python-lib389)
+backup=(etc/dirsrv/config/certmap.conf
+        etc/dirsrv/config/ldap-agent.conf
+        etc/dirsrv/config/slapd-collations.conf
+        etc/dirsrv/config/template-initconfig)
+depends=(libevent nspr nss net-snmp pam openldap python-argcomplete python-dateutil python-ldap)
+makedepends=(cargo rsync doxygen cmocka python-setuptools python-argparse-manpage)
+source=("https://releases.pagure.org/389-ds-base/${pkgname}-${pkgver}.tar.bz2"
+        389-ds-base.sysusers
+        389-ds-base.tmpfiles)
+sha512sums=('410f79de429d552286100744add6c7f2a01aca08a74e87fb3bdb3a5758476d9ab129a367ec457f3bceed4ae971d5c33cd4be36252cf074f4c3450d188b6d7df6'
+            '8689b60f13517e6541e1faa62e61781654a8e4678990d14a3fe0cfe4673697cdde1c46763fdc7ef6203e4026286fa004c73b2857fd7fecff69483e6d1e8e6d68'
+            '5dff695ae866a591a711f836f2f72f2005b4afdb20760cda8711791910299e2c6ec71dff5eca9a2d9832cad8f9e9904dbbcf2d314cd9b20432bc8fd05c097868')
+
+prepare() {
+  cd "${pkgbase}-${pkgver}"
+
+  autoreconf -fiv
+}
+
+build() {
+  cd "${pkgbase}-${pkgver}"
+
+  # Build 389-ds-base
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --sbindir=/usr/bin \
+    --localstatedir=/var \
+    --libexecdir=/usr/lib/${pkgbase} \
+    --with-tmpfiles-d=/usr/lib/tmpfiles.d \
+    --with-systemd \
+    --with-systemdsystemunitdir=/usr/lib/systemd/system \
+    --with-systemdsystemconfdir=/etc/systemd/system \
+    --with-journald \
+    --enable-autobind \
+    --enable-cmocka \
+    --with-openldap \
+    --enable-rust
+  make
+
+  # Build lib389
+  cd src/lib389
+  python setup.py build
+}
+
+check() {
+  cd "${pkgbase}-${pkgver}"
+  make check
+}
+
+package() {
+  cd "${pkgbase}-${pkgver}"
+  make -j1 DESTDIR="${pkgdir}/" install
+
+  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+
+  # Upstream expects lib389 and 389-ds-base to be shipped in the same package more or less
+  # so that's why it's not a split package.
+  cd src/lib389
+  python setup.py install --skip-build -O1 --root=${pkgdir}
+  mv ${pkgdir}/usr/sbin/* ${pkgdir}/usr/bin/
+  rmdir ${pkgdir}/usr/sbin
+
+  install -Dm644 "${srcdir}/${pkgname}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
+  install -Dm644 "${srcdir}/${pkgname}.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
+}