net-wireless/gr-osmosdr: add 0.2.6

Signed-off-by: Thomas Beierlein <[email protected]>

net-wireless/gr-osmosdr/Manifest

@@ -1 +1,2 @@
 DIST gr-osmosdr-0.2.5.tar.gz 267914 BLAKE2B cec3790513a8e050610cb4b7f928c7b1d47e5b34e372f577c7f90a929a7353e2d7a86d04b8fcde57b24cc08554c5bee7257c052263de55e0f5ba3201f19a275c SHA512 d1c126d94accbd292624022df6ff7febecb1c73c3a1a0c3e8d0e3e4d882076df5b77ad14d79966a150e2c9d889c391239b1dc831acf49cdf891a19db7f830901
+DIST gr-osmosdr-0.2.6.tar.gz 268003 BLAKE2B e9826301e2836dbe937aa69bcc8078769a44889b19aa8981224ab4b0de96bd93cd3b6a0b42366b85e44854fc4300c5846cd07fdd5d9e3f7695082be3a29cb249 SHA512 2afac3503e74b67c8fb20b51dbe3c4d25f8247a9da4bfd9aec6d68412381e5e2319e8cc5b411faa9909a6c2b00c4844307c94d63e4efd613a2ddba027fd2e570

net-wireless/gr-osmosdr/gr-osmosdr-0.2.6.ebuild

@@ -0,0 +1,84 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..12} )
+
+inherit cmake python-single-r1
+
+DESCRIPTION="GNU Radio source block for OsmoSDR and rtlsdr and hackrf"
+HOMEPAGE="
+	https://sdr.osmocom.org/trac/wiki/GrOsmoSDR
+	https://gitea.osmocom.org/sdr/gr-osmosdr
+"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitea.osmocom.org/sdr/gr-osmosdr.git"
+else
+	SRC_URI="https://gitea.osmocom.org/sdr/gr-osmosdr/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~riscv ~x86"
+	S="${WORKDIR}/${PN}"
+fi
+
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+IUSE="airspy bladerf doc hackrf iqbalance rtlsdr sdrplay soapy uhd xtrx"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/boost:=
+	dev-libs/log4cpp
+	net-wireless/gnuradio:0=[${PYTHON_SINGLE_USEDEP}]
+	sci-libs/volk:=
+	airspy? ( net-wireless/airspy )
+	bladerf? ( >=net-wireless/bladerf-2018.08_rc1:= )
+	hackrf? ( net-libs/libhackrf:= )
+	iqbalance? ( net-wireless/gr-iqbal:=[${PYTHON_SINGLE_USEDEP}] )
+	rtlsdr? ( >=net-wireless/rtl-sdr-0.5.4:= )
+	sdrplay? ( net-wireless/sdrplay )
+	soapy? ( net-wireless/soapysdr:= )
+	uhd? ( net-wireless/uhd:=[${PYTHON_SINGLE_USEDEP}] )
+	xtrx? ( net-wireless/libxtrx )
+	"
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+		$(python_gen_cond_dep 'dev-python/pybind11[${PYTHON_USEDEP}]')
+		doc? ( app-text/doxygen )
+	"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.2.3_p20210128-fix-enable-python.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_DEFAULT=OFF
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DENABLE_FILE=ON
+		-DENABLE_AIRSPY="$(usex airspy ON OFF)"
+		-DENABLE_BLADERF="$(usex bladerf ON OFF)"
+		-DENABLE_HACKRF="$(usex hackrf ON OFF)"
+		-DENABLE_IQBALANCE="$(usex iqbalance ON OFF)"
+		-DENABLE_PYTHON=ON
+		-DENABLE_RTL="$(usex rtlsdr ON OFF)"
+		-DENABLE_RTL_TCP="$(usex rtlsdr ON OFF)"
+		-DENABLE_SDRPLAY="$(usex sdrplay ON OFF)"
+		-DENABLE_NONFREE="$(usex sdrplay ON OFF)"
+		-DENABLE_SOAPY="$(usex soapy ON OFF)"
+		-DENABLE_UHD="$(usex uhd ON OFF)"
+		-DENABLE_XTRX="$(usex xtrx ON OFF)"
+		-DENABLE_DOXYGEN="$(usex doc ON OFF)"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	find "${ED}" -name '*.py[oc]' -delete || die
+	python_fix_shebang "${ED}"/usr/bin
+	python_optimize
+}