Merge pull request breakroom#18 from jshmrtn/search_suggest_response

Support suggest in SearchReponse

lib/snap/search_response.ex

@@ -4,14 +4,15 @@ defmodule Snap.SearchResponse do
 
   Implements `Enumerable`, so you can iterate directly over the struct.
   """
-  defstruct [:took, :timed_out, :shards, :hits, :aggregations, :scroll_id, :pit_id]
+  defstruct [:took, :timed_out, :shards, :hits, :suggest, :aggregations, :scroll_id, :pit_id]
 
   def new(response) do
     %__MODULE__{
       took: response["took"],
       timed_out: response["timed_out"],
       shards: response["_shards"],
       hits: Snap.Hits.new(response["hits"]),
+      suggest: Snap.Suggests.new(response["suggest"]),
       aggregations: build_aggregations(response["aggregations"]),
       scroll_id: response["_scroll_id"],
       pit_id: response["pit_id"]
@@ -23,6 +24,7 @@ defmodule Snap.SearchResponse do
           timed_out: boolean(),
           shards: map(),
           hits: Snap.Hits.t(),
+          suggest: Snap.Suggests.t() | nil,
           aggregations: %{String.t() => Snap.Aggregation.t()} | nil,
           scroll_id: String.t() | nil,
           pit_id: map() | nil

lib/snap/suggest.ex

@@ -0,0 +1,27 @@
+defmodule Snap.Suggest do
+  @moduledoc """
+  Represents an individual suggest dictionary from a [Search API](https://www.elastic.co/guide/en/elasticsearch/reference/current/search.html) response.
+  """
+  defstruct ~w[
+    length
+    offset
+    options
+    text
+  ]a
+
+  def new(response) do
+    %__MODULE__{
+      length: response["length"],
+      offset: response["offset"],
+      options: Snap.Suggest.Options.new(response["options"]),
+      text: response["text"]
+    }
+  end
+
+  @type t :: %__MODULE__{
+          length: non_neg_integer(),
+          offset: non_neg_integer(),
+          options: [Snap.Suggest.Option.t()],
+          text: String.t()
+        }
+end

lib/snap/suggest/option.ex

@@ -0,0 +1,24 @@
+defmodule Snap.Suggest.Option do
+  @moduledoc """
+  Represents an individual `suggest` / `options` dictionary from a [Search API](https://www.elastic.co/guide/en/elasticsearch/reference/current/search.html) response.
+  """
+  defstruct ~w[
+    freq
+    score
+    text
+  ]a
+
+  def new(response) do
+    %__MODULE__{
+      freq: response["freq"],
+      score: response["score"],
+      text: response["text"]
+    }
+  end
+
+  @type t :: %__MODULE__{
+          freq: integer(),
+          score: float(),
+          text: String.t()
+        }
+end

lib/snap/suggest/options.ex

@@ -0,0 +1,9 @@
+defmodule Snap.Suggest.Options do
+  @moduledoc """
+  Represents the `suggest` / `options` dictionary returned from an ElasticSearch [Search API](https://www.elastic.co/guide/en/elasticsearch/reference/current/search.html) response.
+  """
+
+  def new(response), do: Enum.map(response, &Snap.Suggest.Option.new/1)
+
+  @type t :: [Snap.Suggest.Option.t()]
+end

lib/snap/suggests.ex

@@ -0,0 +1,14 @@
+defmodule Snap.Suggests do
+  @moduledoc """
+  Represents the `suggest` dictionary returned from an ElasticSearch [Search API](https://www.elastic.co/guide/en/elasticsearch/reference/current/search.html) response.
+  """
+
+  def new(response)
+  def new(nil), do: nil
+
+  def new(response),
+    do:
+      Map.new(response, fn {name, suggest} -> {name, Enum.map(suggest, &Snap.Suggest.new(&1))} end)
+
+  @type t :: %{String.t() => [Snap.Suggest.t()]}
+end

test/search_test.exs

@@ -25,4 +25,33 @@ defmodule Snap.SearchTest do
     assert first_hit.id == "1"
     assert first_hit.source["title"] == "Document 1"
   end
+
+  test "search with suggestion response" do
+    {:ok, _} = Snap.Indexes.create(Cluster, @test_index, %{})
+
+    1..5
+    |> Enum.map(fn i ->
+      doc = %{"title" => "Document #{i}"}
+
+      %Action.Index{_id: i, doc: doc}
+    end)
+    |> Snap.Bulk.perform(Cluster, @test_index, refresh: :wait_for)
+
+    query = %{
+      "query" => %{"match_all" => %{}},
+      "sort" => ["_doc"],
+      "suggest" => %{"title" => %{"text" => "Doument", "term" => %{"field" => "title"}}}
+    }
+
+    {:ok, search_response} = Search.search(Cluster, @test_index, query)
+    assert Enum.count(search_response) == 5
+
+    first_hit = Enum.at(search_response, 0)
+    assert first_hit.id == "1"
+    assert first_hit.source["title"] == "Document 1"
+
+    assert %Snap.SearchResponse{
+             suggest: %{"title" => [%{text: "doument", options: [%{text: "document"}]}]}
+           } = search_response
+  end
 end