archrelease: copy trunk to testing-x86_64

git-svn-id: file:///srv/repos/svn-packages/svn@324109 eb2447ed-0c53-47e4-bac8-5bc4a241df78

baloo/repos/testing-x86_64/PKGBUILD

@@ -0,0 +1,39 @@
+# $Id$
+# Maintainer: Felix Yan <[email protected]>
+# Maintainer: Antonio Rojas <[email protected]>
+# Contributor: Andrea Scarpino <[email protected]>
+
+pkgname=baloo
+pkgver=5.46.0
+pkgrel=1
+pkgdesc="A framework for searching and managing metadata"
+arch=(x86_64)
+url='https://community.kde.org/Frameworks'
+license=(LGPL)
+depends=(kfilemetadata kidletime kio lmdb)
+makedepends=(extra-cmake-modules kdoctools doxygen qt5-tools qt5-declarative)
+optdepends=('qt5-declarative: QML bindings')
+groups=(kf5)
+source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('c33788167d65fe20621b2ae11ad8ae734c20f43e083e14c3c922fec4b14f9c07'
+            'SKIP')
+validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <[email protected]>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF \
+    -DBUILD_QCH=ON
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}