archrelease: copy kde-unstable to kde-unstable-x86_64

git-svn-id: file:///srv/repos/svn-packages/svn@410472 eb2447ed-0c53-47e4-bac8-5bc4a241df78

akonadi/repos/kde-unstable-x86_64/PKGBUILD

@@ -0,0 +1,42 @@
+# Maintainer: Antonio Rojas <[email protected]>
+# Maintainer: Felix Yan <[email protected]>
+# Contributor: Andrea Scarpino <[email protected]>
+# Contributor: Pierre Schmitz <[email protected]>
+
+pkgbase=akonadi
+pkgname=(akonadi libakonadi)
+pkgver=21.03.80
+pkgrel=1
+pkgdesc="PIM layer, which provides an asynchronous API to access all kind of PIM data"
+arch=(x86_64)
+url='https://kontact.kde.org'
+license=(LGPL)
+makedepends=(extra-cmake-modules postgresql qt5-tools boost kitemmodels kaccounts-integration)
+source=("https://download.kde.org/unstable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('0792eb92961913cd6d9035aa8feb63f92da92ea3e5c5a8dc3a412c3bb77318d2'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <[email protected]>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <[email protected]>
+              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <[email protected]>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package_libakonadi() {
+  pkgdesc='Libraries used by applications based on Akonadi'
+  depends=(kitemmodels kaccounts-integration)
+
+  DESTDIR="$pkgdir" cmake --install build
+  rm -r "$pkgdir"/usr/bin # Provided by akonadi
+}
+
+package_akonadi() {
+  depends=(libakonadi mariadb)
+  optdepends=('postgresql: PostgreSQL backend')
+
+  DESTDIR="$pkgdir" cmake --install build
+  rm -r "$pkgdir"/{etc,usr/{include,lib,share}} # Provided by libakonadi
+}